PVROYALC ;Royal Crown export lijsten [ 11/29/2003  1:44 PM ]
 ; Orgalux
PRODUCT ; Opbouw van een transferdocument met ALLE producten
 New KLNm,Dev,I,Rec
 Set Talen=$G(Talen,"NF")
 Set Dev=0
 Set KLNr=8197
 Set Dev=$$OPEN^vhDEV(,"ProductRC.txt","W")
 Use Dev
 Do TITEL
 Set PRNr=0
 For  Set PRNr=$O(^KPR(PRNr)) Quit:PRNr=""  Do
 .Quit:$P(^KPR(PRNr,0),D,3)?4.7N
 .
 .Do CLEAN
 .Set Merk="VANHOECKE"
 .Do FETCH(PRNr)
 .Quit:$P(Rec("I"),D,1)'["BX"&($P(Rec("I"),D,2)'["MON")&($P(Rec("I"),D,3)'["MAT/AG")
 .Do WRITE
 Close:0'[Dev Dev
 Quit
 
ORGALUX ; Opbouw van een transferdocument met ALLE ORGALUX producten
 New KLNm,Dev,I,Rec
 Set Talen=$G(Talen,"NF")
 Set Dev=0
 Set KLNr=8197
 Set Dev=$$OPEN^vhDEV(,"OrgaluxRC.txt","W")
 Use Dev
 Do TITEL
 Set (HG,GR,SG,KORTT)=""
 For  Set HG=$O(^KPH(HG)) Quit:HG=""  Do:HG["OL" 
 .For  Set GR=$O(^KPH(HG,GR)) Quit:GR=""  Do
 ..Quit:GR["SHR"  ;Showroom
 ..Quit:GR["BRO"  ;Brochures
 ..Quit:GR["XXX"  ;Brochures
 ..For  Set SG=$O(^KPH(HG,GR,SG)) Quit:SG=""  Do
 ...For  Set KORTT=$O(^KPH(HG,GR,SG,"  ",KORTT)) Quit:KORTT=""  Do
 ....Set PRNr=^KPH(HG,GR,SG,"  ",KORTT)
 ....Do CLEAN
 ....Set Merk="ORGALUX"
 ....Do FETCH(PRNr)
 ....Do WRITE
 Close:0'[Dev Dev
 Quit
 
TITEL Write $TR("SortKey;ArtNr;TypeNr;BestelNr;Prijs;OmsN1;OmsN2;OmsN3;OmsF1;OmsF2;OmsF3;KleurN;KleurF;KlasHGN;KlasHGF;KlasGRN;KlasGRF;KlasSGN;KlasSGF;VerpakG;VerpakN;VerpakSt;PictRef;TechRef;Merk;Maat;KastBr;WandDikte;Stock;MinBH;LevTrm",";",$C(9)),!
 Quit
 
CLEAN Kill Oms
 Set (SortKey,ArtNr,TypeNr,BestelNr,Prijs,KleurN,KleurF,KlasHGN,KlasHGF,KlasGRN,KlasGRF,KlasSGN,KlasSGF,VerpakG,VerpakN,VerpakSt,PictRef,TechRef,Merk,Maat,KastBr,WandDikte,Stock,MinBH,LevTrm)=""
 Quit
 
FETCH(PRNr) 
 New I,Txt,Cnt
 Do FETCHPR^UTILI(PRNr,"Rec")
 Do VANNAAR^vhTERMINA("P")
 Set SortKey=$$SORTKEY^PRODUKT(PRNr)
 Set TypeNr=$E($P(Rec(0),D),$S(Merk="ORGALUX":4,1:1),99)
 Set ArtNr=$$UPTRIMAN^vhRtn1(TypeNr)
 Set BestelNr=$P(Rec(2),D,25)
 Set:Merk="ORGALUX" PictRef=$$TEKREF(PRNr)
 For I=1:1:$L(Talen) Do
 . Set Taal=$E(Talen,I)
 . Set:Taal="N" List="0.2,0.11,6.1,6.2,6.3"
 . Set:Taal="F" List="1.22,3.21,8.1,8.2,8.3"
 . Set:Taal="D" List="2.2,3.23,10.1,10.2,10.3"
 . Set:Taal="E" List="2.1,3.22,12.1,12.2,12.3"
 . Set Cnt=0
 . For J=1:1:$L(List,",") Do
 .. Set Node=$P($P(List,",",J),".",1)
 .. Set Piece=$P($P(List,",",J),".",2)
 .. Set Txt=$P($G(^KPR(PRNr,Node)),D,Piece)
 .. Quit:Txt=""
 .. Set Cnt=Cnt+1
 .. Set Oms(Taal,Cnt)=Txt
 Set KlasHGN=$P(^KPHG1($P(Rec("I"),D,1)),D)
 Set KlasGRN=$P(^KPGR1($P(Rec("I"),D,2)),D)
 Set KlasSGN=$P(^KPSG1($P(Rec("I"),D,3)),D)
 Set Kleur=$E($P(Rec(0),D,1),22,25)
 If $L(Kleur),$D(^KCOL(Kleur_" ")) Do
 .Set KleurN=$G(^KCOL(Kleur_" ","N"))
 .Set KleurF=$G(^KCOL(Kleur_" ","F"))
 Set VerpakG=$P(Rec("J"),D,16) ; Export tandembox
 Set VerpakN=$P(Rec("J"),D,15) ; export tandembox
 ;Set VerpakG=$P(Rec("J"),D,12) ; royal crown
 ;Set VerpakN=$P(Rec("J"),D,11) ; royal crown
 Set VerpakSt=1
 Set Stock=$S($P(Rec(1),D,20):"S",1:"N")
 If Stock="N" Do
 .Set LevTrm=$P(Rec("J"),D,7)
 .Set MinBH=$P(Rec("J"),D,6)
 Set Prijs=$$KLANTPR^KPRIJS(KLNr,PRNr)
 Set Prijs=$J($P(Prijs,D,1)/$P(Prijs,D,11),0,4) ; Prijs steeds per stuk met 4 cijfers na de comma
 Quit
 
WRITE Write SortKey,$C(9),ArtNr,$C(9),TypeNr,$C(9),BestelNr,$C(9),$TR(Prijs,".",","),$C(9)
 For T="N","F" For I=1:1:3 Do
 .Write $G(Oms(T,I)),$C(9)
 Write KleurN,$C(9),KleurF,$C(9),KlasHGN,$C(9),KlasHGF,$C(9),KlasGRN,$C(9),KlasGRF,$C(9),KlasSGN,$C(9),KlasSGF,$C(9),VerpakG,$C(9),VerpakN,$C(9),VerpakSt,$C(9),PictRef,$C(9),TechRef,$C(9),Merk,$C(9),Maat,$C(9),KastBr,$C(9),WandDikte,$C(9),Stock,$C(9),MinBH,$C(9),LevTrm,!
 Quit
 
TEKREF(PRNr,Opties) 
 New TekRef
 Set TekRef=$P(^KPR(PRNr,0),D)
 Set TekRef=$E(TekRef,4,99)
 Set TekRef=$TR($E(TekRef,1,8),".# ","")
 Set:($E(TekRef,7,8)=16)!($E(TekRef,7,8)=18)!($E(TekRef,7,8)=19) $E(TekRef,7,8)="xx"
 Set:($E(TekRef,7,8)="IN")!($E(TekRef,7,8)="GR")!($E(TekRef,7,8)="WI") $E(TekRef,7,8)=""
 Quit $S($L(TekRef):TekRef_".Gif",1:"")