EWRECL ;EWMS LOGGING bekijken [ 05/27/2003  4:38 PM ]
 ;
 Kill
 Do VERWERK
 Kill ^HULP(%J)
 Quit
 ;
VERWERK 
 New R,LD,Input,DatVan,DatTot,Types,ZoekExec,Zoek
 For  Do INIT,EDIT Quit:'%SC  Do  Quit:Input'="S"
 .Write @FS132
 .Do DISPLAY^vhScherm("EWRECL")
 .Do FETCHALL(DatVan,DatTot,Types,.ZoekExec) 
 .Do INIT^vhLIST("EWRECL","LOGGING",.LD)
 .Do WRITE^vhLIST(.LD)
 .For  Set Input=$$SCROLL^vhLIST(.LD) Do  Quit:"\-\CANC\S\"[(D_Input_D)
 ..If Input="COM" Set Input="" Do CALL^vhMenu("EWRECL")
 ..Do EXEC^vhMenu("EWRECL",.Input)
 .Write @FS80
 .Kill ^HULP(%J)
 Quit
 ;
DETAIL 
 For  Do  Quit:Input'="D"
 .Set Input=$$SHOWDTL(LD("SELECT"))
 .If Input=+1 Do MOVE^vhLIST(.LD,"DO",0) Set Input="D"
 .If Input=-1 Do MOVE^vhLIST(.LD,"UP",0) Set Input="D"
 .Set Rec=$G(^HULP(%J,"L",LD("SELECT")))
 .If $P(Rec,D,1)="LOG"!($P(Rec,D,1)="EWL")!(Rec="") Set Input="" 
 Quit
 ;
FETCHALL(DatVan,DatTot,Types,ZoekExec) 
 Kill FileMark ;het bestand mag eventueel terug doorgestuurd worden
 New STypes,RTypes,Type,Node
 ;ZoekExec(I,J) ;I = OF functie en J = EN
 Kill ^HULP(%J,"L")
 Set (STypes,RTypes)=""
 Set:$L(Types) Types=";"_Types_";"
 Set Type=""
 For  Set Type=$O(^EWREC("D",Type)) Quit:Type=""  Do
 .Set Node=$P(^EWREC("D",Type),D,2)
 .Quit:Types'=""&(Types'[(";"_Type_";"))
 .Set:Node="S" STypes=STypes_";"_Type
 .Set:Node="R" RTypes=RTypes_";"_Type
 Set:$L(STypes) STypes=STypes_";"
 Set:$L(RTypes) RTypes=RTypes_";"
 Do FETCH("S",DatVan,DatTot,STypes,.ZoekExec)
 Do FETCH("R",DatVan,DatTot,RTypes,.ZoekExec)
 Do FETCHLOG(DatVan,DatTot,.ZoekExec):Types["LOG"
 Do FETCHEWL(DatVan,DatTot,.ZoekExec):Types["EWL"
 Quit
 ;
FILE
 New Dir,FileNm,Dev,Node,RecL,Key,I,Cnt
 If $G(FileMark) Write "Reeds verstuurd" Quit
 Read "Bent u zeker om deze gegevens te versturen V[]=versturen ?",K 
 Quit:(K'="V")&(K'="v")
 ; Test file mark
 Lock +^EWREC("S")
 Set Dir=##class(TECH.Config.ConfigMgr).Instance().GetString("WMSExchange_RootDir")_^EWREC("P","DIRS")
 Set FileNm=$$GetFileNm^EWORDSW()_".txt"
 Set Dev=0
 Set Dev=$$OPEN^vhDEV(Dir,FileNm,"W","M")
	Set Cnt=""
	For  Set Cnt=$O(^HULP(%J,"L",Cnt)) Quit:Cnt=""  Do
	. Set RecL=^HULP(%J,"L",Cnt)
	. Set Node="S"
	. Set Key=$P(RecL,D,2)
	. Set VolgNr=$P(RecL,D,3)
	. Set Rec=$G(^EWREC(Node,Key,VolgNr))
	. If Rec=""  For I=1:1:$O(^EWREC(Node,Key,VolgNr,""),-1) Set Rec=Rec_^(I)
	. Write Rec,!
 Close:Dev'=0 Dev
 Set FileMark=1
 Write "File transferd ",FileNm," (Druk op ENTER)" Read K
 Lock -^EWREC("S")
 Quit
	
FETCH(Node,DatVan,DatTot,Types,ZoekExec) 
 New OFI,ENI,Cnt,ENCnt,VolgNr,Key,Tot,Rec
 Quit:'$L(Types)
 Set Cnt=$O(^HULP(%J,"L",""),-1)
 Set Key="" Do ADDDAT^EWRECS(.Key,DatVan,14) Set $E(Key,9,14)="000000"
 Set:DatTot="" DatTot=$H
 Set Tot="" Do ADDDAT^EWRECS(.Tot,DatTot,14) Set $E(Tot,9,14)="999999"
 For  Set Key=$O(^EWREC(Node,Key)) Quit:Key=""!(Key>Tot)  Do
 .Set VolgNr=""
 .For  Set VolgNr=$O(^EWREC(Node,Key,VolgNr)) Quit:VolgNr=""  Do
 ..Set Rec=$G(^EWREC(Node,Key,VolgNr))
 ..If Rec=""  For I=1:1:$O(^EWREC(Node,Key,VolgNr,""),-1) Set Rec=Rec_^(I)
 ..Quit:Types'[$E(Rec,1,3)
 ..Quit:'$$CHECK(Rec,.ZoekExec) 
 ..Set Cnt=Cnt+1
 ..Set ^HULP(%J,"L",Cnt)=Node_D_Key_D_VolgNr_D_$E(Rec,1,132)
 Quit
 
 
FETCHEWL(DatVan,DatTot,ZoekExec) 
 Set DatVan=DatVan-1
 Set Cnt=$O(^HULP(%J,"L",""),-1)
 Set VolgNr=""
 For  Set DatVan=$O(^EWLOG(DatVan)) Quit:DatVan=""!(DatVan>DatTot)  Do
 .For  Set VolgNr=$O(^EWLOG(DatVan,VolgNr)) Quit:VolgNr=""  Do
 ..Set Rec=^EWLOG(DatVan,VolgNr)
 ..Quit:'$$CHECK(Rec,.ZoekExec) 
 ..Set Cnt=Cnt+1
 ..Set ^HULP(%J,"L",Cnt)="EWL"_D_DatVan_D_VolgNr_D_$$EXTTIME^vhDTyp($P(Rec,"`",2))_"-"_$TR($P(Rec,"`",3)_$P(Rec,"`",4),"`","-")
 Quit
 
FETCHLOG(DatVan,DatTot,ZoekExec) 
 Set DatVan=DatVan-1
 Set Cnt=$O(^HULP(%J,"L",""),-1)
 Set VolgNr=""
 For  Set DatVan=$O(^LOG(DatVan)) Quit:DatVan=""!(DatVan>DatTot)  Do
 .For  Set VolgNr=$O(^LOG(DatVan,VolgNr)) Quit:VolgNr=""  Do
 ..Set Rec=^LOG(DatVan,VolgNr)
 ..Quit:'$$CHECK(Rec,.ZoekExec) 
 ..Set Cnt=Cnt+1
 ..Set ^HULP(%J,"L",Cnt)="LOG"_D_DatVan_D_VolgNr_D_$$EXTDATE^vhDTyp(DatVan,"DK")_" "_$$EXTTIME^vhDTyp($P(Rec,D,4))_" - "_$TR($P(Rec,D,1,3)_D_$P(Rec,D,5),D," - ")
 Quit
 
CHECK(Rec,ZoekExec) 
 New ENCnt,OFI,ENI
 ;ZoekExec via .Local
 Set ENCnt=1
 For OFI=1:1:$O(ZoekExec(""),-1) Do  Quit:ENCnt
 .Set ENCnt=1
 .For ENI=1:1:$O(ZoekExec(OFI,""),-1) Do
 ..If Rec'[ZoekExec(OFI,ENI)!'$L(ZoekExec(OFI,ENI)) Set ENCnt=0
 Quit ENCnt
 
 ;
SHOWDTL(Select) 
 New L,Node,Dat,VolgNr
 Set Rec=$G(^HULP(%J,"L",Select))
 Quit:Rec="" ""
 If $P(Rec,D,1)="LOG"!($P(Rec,D,1)="EWL") Write *7 Quit ""
 Set Node=$P(Rec,D)
 Set Dat=$P(Rec,D,2)
 Set VolgNr=$P(Rec,D,3)
 Set Type=$E($P(Rec,D,4),1,3)
 Do FETCHDTL(Node,Dat,VolgNr)
 Do INIT^vhLIST("EWRECL","DTL",.L)
 Do STORE^vhTERMINA(1,24)
 Do WRITE^vhLIST(.L)
 For  Set Input=$$SCROLL^vhLIST(.L) Do  Quit:$L(Input)
 .If Input="(",LD("SELECT")=1 Write *7 Set Input=""
 .If Input=")",LD("SELECT")=LD("MAX") Write *7 Set Input=""
 Do REFRESH^vhTERMINA(1,24)
 Quit $S(Input="(":-1,Input=")":+1,1:"")
 ;
FETCHDTL(Node,Dat,VolgNr) 
 New C,I,Rec
 Kill ^HULP(%J,"D")
 Set Rec=$G(^["ADMIN1"]EWREC(Node,Dat,VolgNr))
 If Rec=""  For I=1:1:$O(^["ADMIN1"]EWREC(Node,Dat,VolgNr,""),-1) Set Rec=Rec_^(I)
 Do TRANSREC^EWRECR(Rec,$E(Rec,1,3))
 For VolgNr=1:1:$O(^EWREC("D",C,VolgNr),-1) Do                
 .Set Rec=^EWREC("D",C,VolgNr)   
 .Set Value=$G(C($P(Rec,D)))       
 .If $P(Rec,D,3)="DT" Set Rec=Rec_D_Value_" - "_$$EXTDATE^vhDTyp(Value)_" "_$$EXTTIME^vhDTyp(Value)
 .Else  If $P(Rec,D,1)["PRNR" Set Rec=Rec_D_Value_$S(Value:" - "_$P($G(^KPR(Value,0),"Onbekend"),D),1:"")
 .Else  Set Rec=Rec_D_Value_"-"
 .Set ^HULP(%J,"D",VolgNr)=Rec
 Quit
 ;
INIT 
 New OFI,ENI
 Do INIT^vhTERMINA
 Set %J=$G(%J,$$%J^vhRtn1())
 Kill ^HULP(%J)
 Set DatVan=$G(DatVan,$H),DatTot=$G(DatTot,$H),Types=$G(Types,"")
 For OFI=1,2 For ENI=1:1:3 Set Zoek(OFI,ENI)=$G(Zoek(OFI,ENI),""),Zoek(OFI,ENI,"S")=$G(Zoek(OFI,ENI,"S"),"")
 Quit
 
EDIT New OFI,ENI
 Do EDIT^vhScherm("EWRECL")
 Merge ZoekExec=Zoek
 For OFI=1:1:$O(ZoekExec(""),-1) Do
 .For ENI=1:1:$O(ZoekExec(OFI,""),-1) Do
 ..Kill:'$L($G(ZoekExec(OFI,ENI))) ZoekExec(OFI,ENI)
 Quit
 
TYPES(Types,Display) 
 New R,Type,Count
 Set Types=$G(Types),Display=$G(Display)
 If Display Do
 .Quit:Types=""
 .If $L(Types,";")=1 Set R=$G(^EWREC("D",Types),$S(Types="EWL":"WMS Log",Types="LOG":"Administratie log",1:"")) Set:$L(R) Types=Types_D_$P(R,D)
 Else  Do
 .Set Type="",Count=0
 .Set Count=Count+1,Types(Count)="LOG`Administratie log"
 .Set Count=Count+1,Types(Count)="EWL`WMS Log"
 .Set Count=Count+1,Types(Count)="&S"
 .For  Set Type=$O(^EWREC("D",Type)) Quit:Type=""  Do
 ..Set R=^EWREC("D",Type)
 ..Set Count=Count+1,Types(Count)=Type_"`"_$P(R,D)
 .Set Types=$$WILD^vhPOPUP("C;C","-1KOMB","Types",.Types,Types)
 Quit Types
 ;
PRINT 
 New PLD
 Do INIT^vhLISTO("EWRECL","LOGGING",.PLD)
 Set PLD(1)=$NA(^HULP(%J))
 Set PLD(5)=132
 Set PLD(10)=""
 Set PLD(11)="Overzicht logging WMS"
 Do PRINT^OUTPUT(.PLD,"P")
 Quit
 ;