EWORDS4 ;E'WMS Markeren voor orderpicking [ 10/11/2002  10:13 AM ]
 ;
HOOFDING 
 New R,Verv30D,LimExceeded,KredietLim,VooruitRemb
 Set FP=101
 Write @F,@F2
 Do DISPLAY^vhScherm("EWORDS",,,,,1)
 Set FP=201
 Write @F,@F2,"Klant : ",KLNr_" "_$P(^KKL(^KK1(KLNr),0),D,2)
 Set FP=301
 Write @F,@F2
 Set FP=FP+8
 Write @F,$J("",40),@F
 Set R=$$BETINFO^KREDIET(KLNr),Verv30D=$LG(R),LimExceeded=$LG(R,2),KredietLim=$LG(R,3),VooruitRemb=$LG(R,4)
 If $L(Verv30D)!$L(LimExceeded) Do
 .Write @FMTB Write:Verv30D="Dubieus" @FMTK
 .Write:$L(Verv30D) $$UPTRIMA^vhRtn1(Verv30D)
 .Write @FMTk
 .If $L(Verv30D),$L(LimExceeded) Write "/"
 .Write:$L(LimExceeded) $$UPTRIMA^vhRtn1(LimExceeded)
 .Write @FMTb
 Set FP=321 Write @F,$$UPTRIMA^vhRtn1(KredietLim)
 If $L(VooruitRemb) Set FP=321+$S($L(KredietLim):15,1:0) Write @F,@FMTK,$$UPTRIMA^vhRtn1(VooruitRemb),@FMTk
 Set FP=401
 Write @F,@F2		
 Do DISPLAY^vhScherm("EWORDSH",,,,,1)
 Quit
 ;
VERZABX(%J,KLNr,NoAsk) 
 Quit
 
 New R,ORDNr,OLUNr,OLNr,Gewicht,VerzW,VerzSp,Aantal,TranspLink
 Set (ORDNr,Gewicht)=""
 Set VerzW=$P(^HULP(%J,KLNr,"V"),D)
 If '$G(NoAsk),$E(VerzW,1,2)="OD" Do
 .For  Set ORDNr=$O(^HULP(%J,KLNr,"M","A",ORDNr)) Quit:ORDNr=""  Do  Quit:Aantal'>0
 ..Set TranspLink=$$TranspLink^FLOWORD(ORDNr)
 ..Set OLUNr=""
 ..For  Set OLUNr=$O(^HULP(%J,KLNr,"M","A",ORDNr,OLUNr)) Quit:OLUNr=""  Do  Quit:Aantal'>0
 ...Set R=^HULP(%J,KLNr,"M","A",ORDNr,OLUNr),Aantal=$P(R,D)
 ...If Aantal'>0 Set Gewicht="" Quit
 ...Set OLNr=^ORD("IU",ORDNr,OLUNr)
 ...Set R=^KOD(KLNr,"F",ORDNr,OLNr),PRNr=$P(R,D,2)
 ...Quit:$D(^KPR(PRNr,"J5810"))  Quit:$D(^KPR(PRNr,"J6092"))  Quit:$D(^KPR(PRNr,"J6428"))
 ...Set Gewicht=Gewicht+($$CALCGEW^EWBON4(PRNr)*Aantal)
 .Quit:$L(TranspLink)  Quit:Gewicht=""  Quit:Gewicht>30
 .Set VerzSp="DI1"
 .Quit:$G(NoAsk)
 .Set R="$$^vhTXTPOP(""EWORDS"",""VERZABX"",,$$EXTNUM^vhDTyp(Gewicht,0,""."",$L($P(Gewicht,""."",2))),$P(VerzW,"";"")"
 .Set R=R_","""_$P(^RES("KLANT","PI","VERZENDWIJZE","D",$P(VerzW,";")),"`",2)
 .Set R=R_""",""DI1"","""_$P(^RES("KLANT","PI","VERZENDWIJZE","D","DI1"),"`",2)_""")"
 .Xecute "Set R="_R
 .Quit:'R
 .Do SETVERZW^EWORDS(KLNr,,"DI1")
 .Do DISPLAY^vhScherm("EWORDSH",,,,"VERZWIJZE;GERAAPT;VERZZONE;VERZDATUM")
 Quit
 ;
RPLKL 
 New R
 Set R=$$RAADPL^KLANT(KLNr,$G(Screen,"O"),1)
 Do REFRESH^EWORDS(KLNr,,Optie)
 Quit
 ;
RPLPR 
 New R,PRNr
 Do STORE^vhTERMINA()
 Set R=^HULP(%J,KLNr,"O",LD("SELECT")),PRNr=$P(R,D,12)
 Set R=$$RAADPL^PRODUKT(PRNr,$G(Screen,"O"),1)
 Do REFRESH^vhTERMINA()
 Quit
 ;
MODORD 
 New R,Locals,ORDNr
 Set R=^HULP(%J,KLNr,"O",LD("SELECT")),ORDNr=$P(R,D)
 Set Locals("ORDNr")=ORDNr,Locals("Extern")=1,Locals("EwmsLink")=0
 Do DO^vhPROGRAM("FOE^KF9")
 Do REFRESH^EWORDS(KLNr,,Optie)
 Quit
 ;
MODTOE 
 New R,Locals,TOENr
 Set R=^HULP(%J,KLNr,"O",LD("SELECT")),TOENr=$P(R,D,17)
 Set Locals("TOENr")=TOENr,Locals("Extern")=1
 Do DO^vhPROGRAM("FTE^KTO30")
 Do REFRESH^EWORDS(KLNr,,Optie)
 Quit
 ;