FALIDV ;Afdrukken fakturen van (CEMIK) klanten ; [ 11/07/2001  2:29 PM ]
 ; Lid van inkoopcombinatie
 ;
 Do INIT,REFRESH,KRITERIA
 Do COMMAND
 Kill ^HULP(%J)
 Lock
 Quit
 ;
COMMAND Set Input=""
 For  Quit:Input="-"  Quit:Input="CANC"  Do
 .Do REFRESH
 .Do SL^PROC
 .Set Input=R
 .If Input="COM" Set Input="" Do CALL^vhMenu("FALIDV")
 .Set:Input="-" Input="CANC"
 .Do EXEC^vhMenu("FALIDV",.Input)
 Quit
 ;
FETCH 
 New R,KlantId,KLNr,KlNaam,LidVan,FANr,Begin,Einde,Count,Munt,FaktDat,Bedrag,BedrBhM
 Kill ^HULP(%J)
 Set (KlantId,Count)=0
 For  Set KlantId=$O(^KKL(KlantId)) Quit:KlantId=""  Do
 .Set R=^KKL(KlantId,1),LidVan=$P(R,D,13)
 .If LidVan'=$P(Kriteria,D),$P(LidVan,"+",2)'=$P(Kriteria,D) Quit
 .Set R=^KKL(KlantId,0),KLNr=$P(R,D),KlNaam=$P(R,D,2)
 .Set Begin=-$P(Kriteria,D,2)+1,Einde=-$P(Kriteria,D,3)
 .For  Set Begin=$O(^KFA1("F",KLNr,Begin),-1) Quit:Begin=""  Quit:Begin<Einde  Do
 ..Set FANr=""
 ..For  Set FANr=$O(^KFA1("F",KLNr,Begin,FANr)) Quit:FANr=""  Do
 ...Set R=^KFA("F",FANr,0,0),Munt=$P(R,D,5),FaktDat=$P(R,D,6),Bedrag=$P(R,D,12),BedrBhM=$P(R,D,14)
 ...Set Munt=$$MUNT^vhRtn1(Munt,1)
 ...Set R=KLNr_D_KlNaam_D_FANr_D_FaktDat_D_BedrBhM_D_Bedrag_D_Munt
 ...Set Count=Count+1,^HULP(%J,Count)=R
 Quit
 ;
INIT 
 Set %J=$$%J^vhRtn1()
 Kill ^HULP(%J)
 Set Kriteria=""
 Do INIT^PROC("FALIDV",.LD),ADD^vhScherm(1,24)
 Quit
 
RPLKL Quit:'LD("MAX")
 Set KLNr=$P($G(^HULP(%J,LD("SELECT"))),D,2)
 Quit:'KLNr
 Set Aktie=$$RAADPL^KLANT(KLNr,$P($G(Aktie),D))
 Do ADD^vhScherm(1,24)
 Quit
 ;
KRITERIA 
 New %SC,OldKrit
 Set OldKrit=Kriteria
 If Kriteria="" Do
 .Set Kriteria="CEMIK" ;_D_$$INTDATE^vhDTyp("01.11.99")_D_$$INTDATE^vhDTyp("01.02.00")
 .Do NIEUW^vhScherm("FALIDV")
 .Set %SC=1
 Else  Do EDIT^vhScherm("FALIDV")
 If %SC,Kriteria'=OldKrit Do
 .Do INIT^PROC("FALIDV",.LD),ADD^vhScherm(1,24)
 .Kill ^HULP(%J)
 .Do REFRESH
 .Do FETCH
 .Do ADD^vhScherm(1,24)
 Quit
 ;
REFRESH 
 If sRT<4 Do DISPLAY^vhScherm("FALIDV","","","H")
 If sRB>3 Do WL^PROC
 Do WL^PROC
 Do RESET^vhScherm
 Quit
 ;
TRANS 
 Do ^OUTPUT("T","-","S;L;B")
 Quit
 ;
Locals(List) 
 New I
 For I=1:1:$L(List,",") Set $P(List,",",I)=""""_$P(List,",",I)_""""
 Xecute "For Locals="_List_" Set Locals(Locals)=@Locals"
 Quit
 ;