PVBALANS ;Exporteren van de proefbalans [ 11/08/2003   8:40 PM ]
ONE Set RekNr="099999 "
 Read !,"Welk boekjaar (4 cijfers) : ",BJaar
 Read !,"Aantal kwartalen (1 tot 4) : ",Kwart
 Set HBJaar=$$EXTDATE^vhDTyp($$CALCDATE^vhDTyp($H,"BJ","LD"),"J4")
 Quit:HBJaar<BJaar
 Quit:HBJaar-10>BJaar
 Set Dev=0
 Set Dev=$$OPEN^vhDEV(,"PROEFBALANS.TXT","W")
 Use Dev
 Write "RekNr",$C(9),"Omschrijving",$C(9),"BJ",BJaar,".",Kwart,!
 For  Set RekNr=$O(^KAR(RekNr)) Quit:RekNr=""  Do:RekNr?6N1" "
 . Set J1=RekNr
 . Set B(1)=^KAR(RekNr,0)
 . ;Kwartaal gegevens ophalen
 . Set R1=HBJaar-BJaar
 . Set R2=$P("1\2\3\4","\",1,Kwart)
 . Set R3="AR"
 . Set R4="S"
 . Do 4^cANT79
 . Set Som=K ; Kwartaal
 . ; Beginsaldo ophalen
 . Set R1=HBJaar-BJaar
 . Set R3="AR"
 . Set R4="B"
 . Do 2^cANT79
 . Set Som=Som+K ; Kwartaal + Beginsaldo
 . Quit:'Som
 . Write $P(B(1),D,1),$C(9),$P(B(1),D,2),$C(9),$TR(Som,".",","),!
 Close:Dev'=0 Dev
 Quit
 
ALL Set RekNr="099999 "
 Read !,"Begin Boekjaar : ",BBJaar
 Read !,"Eind boekjaar : ",EBJaar
 Set Kwart=4
 Set HBJaar=$$EXTDATE^vhDTyp($$CALCDATE^vhDTyp($H,"BJ","LD"),"J4")
 Set Dev=0
 Set Dev=$$OPEN^vhDEV(,"PROEFBALANSALL.TXT","W")
 Use Dev
 Write "RekNr",$C(9),"Omschrijving"
 For BJaar=EBJaar:-1:BBJaar Write $C(9),"BJ",BJaar
 Write !
 For  Set RekNr=$O(^KAR(RekNr)) Quit:RekNr=""  Do:RekNr?6N1" "
 . Kill Som
 . For BJaar=BBJaar:1:EBJaar Do
 .. Set J1=RekNr
 .. Set B(1)=^KAR(RekNr,0)
 .. Set R1=HBJaar-BJaar
 .. Set R3="AR"
 .. Set R4="S"
 .. Do 2^cANT79
 .. Quit:'K
 .. Set Som(BJaar)=K
 . Quit:'$D(Som)
 . Write $P(B(1),D,1),$C(9),$P(B(1),D,2)
 . For BJaar=EBJaar:-1:BBJaar Do
 .. Write $C(9),$TR($G(Som(BJaar)),".",",")
 . Write !
 Close:Dev'=0 Dev
 Quit