PVBON ;Leveringsbonnen geextraheerd uit fakturen met sommatie van de lijnen [ 11/08/2003   8:40 PM ]
STAT ; Statistiek verkoop KFA
 Set Dev=0
 Set Dev=$$OPEN^vhDEV(,"BONTRANSP.TXT","W")
 Use Dev
 Set PRNr=0
 Write $TR("KLNr,KLNm,Codex,Regio,Land,DefVzw,FAKNr,FaktDat,BonNr,BonDat,Vzw,#LijnPos,#CntNeg,#CntZndWMS,Omzet,Aankoop,Gewicht,TransNr,TransBon,#Collie,#Europal,#Langoed",",",$C(9)),!
 Set FAKNr=10000
 Set Glob=$NA(^KFAP)
 For  Set FAKNr=$O(@Glob@("F",FAKNr)) Quit:FAKNr=""  Quit:FAKNr>20000  Do
 .Set KLNr=$P(@Glob@("F",FAKNr,0,0),D,1)
 .Quit:'$D(^KK1(KLNr))
 .Set Dat=$P(@Glob@("F",FAKNr,0,0),D,6)
 .Set KLId=$G(^KK1(KLNr),"*")
 .Set KLNm=$P($G(^KKL(KLId,0)),D,2)
 .Set Regio=$P($G(^KKL(KLId,0)),D,20)
 .Set Land=$P($G(^KKL(KLId,0)),D,8)
 .Set Codex=$P($G(^KKL(KLId,2)),D,3)_$S($D(^KLPUTZ("N",KLNr)):"+",1:"")
 .Set DefVzw=$$DEFAULT^KLVERZW(,KLNr)
 .Set Port=$P($P(@Glob@("F",FAKNr,0,0),D,17),"#",2)
 .Set (CntPos,CntNeg,CntZndWMS,Omzet,Aankoop,Gewicht)=0
 .Set ULNr="U"
 .For  Set ULNr=$O(@Glob@("F",FAKNr,ULNr)) Quit:ULNr=""  Do
 ..Set LNr=99
 ..Set ULDat=$P(@Glob@("F",FAKNr,ULNr,1),D,2)
 ..Set Vzw=$P($P(@Glob@("F",FAKNr,ULNr,1),D,7),"#")
 ..Set TransKey=$P(@Glob@("F",FAKNr,ULNr,1),D,8)
 ..Set (TransNr,TransBon,ColC,ColE,ColL)=""
 ..If TransKey[";" Do
 ...Set TransNr=$P(TransKey,";")
 ...Set TransBon=$P(TransKey,";",2)
 ...Set ColC=+$G(^TRANSP("D",TransNr,"D",TransBon,"Q","C"))
 ...Set ColE=+$G(^TRANSP("D",TransNr,"D",TransBon,"Q","E"))
 ...Set ColL=+$G(^TRANSP("D",TransNr,"D",TransBon,"Q","L"))
 ...Set Vzw="DI1 "
 ..For  Set LNr=$O(@Glob@("F",FAKNr,ULNr,LNr)) Quit:LNr=""  Do
 ...Set RecF=@Glob@("F",FAKNr,ULNr,LNr)
 ...Set PRNr=$P(RecF,D,2)
 ...Quit:'PRNr
 ...Set:$P(RecF,D,3)>0 CntPos=CntPos+1
 ...Set:$P(RecF,D,3)<0 CntNeg=CntNeg+1
 ...Set:$P(RecF,D,14)["S"!$P(RecF,D,14)["Z" CntZndWMS=CntZndWMS+1
 ...Set Omzet=Omzet+$P(RecF,D,34)
 ...Set Aankoop=Aankoop+$P(RecF,D,33)
 ...Set Gew=$P($G(^KPR(PRNr,1)),D,13)
 ...Set:'Gew Gew=$P($G(^KPRO(PRNr,1)),D,13)
 ...Set Gewicht=Gewicht+(Gew*$P(RecF,D,3)/1000)
 ..Write KLNr,$C(9),KLNm,$C(9),Codex,$C(9),Regio,$C(9),Land,$C(9),DefVzw,$C(9),FAKNr,$C(9),$TR(Dat,".","/"),$C(9),$E(ULNr,2,99),$C(9),$TR(ULDat,".","/"),$C(9),Vzw,$C(9),CntPos,$C(9),CntNeg,$C(9),CntZndWMS,$C(9),$J(Omzet,0,0),$C(9),$J(Aankoop,0,0),$C(9),$TR($J(Gewicht,0,1),".",",")
 ..Write $C(9),TransNr,$C(9),TransBon,$C(9),ColC,$C(9),ColE,$C(9),ColL
 ..Write !
 Close:0'[Dev Dev
 Quit