KPHPR ;STOCKEREN HUIDIGE PRIJZEN KLANTEN ;KPHPR; [ 09/01/93  1:30 PM ]
 ;
NOSA
 Do DISPLAY^vhScherm("KPHPR")
 Lock +^KPHPR("N"):3 Else  Xecute ^cTXT(0,"N",14) Read R Quit
 Lock +^KPHPR("S"):3 Else  Xecute ^cTXT(0,"N",14) Read R Quit
 Do FIELD^vhScherm("KPHPR","GO")
 Job:%SC JOB^KPHPR($J)
 Quit
 ;
INIT
 Set Go=""
 Set NAangemaakt=$G(^KPHPR("N",0)),SAangemaakt=$G(^KPHPR("S",0))
 For Field="ALLCUST","VOLASSORT","HSPRIJZEN","BGROUNDJOB","AANGEMAAKT","AANMAAKTYD" Do REMATTR^vhScherm(Field,"H","H")
 Quit
 ;
JOB(JobId)
 New (JobId)
 Do
 . New JobId
 . Set Q="K"
 . Do ^cA604
 Lock +^KPHPR("N"),+^KPHPR("S")
 Set Start=$H
 Kill ^KPHPR("N"),^KPHPR("S")
 Set KlKey=0
 For  Set KlKey=$O(^KKL(KlKey)) Quit:KlKey=""  Do
 . Set KLNr=$P(^KKL(KlKey,0),D),PRNr=0
 . For  Set PRNr=$O(^KSTKL(KLNr,PRNr)) Quit:PRNr=""  Do
 ..  Set KortTekst=$P($G(^KPR(PRNr,0)),D)
 ..  Quit:KortTekst=""
 ..  Set IdentNr=$P(^KPR(PRNr,2),D,25)
 ..  For NoSa="N","S" Do
 ...   Set KPrijs=$$KLANTPR^KPRIJS(KLNr,PRNr,NoSa)
 ...   Set Prijs=$P(KPrijs,D,1),Munt=$P(KPrijs,D,2),GrOrde=$P(KPrijs,D,3)
 ...   Set ^KPHPR(NoSa,KLNr,PRNr)=IdentNr_D_KortTekst_D_Prijs_D_Munt_D_GrOrde_D_PRNr_D
 Set ^KPHPR("N",0)=Start_D_$H,^KPHPR("S",0)=Start_D_$H
 Lock -^KPHPR("N"),-^KPHPR("S")
 Do:$G(JobId)
 . Set Message="**** Stockeren huidige- en schaduwprijzen afgelopen ****"
 . Set End=$ZUTIL(94,JobId,Message)
 Quit
 ;