FOLTECIM ;Produkt duplicering voor FolieTec deuren[ 04/03/2003  9:57 AM ]
 Quit  ; Moet aangepast worden op de nieuwe FOLTEC global
 Set Dev=$$OPEN^vhDEV($$DIRUSER^vhDEV,$$ASKFILE^vhDEV("SPECIAL.TXT"),"R")
 Quit:0[Dev
 For  Use Dev Read Rec Quit:$ZC=-1  Do
 .Use 0
 .Quit:Rec=""
 .Set KLNr=$$UPTRIMAN^vhRtn1($P(Rec,$C(9),1))
 .Quit:'$D(^KK1(KLNr))
 .Set Hoogte=$$TRIMN^vhRtn1($P(Rec,$C(9),2))
 .Set Breedte=$$TRIMN^vhRtn1($P(Rec,$C(9),3))
 .Set Front=$$UPTRIMAN^vhRtn1($P(Rec,$C(9),4))
 .Set:Front="" Front="D"
 .Do DEFINE
 Close Dev
 Quit
 
DEFINE Set (KeyD,Key)=Hoogte_"x"_Breedte 
 Set:Front'="D" Key=Key_Front
 Set Type=""
 Set Klant=""
 Write !,KLNr,$C(9),Key
 For  Set Klant=$O(^FOLTEC("T",Klant)) Quit:Klant=""  Do  Quit:Type'=""
 .If $D(^FOLTEC("T",Klant,Key)) Do
 ..Set Type=$P(^FOLTEC("T",Klant,Key),D,2)
 ..Set MemKlant=Klant
 If Type="",Front'="D" Do  ; Proberen van afm. type bij deuren
 .Set Type=""
 .Set Klant=""
 .For  Set Klant=$O(^FOLTEC("T",Klant)) Quit:Klant=""  Do  Quit:Type'=""
 ..If $D(^FOLTEC("T",Klant,KeyD)) Do
 ...Set Type=$P(^FOLTEC("T",Klant,KeyD),D,2)
 ...Set MemKlant=Klant
 Set:Type="" Type=$$NEXTID^FOLTECT(),MemKlant=9999 ; Nieuw afm. type  bijvoegen
 Write $C(9),Type,$C(9),MemKlant
 Write:MemKlant=9999 $C(9),"nieuw"
 Set ^FOLTEC("T",KLNr,Key)=D_Type_D_Front
 Quit
 
EXPKLANT(KLNr,XLS) 
 Write @F11,@F1,@FMTI," Export spec. maten voor FolieTec klanten - ",QN," ",@FMTi
 ;Set:'$G(KLNr) KLNr=$$SELECT^KLANT6()
 ;Quit:'KLNr
 Set KLNr=0
 Quit:'$D(^FOLTEC("T",KLNr))
 Set FP=1501
 Write @F,@F1," Klant: ",KLNr," ",$S(KLNr:$P(^KKL(^KK1(KLNr),0),D,2),1:"Standaard")
 Set Dev=$$OPEN^vhDEV($$DIRUSER^vhDEV,$$ASKFILE^vhDEV($$UPTRIMAN^vhRtn1($S(KLNr:$P(^KKL(^KK1(KLNr),0),D,2),1:"Fol_Std"))_".TXT"),"W")
 Quit:0[Dev
 Use Dev
 Set KLNaam=$S(KLNr:$P(^KKL(^KK1(KLNr),0),D,2),1:"Standaard")
 Write KLNr,$C(9),KLNaam,!
 Write $TR("Type,Hoogte,Breedte",",",$C(9)),!
 Set Taal=$S(KLNr:$P(^KKL(^KK1(KLNr),0),D,9),1:"N")
 Set:Taal'="F" Taal="N"
 Set Key=""
 Set XLS=$G(XLS)
 Kill Hulp
 For  Set Key=$O(^FOLTEC("T",KLNr,Key)) Quit:Key=""  Do
 .Set Rec=^FOLTEC("T",KLNr,Key)
 .Set Hoogte=$P(Rec,D,1)
 .Set Breedte=+$P(Rec,D,2)
 .Set BasisType=$P(Rec,D,3)
 .Set Type=$P(Rec,D,4)
 .Set VolgNr=+^RES("FOLTEC","PI","FRONTDTL","D",Type)
 .Set Hulp(VolgNr,Hoogte,Breedte)=Key_D_Type_D_BasisType
 Set (VolgNr,Hoogte,Breedte,MemOms)=""
 For  Set VolgNr=$O(Hulp(VolgNr)) Quit:VolgNr=""  Do
 .For  Set Hoogte=$O(Hulp(VolgNr,Hoogte)) Quit:Hoogte=""  Do
 ..For  Set Breedte=$O(Hulp(VolgNr,Hoogte,Breedte)) Quit:Breedte=""  Do
 ...Set Key=$P(Hulp(VolgNr,Hoogte,Breedte),D)
 ...Set Type=$P(Hulp(VolgNr,Hoogte,Breedte),D,2)
 ...Set BasisType=$P(Hulp(VolgNr,Hoogte,Breedte),D,3)
 ...Set:Type="D" Type=$$FRONT^FOLTEC(Hoogte)
 ...If XLS  Do  ; Voor opname in excel
 ....Set:Type="T" Type="D" ; Twijfel-geval : Deur/Ladefront
 ....Write BasisType,";",Type,";",Hoogte,";",Breedte,$C(9),Key,!
 ...Else  Do
 ....Set FrontOms=$P($G(^RES("FOLTEC","PI","FRONTDTL","D",Type,Taal),Type),"`")
 ....Write:MemOms'=FrontOms FrontOms
 ....Write $C(9),Key,$C(9),Hoogte," x ",Breedte," mm",!
 ....Set MemOms=FrontOms
 Close Dev
 Quit
 
EXPALL Quit  ; Moet aangepast worden op de nieuwe foltec global
 Set Dev=$$OPEN^vhDEV($$DIRUSER^vhDEV,$$ASKFILE^vhDEV("TRANSFERT.TXT"),"W")
 Quit:0[Dev
 Use Dev
 Set KLNr="",Key=""
 Set Max=-1
 Write $TR("Front,Type,Hoogte,Breedte",",",$C(9)),!
 For  Set KLNr=$O(^FOLTEC("T",KLNr)) Quit:KLNr=""  Do
 .Set KLNaam=$S(KLNr:$P(^KKL(^KK1(KLNr),0),D,2),1:"Standaard")
 .For  Set Key=$O(^FOLTEC("T",KLNr,Key)) Quit:Key=""  Do
 ..Set Type=$P(^FOLTEC("T",KLNr,Key),D,2)
 ..Set Front=$$UPTRIMA^vhRtn1($P(Key,"x",2))
 ..Set:Front="" Front="D"
 ..Set Hoogte=$P(Key,"x",1)
 ..Set Breedte=+$P(Key,"x",2)
 ..Set:Max<Type Max=Type
 ..Write KLNr,$C(9),KLNaam,$C(9),Type,$C(9),Front,$C(9),Hoogte,$C(9),Breedte,!
 Close Dev
 Quit