RPLFAKT ;Raadplegen fakturen [ 12/06/2003  1:13 PM ]
 d ^cA604
RPLF2 Set FANr=$$ASK^vhINP("Geef faktuur nummer",6,"400013")
 Quit:FANr="-"!(FANr=".")
 Set:$L(FANr)<6 FANr=400000+FANr
 Goto RPLF2:'$D(^KFA("F",FANr))
 Do LIJST(FANr)
 Goto RPLF2
 
LIJST(FANr,BeginPos) ; Fakturen detail
 New %J,KLNr,CC,FAD,R,Input,DL,Bruto,PRNr
 Set %J=$$%J^vhRtn1(),Input=""
 Kill ^HULP(%J)
 If FANr Do INIT For  Do  Quit:"\\(\)\UP\DO\"'[(D_Input_D)
 .Do WL^PROC 
 .Do SL^PROC
 .If R="COM" Do MENU^RPLKL4
 .If R="SPEC" Do SPEC^RPLKL4
 .Set Input=R
 .If Input="(" Set R=$$NEXT(KLNr,FANr,-1) If R Set FANr=R Do INIT
 .If Input=")" Set R=$$NEXT(KLNr,FANr,1) If R Set FANr=R Do INIT
 .If Input="PF"!(Input="PRINT") Do PRINT(FANr) Set Input=""
 .If Input="ENTER" Set Input=","
 .If Input="P" Do  Set Input=""
 ..Set PRNr=$P($G(^HULP($J,"K"_KLNr,"FD",FAD(6))),D,2)
 ..Quit:'PRNr
 ..Kill ^HULP(%J)
 ..Merge ^HULP(%J)=^HULP($J)
 ..Do STORE^vhTERMINA(),RAADPL^PRODUKT(PRNr),REFRESH^vhTERMINA()
 ..Merge ^HULP($J)=^HULP(%J)
 ..Kill ^HULP(%J)
 Quit Input
 
SHOW(FANr,BeginPos) ; Fakturen detail
 New %J,KLNr,CC,FAD,R,Input,DL,Bruto,PRNr
 Set %J=$$%J^vhRtn1(),Input=""
 Kill ^HULP(%J)
 If FANr Do INIT For  Do  Quit:"\\UP\DO\"'[(D_Input_D)
 .Do WL^PROC 
 .Do SL^PROC
 .Set Input=R
 .If Input="ENTER" Set Input=","
 .If Input="P" Do  Set Input=""
 ..Set PRNr=$P($G(^HULP($J,"K"_KLNr,"FD",FAD(6))),D,2)
 ..Quit:'PRNr
 ..Kill ^HULP(%J)
 ..Merge ^HULP(%J)=^HULP($J)
 ..Do STORE^vhTERMINA(),RAADPL^PRODUKT(PRNr),REFRESH^vhTERMINA()
 ..Merge ^HULP($J)=^HULP(%J)
 ..Kill ^HULP(%J)
 Quit Input
 
NEXT(KLNr,FANr,Dir) 
 New Dat
 Set Dat=$P(^KFA("F",FANr,0,0),D,6)
 Set Dat=-$$INTDATE^vhDTyp(Dat)
 Set FANr=$O(^KFA1("F",KLNr,Dat,FANr),Dir)
 Set:FANr="" Dat=$O(^KFA1("F",KLNr,Dat),Dir)
 Set:FANr=""&(Dat'="") FANr=$O(^KFA1("F",KLNr,Dat,FANr),Dir)
 Quit FANr
 
INIT New VNR,ULNr
 New U2,Rappel,Betwist
 Set KLNr=+^KFA("F",FANr,0,0)
 Kill ^HULP($J,"K"_KLNr,"FD")
 Set CC=$P(^KFA("F",FANr,0,3),D,23)
 Set Bruto=$P(^KFA("F",FANr,0,3),D,27)
 Set (FAD(9),VNR)=0
 Set U2=$G(^KKL(^KK1(KLNr),FANr)),Rappel=$P(U2,D,8),Betwist=$P(U2,D,23)
 Do:$L(Betwist)!Rappel
 . Set U2=$S($L(Betwist):$P($G(^RES("FLOWFACT","PI","RAPPELREDEN","D",Betwist)),"`",2),1:"")
 . Set:Rappel U2=U2_$S($L(U2):" - ",1:"")_"Rappels: "_Rappel
 . Quit:U2=""
 . Set U2="\\\\"_U2,$P(U2,D,17)="KF11",VNR=VNR+1,^HULP($J,"K"_KLNr,"FD",VNR)=U2
 Set ULNr="U"
 For  Set ULNr=$O(^KFA("F",FANr,ULNr)) Quit:ULNr=""  Do
 .Set:VNR VNR=VNR+1,^HULP($J,"K"_KLNr,"FD",VNR)=""
 .Set VNR=VNR+1,^HULP($J,"K"_KLNr,"FD",VNR)="U"_D_$E(ULNr,2,99)_D_^KFA("F",FANr,ULNr,1)
 .Set:CC $P(^HULP($J,"K"_KLNr,"FD",VNR),D,9)="CC #cash&carry"
 .Set:+^KFA("F",FANr,ULNr,3) VNR=VNR+1,^HULP($J,"K"_KLNr,"FD",VNR)=^KFA("F",FANr,ULNr,3)
 .Set ULL=100
 .For  Set ULL=$O(^KFA("F",FANr,ULNr,ULL)) Quit:ULL=""  Do
 ..Set U2=^KFA("F",FANr,ULNr,ULL)
 ..If $P($P(U2,D,17),"#")="KF11",$P($P(U2,D,18),";",4)'["F" Set $P(U2,D,5)=$C(171)_$P(U2,D,5)_$C(187)
 ..If $P($P(U2,D,17),"#")="KF1925" Set $P(U2,D,5)=$$KortTxt^FLOWMANL(U2) ; Manuele lijn
 ..Set VNR=VNR+1,^HULP($J,"K"_KLNr,"FD",VNR)=U2
 Quit:'VNR
 Do INIT^PROC("RPLFAKTPR","FAD")
 Set FAD(2,1)=^LD("L","RPLFAKTTXT")
 Set FAD(9)=VNR
 Set R=^KFA("F",FANr,0,0)
 Set FAD(8)="Factuur : "_$E(FANr,1,3)_"."_$E(FANr,4,6)_" van "_$P(R,D,6)_" bedrag goederen "_$$EXTNUM^vhDTyp($P(R,D,7),0,",",2)_" "_$S($P(R,D,5)="":$$FADEF^vhRtn1(),1:$P(R,D,5))
 Set:$P($P(R,D,17),"#",2) FAD(8)=FAD(8)_" incl. port "_$$EXTNUM^vhDTyp($P($P(R,D,17),"#",2),0,",",2)_" "_$S($P(R,D,5)="":$$FADEF^vhRtn1(),1:$P(R,D,5))
 Set FAD(3)=$S($D(BeginPos):BeginPos,1:8)
 Set FAD(4)=""
 Quit
 
CB(Nr,Ref) ; Callback
 If $P(Ref,D,17)="KF6" Quit ""
 If $P($P(Ref,D,17),"#")="KF1925" Quit ""
 If Ref="" Set FL(3,2)="      |" Quit 1
 If $P(Ref,D,17)="KF5" Do  Quit 1
 .New IPers
 .Set IPers=$P($P(Ref,D,4),"#")
 .Set:IPers?1.N IPers=$P($G(^vhUSER("D",IPers)),D,4)
 .Set FL(3,2)="Order | "_$$EXTNUM^vhDTyp($P($P(Ref,D,5)," - "),0,".",0)_" van "_$P($P(Ref,D,5)," - ",2)_" "_IPers_" - "_$P($P(Ref,D,5)," - ",3)
 .;Set FL(3,2)="Order | "_$E($P(Ref,D,5),1,3)_"."_$E($P(Ref,D,5),4,999)
 If $P($P(Ref,D,17),"#")="KF11" Set FL(3,2)="      | "_$P(Ref,D,5) Quit 1
 If $P(Ref,D,1)="U" Do  Quit 1
 . New Transport,TranspNr
 . Set FL(3,2)=$S(CC:"Order | ",1:"Bon   | ")_$E($P(Ref,D,2),1,3)_"."_$E($P(Ref,D,2),4,6)_" van "_$P(Ref,D,4)
 . Set Transport=$P(Ref,D,10),TranspNr=$P(Transport,";",3)
 . If Transport,TranspNr,$D(^TRANSP("T",TranspNr)) Set FL(3,2)=FL(3,2)_" "_$P(^TRANSP("T",TranspNr),D)
 . Else  Set FL(3,2)=FL(3,2)_" "_$$LOCASE^vhRtn1($P($P(Ref,D,9),"#",2))
 Set FL(3,2)="Adres | "_$$INITCAP^vhRtn1($P(Ref,D,2)_" - "_$P(Ref,D,7)_" - "_$P(Ref,D,5)) Quit 1
 
PRINT(FANr) 
 Do EXTERN^DCPRINT("F",FANr,0,1,1)
 Quit