EWRECD ;E'WMS Record definitie [ 11/22/2003   1:21 PM ]
IMPORT ;Inlezen van de record definitie
 Kill  Do INIT^vhTERMINA
 Set %J=$$%J^vhRtn1()
 Kill ^HULP(%J)
 Set RecLab=""
 ;Set FileNm=$$READ^vhDEV($$DIRUSER^vhDEV,"recdef.txt","D`IMPCB^"_$P($T(+1)," ",1),"T","P") 
 Set FileNm=$$READ^vhDEV("C:\WMS\","recdef.txt","D`IMPCB^"_$P($T(+1)," ",1),"T","P") 
 Quit
 
IMPCB(Rec) ; Callback voor het inlezen van EEN recordefinitie
 If $L($P(Rec,D)) Do
 .Set RecLab=$P(Rec,D),RecOms=$P(Rec,D,2),RecDir=$P(Rec,D,3)
 .Set Cnt=0
 Else  If $L($P(Rec,D,2)),$L(RecLab) Do
 .Set Cnt=Cnt+1
 .If Cnt=1 Do
 ..Kill ^EWREC("O",RecLab)
 ..Merge ^EWREC("O",RecLab)=^EWREC("B",RecLab)
 ..Kill ^EWREC("B",RecLab),^EWREC("D",RecLab)
 ..Set ^EWREC("B",RecLab)=RecOms_D_RecDir_D_$H
 ..Set ^EWREC("D",RecLab)=^EWREC("B",RecLab)
 .Set ^EWREC("B",RecLab,Cnt)=Rec
 .Set ^EWREC("D",RecLab,Cnt)=$$IMPTRANS(Rec)
 Quit
 
IMPTRANS(Rec) ; Vertaling van het geimporteerde
 Set LabOms=$$UPTRIMAN^vhRtn1($P(Rec,D,2))
 Set Lengte=$P(Rec,D,3)
 Set Type=$$UPTRIMAN^vhRtn1($P(Rec,D,4))
 If Lengte["+" X "S Lengte="_Lengte
 Set Fmt="A"
 Set:$E(Type="N") Fmt="N"
 Set:$E(Type="A") Fmt="A"
 Set:Type="NUM" Fmt="N"
 Set:Type="FLOAT" Fmt="N"
 Set:Type="ALFANUM" Fmt="AN"
 Set:Type="ALNUM" Fmt="AN"
 Set:Type="ALFA" Fmt="A"
 Set:$P(Rec,D,3)="8+6" Fmt="DT" ; Datum en tijd
 If '$D(^EWREC("T",LabOms)) Do READLAB($P(Rec,D,2))
 Set Label=$P(^EWREC("T",LabOms),D)
 Quit Label_D_Lengte_D_Fmt
 
READLAB(Oms) 
 New I,Cnt,OmsUP,Key,Txt,Label
 Write @F11,@F1,!
 Set OmsUP=$$UPTRIMAN^vhRtn1(Oms)
 Set Cnt=0
 For I=$L(OmsUP)-1:-1:1 Do  Quit:Cnt>20
 .Set Key=$O(^EWREC("T",$E(OmsUP,1,I)),-1)
 .For  Set Key=$O(^EWREC("T",Key)) Quit:$E(Key,1,I)'=$E(OmsUP,1,I)  Do  Quit:Cnt>20
 ..Quit:$D(Txt(Key))
 ..Set Txt(Key)=""
 ..Set Cnt=Cnt+1
 ..Write Key,?25,$P(^EWREC("T",Key),D,2),?50,$P(^EWREC("T",Key),D,1),!
 Set Label=$$ASK^vhINP("Programma label",20,OmsUP,OmsUP)
 Set ^EWREC("T",OmsUP)=Label_D_Oms
 Quit
 
EXPORT 
 ;Set Dev=$$OPEN^vhDEV($$DIRUSER^vhDEV,"EXPRECDEF.TXT","W")
 Set Dev=$$OPEN^vhDEV("\\NOTES01\SHARED\P V","EXPRECDEF.TXT","W")
 Use Dev
 Set (Kode,VolgNr)=""
 For  Set Kode=$O(^EWREC("D",Kode)) Quit:Kode=""  Do
 .Set Rec=^EWREC("D",Kode)
 .Write Kode,$C(9),$P(Rec,"\"),$C(9),$P(Rec,"\",2),!
 .For  Set VolgNr=$O(^EWREC("D",Kode,VolgNr)) Quit:VolgNr=""  Do
 ..Set Rec=^EWREC("D",Kode,VolgNr)
 ..Set Rec=Rec_"\"_^EWREC("B",Kode,VolgNr)
 ..Write $TR("\"_Rec,"\",$C(9)),!
 Close Dev
 Quit
 
EXPVZW Kill  D ^cA604
 Set Key=""
 For  Set Key=$O(^RES("KLANT","PI","VERZENDWIJZE","D",Key)) Quit:Key=""  Do
 .Set Rec=$P(^(Key),"`",2)
 .Set Sort=$P(^(Key),"`",1)
 .Set T(Sort)=$E(Key_$J("",3-$L(Key)),1,3)_$E(Rec_$J("",3-$L(Rec)),1,30)
 Do:$D(T) EXPRES("EXPVZW",.T)
 Write:'$D(T) !,"Niets gevnden",!
 Quit 
 
EXPCOL Kill  D ^cA604
 Set Key=""
 For  Set Key=$O(^RES("EWBON","PI","COLLIETYPE","D",Key)) Quit:Key=""  Do
 .Set Rec=$P(^(Key),"`",2)
 .Set Sort=$P(^(Key),"`",1)
 .Set T(Sort)=$E(Key,1,1)_$E(Rec_$J("",3-$L(Rec)),1,30)
 Do:$D(T) EXPRES("EXPCOL",.T)
 Write:'$D(T) !,"Niets gevnden",!
 Quit 
 
EXPRES(File,Local) 
 Set Dev=$$OPEN^vhDEV($$DIRUSER^vhDEV,File_".txt","W")
 Quit:0[Dev
 Use Dev
 Set Sort=""
 For  Set Sort=$O(Local(Sort)) Quit:Sort=""  Write Local(Sort),!
 Close Dev
 Quit