FLOWLOG ;Logging van akties [ 06/28/2000  4:33 PM ]
 ;
ABT(TOENr) 
 New R,LEVNr,ToeDat
 Set LEVNr=$P(^KTO1(TOENr),D),R=^KTO(LEVNr,TOENr,1),ABNr=$P(R,D,10)
 Do:ABNr'=""
 .Set ToeDat=$P(R,D,2),ToeDat=$$INTDATE^vhDTyp(ToeDat)
 .Set R="ABT\"_LEVNr_D_TOENr_D_ToeDat_D_$P($H,",")
 .Do PUTLOG(R)
 Quit
 ;
RLT(RCPNr) 
 New R,LEVNr,TOENr,TLUNr,PRNr,ToeDat,RCPTyp,RCPDat,WMSStat,LTA,LTB,LCompl,TLNr,ToeAant,RCPAant
 Set R=^RCP("D",RCPNr),RCPTyp=$P(R,D),RCPDat=$P($P(R,D,4),","),TOENr=""
 If RCPTyp="L" For  Set TOENr=$O(^RCP("D",RCPNr,"D",TOENr)) Quit:TOENr=""  Do
 .Set LEVNr=$P($G(^KTO1(TOENr)),D)
 .Quit:'LEVNr
 .Set R=^KTO(LEVNr,TOENr,1)
 .Set ToeDat=$P(R,D,2),ToeDat=$$INTDATE^vhDTyp(ToeDat)
 .Set TLUNr=""
 .For  Set TLUNr=$O(^RCP("D",RCPNr,"D",TOENr,TLUNr)) Quit:TLUNr=""  Do
 ..Set R=^RCP("D",RCPNr,"D",TOENr,TLUNr),PRNr=$P(R,D),WMSStat=$P(R,D,2),RCPAant=$P(R,D,4)
 ..Quit:$L(WMSStat)
 ..Set TLNr=^TO("IU",TOENr,TLUNr),R=^KTO(LEVNr,TOENr,TLNr),ToeAant=$P(R,D,3),LTB=$P(R,D,25),LTA=$P(R,D,29)
 ..Set:LTA="" LTA=LTB Set LTA=$$INTDATE^vhDTyp(LTA,"DW"),LTB=$$INTDATE^vhDTyp(LTB,"DW")
 ..Set R="RLT\"_PRNr_D_TOENr_D_RCPNr_D_ToeDat_D_LTA_D_LTB_D_RCPDat_D_(RCPAant=ToeAant)
 ..Do PUTLOG(R)
 Quit
 ;
NEXTID() 
 New LogNr
 Lock +^FLOWLOG Set LogNr=$G(^FLOWLOG)+1,^FLOWLOG=LogNr Lock -^FLOWLOG
 Quit LogNr
 ;
PUTLOG(Rec) 
 New LogNr
 Set LogNr=$$NEXTID(),^FLOWLOG(+$H,LogNr)=Rec
 Quit
 ;