ATKJOB4 ; Afstand-toegang voor klanten [ 05/31/2002   9:21 AM ]
 Quit
 ;
ORDER(JobNr,KLNr,Type,LEVNr) 
 If Type="T" Do DORDER(JobNr,KLNr,$G(LEVNr)) Quit
 New D,U,Q,I,R,Count,ORDNr,OLNr,DataRef,PRNr,Stock,FysStock,PraStock,TeoStock,InStock
 Quit:'$G(^ATK(0,0,"A"))
 Do INIT^ATKJOB
 Set Count=0,Type=$G(Type),DataRef=$S(Type="C":"CORDER",Type="A":"AORDER",1:"OORDER")
 Set:Type="" Type="-ACMPY"
 For I=$L(Type):-1:1 Set $E(Type,I)=$E(Type,I)_D
 Set:Type="" Type=D Set:$E(Type)'="-" Type=D_Type
 Set ORDNr=0
 For  Set ORDNr=$O(^KOD(KLNr,"F",ORDNr)) Quit:ORDNr=""  Do
 .Set R=^KOD(KLNr,"F",ORDNr,1)
 .If $E(Type)="-",Type[(D_$P(R,D,25)_D) Quit
 .If $E(Type)'["-",Type'[(D_$P(R,D,25)_D) Quit
 .For I=1,4:1:24,26:1:$L(R,D) Set $P(R,D,I)=""
 .Set $P(R,D,99)="1\"_ORDNr
 .Do PUTHULP^ATKJOB(DataRef,R)
 .Set OLNr=100
 .For  Set OLNr=$O(^KOD(KLNr,"F",ORDNr,OLNr)) Quit:OLNr=""  Do
 ..Set R=^KOD(KLNr,"F",ORDNr,OLNr),PRNr=$P(R,D,2),(FysStock,PraStock,TeoStock,InStock)=""
 ..If PRNr,$D(^KPR(PRNr)) Do
 ...Set $P(R,D,5)=$P(^KPR(PRNr,0),D)
 ...Set Stock=$$GETSTOCK^PRODUKT4(PRNr),FysStock=$P(Stock,D),PraStock=$P(Stock,D,2),TeoStock=$P(Stock,D,3)
 ...If '$P(R,D,27),$P(R,D,3)'>FysStock Set InStock=1
 ..If $P($P(R,D,17),"#")="KF1925"!PRNr Set $P(R,D,22)=$$MUNT^ATKJOB($P(R,D,22))
 ..For I=1,4,7:1:20,23,24,26,28:1:$L(R,D) Set $P(R,D,I)=""
 ..Set $P(R,D,33,99)=FysStock_D_PraStock_D_TeoStock_D_InStock_D,$P(R,D,41)=R
 ..For I=1:1:40 Set $P(R,D,I)=""
 ..Do PUTHULP^ATKJOB(DataRef,R)
 Do PUTHULP^ATKJOB(DataRef)
 Quit
 ;
DORDER(JobNr,KLNr,LEVNr) 
 New D,U,Q,I,R,%J,Count,DataRef,BLKLNr,Next,LevNr,TOENr,TLNr,PRNr,Stock,FysStock,PraStock,TeoStock,InStock
 Quit:'$G(^ATK(0,0,"A"))
 Do INIT^ATKJOB
 Set DataRef="TORDER",BLKLNr=$G(^BLBeri("IK",KLNr)),LevNr=$S($G(LEVNr):LEVNr,1:5005)
 If $L(BLKLNr) Do
 .Set %J=$J
 .Kill ^HULP(%J)
 .Set R=$$CBMORE^RPLDORD("",9999,"")
 .Set Count=0
 .For Next=1:1 Quit:'$D(^HULP(%J,"K"_KLNr,"DIRORD",Next))  Do
 ..Set R=^HULP(%J,"K"_KLNr,"DIRORD",Next),LEVNr=$P(R,D),TOENr=$P(R,D,2),TLNr=$P(R,D,3)
 ..If 'TLNr Do  Quit
 ...Set R=^KTO(LEVNr,TOENr,1)
 ...For I=1,4:1:9,11:1:24,26:1:$L(R,D) Set $P(R,D,I)=""
 ...Set $P(R,D,99)="1\"_TOENr
 ...Do PUTHULP^ATKJOB(DataRef,R)
 ..Set R=^KTO(LEVNr,TOENr,TLNr),PRNr=$P(R,D,2),(FysStock,PraStock,TeoStock,InStock)=""
 ..If PRNr,$D(^KPR(PRNr)) Do
 ...Set $P(R,D,5)=$P(^KPR(PRNr,0),D)
 ...Set Stock=$$GETSTOCK^PRODUKT4(PRNr),FysStock=$P(Stock,D),PraStock=$P(Stock,D,2),TeoStock=$P(Stock,D,3)
 ...If '$P(R,D,27),$P(R,D,3)'>FysStock Set InStock=1
 ..If $P($P(R,D,17),"#")="KF1925"!PRNr Set $P(R,D,22)=$$MUNT^ATKJOB($P(R,D,22))
 ..For I=1,4,7:1:20,23,24,26,28:1:$L(R,D) Set $P(R,D,I)=""
 ..Set $P(R,D,33,99)=FysStock_D_PraStock_D_TeoStock_D_InStock_D,$P(R,D,41)=R
 ..For I=1:1:40 Set $P(R,D,I)=""
 ..Do PUTHULP^ATKJOB(DataRef,R)
 .Kill ^HULP(%J)
 Do PUTHULP^ATKJOB(DataRef)
 Quit
 ;
BON(JobNr,KLNr) 
 New D,U,Q,I,R,Count,BONNr,OLNr,DataRef,PRNr,ORDNr,OrdRef,Taal,Transp
 Quit:'$G(^ATK(0,0,"A"))
 Do INIT^ATKJOB
 Set Taal=$P(^KKL(^KK1(KLNr),0),D,9) Set:Taal="" Taal="N"
 Set (Count,BONNr)=0,DataRef="BON"
 For  Set BONNr=$O(^KUL(KLNr,"F",BONNr)) Quit:BONNr=""  Do
 .Set R=^KUL(KLNr,"F",BONNr,1)
 .For I=1,3:1:6,8,11:1:$L(R,D) Set $P(R,D,I)=""
 .Set Transp=$P(R,D,7)
 .If "\EX\OD\PO\VT\"[(D_$E(Transp,1,2)_D) Do
 ..Quit:'$L($G(^RES("KLANT","PI","VERZENDWIJZE","D",$E(Transp,1,2),Taal)))
 ..Set $P(Transp,"#",2)=^RES("KLANT","PI","VERZENDWIJZE","D",$E(Transp,1,2),Taal),$P(R,D,7)=Transp
 .Set $P(R,D,99)="1\"_BONNr
 .Do PUTHULP^ATKJOB(DataRef,R)
 .Set OLNr=100
 .For  Set OLNr=$O(^KUL(KLNr,"F",BONNr,OLNr)) Quit:'OLNr  Do
 ..Set R=^KUL(KLNr,"F",BONNr,OLNr),PRNr=$P(R,D,2)
 ..If $P(R,D,17)="KF5" Do  Quit
 ...Set ORDNr=$P($P(R,D,5)," - "),OrdRef=$P($P(R,D,5)," - ",3)
 ...Set $P(R,D,5)=OrdRef
 ...For I=1:1:4,6:1:$L(R,D) Set $P(R,D,I)=""
 ...Set $P(R,D,99)="1\\"_ORDNr
 ...Do PUTHULP^ATKJOB(DataRef,R)
 ..If PRNr Do
 ...If $D(^KPR(PRNr)) Set $P(R,D,5)=$P(^KPR(PRNr,0),D)
 ..If $P($P(R,D,17),"#")="KF1925"!PRNr Set $P(R,D,22)=$$MUNT^ATKJOB($P(R,D,22))
 ..For I=1,4,7:1:20,23,24,26,28:1:$L(R,D) Set $P(R,D,I)=""
 ..Set $P(R,D,41)=R
 ..For I=1:1:40 Set $P(R,D,I)=""
 ..Do PUTHULP^ATKJOB(DataRef,R)
 Do PUTHULP^ATKJOB(DataRef)
 Quit
 ;
OFAKT(JobNr,KLNr) 
 New D,U,Q,I,R,Count,FANr,KlantInd,VerVal,DataRef
 Quit:'$G(^ATK(0,0,"A"))
 Do INIT^ATKJOB
 Set Count=0,KlantInd=^KK1(KLNr),FANr=9999,DataRef="OFAKT"
 For  Set FANr=$O(^KKL(KlantInd,FANr)) Quit:FANr'?5N.N!(FANr>999999)  Do
 .Set R=^KKL(KlantInd,FANr)
 .Quit:'$L($P(R,D,5))
 .For I=6,7 Set $P(R,D,I)=""
 .Set Verval=$H-$$INTDATE^vhDTyp($P(R,D,3)) Set:Verval<1 Verval=""
 .Set $P(R,D,9)=$$MUNT^ATKJOB($P(R,D,9)),$P(R,D,10,99)="",$P(R,D,40)=FANr_D_Verval
 .Do PUTHULP^ATKJOB(DataRef,R)
 Do PUTHULP^ATKJOB(DataRef)
 Quit
 ;