BURSTOCK ;Berekenen van de stockbestelling van burbidge [ 11/06/2001  8:32 AM ]
 k  S Q="K" D ^cA604
 Set %J=$$%J^vhRtn1()
 Kill ^HULP(%J)
 Set $ZTRAP="^cA406"
 Set LevNr=5810
 Set Cnt=0
 Set TLNr=""
 Set PRNr=0
 For  Set PRNr=$O(^KPR(PRNr)) Quit:'PRNr  Do
 .Quit:'$D(^KPR(PRNr,"J"_LevNr))
 .Set Lim=$P($G(^KPR(PRNr,0)),D,24)
 .Quit:'Lim  ; Geen limiet
 .Set Stock=$$GETSTOCK^PRODUKT4(PRNr,"T")
 .Set LevTrm=$P(^KPR(PRNr,"J"_LevNr),D,7)
 .If Stock<Lim Set ^HULP(%J,LevTrm,PRNr)=Lim-Stock,Cnt=Cnt+1
 ; Kreatie toeleveringen
 Set LevTrm="",CntTL=0
 For  Set LevTrm=$O(^HULP(%J,LevTrm)) Quit:LevTrm=""  Do
 .Set TLNr="",PRNr="",LijnCnt=0
 .For  Set PRNr=$O(^HULP(%J,LevTrm,PRNr)) Quit:PRNr=""  Do
 ..Set TLNr=$$ADD(LevNr,TLNr,PRNr,$P(^HULP(%J,LevTrm,PRNr),D))
 ..Set LijnCnt=LijnCnt+1
 .Set CntTL=CntTL+1,TLLnk(CntTL)="TL\"_TLNr_"\W"
 .Set TLTxt(CntTL)="Toelevering "_TLNr_" bevat "_LijnCnt_" lijn"_$S(LijnCnt>1:"en",1:"")
 .Set TLTxt(CntTL+1)="Totaal aantal lijnen : "_Cnt
 ;
 Kill ^HULP(%J)
 Set:Cnt MailId=$$SYSTEM^vhMAIL("LE",LevNr,"Creatie toelevering",19,.TLTxt,.TLLnk,"","A")
 Quit
 
ADD(LevNr,TLNr,PRNr,Qty,LevWK) 
 New Rec
 If 'TLNr Do  ; Hoofding
 .Set TLNr=$$GETNUM^FLOW("KTO","KTO1")
 .Set Rec=D_$$EXTDATE^vhDTyp($H,"DKP")_D_"Stock"_D_D_D_LevNr
 .Set $P(Rec,D,18)=$P(^KLE(^KL1(LevNr),0),D,11)
 .Set ^KTO(LevNr,TLNr,0)=101
 .Set ^KTO(LevNr,TLNr,1)=Rec
 .Set ^KTO1(TLNr)=LevNr_D
 .Set ^KTO2(LevNr,TLNr)=""
 .Set ^KTOB(TLNr)=LevNr_D
 ; Lijn
 Lock +^KTO(LevNr,TLNr)
 Set TLLNr=^KTO(LevNr,TLNr,0),^KTO(LevNr,TLNr,0)=TLLNr+1
 Set:'$L($G(LevWK)) LevWK=$$EXTDATE^vhDTyp($$CALCDATE^vhDTyp($H,"W","MD",$P(^KPR(PRNr,"J"_LevNr),D,7)),"DW")
 Set Rec=D_PRNr_D_Qty
 Set $P(Rec,D,12)="L"
 Set $P(Rec,D,13)=TLLNr#100
 Set $P(Rec,D,17)="KTRPL"
 ;Set $P(Rec,D,22)=$P(^KLE(^KL1(LevNr),0),D,11)
 Set $P(Rec,D,25)=LevWK
 Set ^KTO(LevNr,TLNr,TLLNr)=Rec
 Do LRECALC^FLOWTOE(LevNr,TLNr,TLLNr,0,1)
 Do SWNODE^FLOWTOE(LevNr,TLNr,TLLNr)
 Do ProductToeleveringLijnGemaakt^FLOWTOE2(LevNr,TLNr,TLLNr)
 Lock -^KTO(LevNr,TLNr)
 Quit TLNr