RPLMBON2 ;Raadplegen MoederBon [ 03/11/2002  11:28 AM ]
 Q
 ;
FAXL 
 New %J,%TC,%INT,%EXT,I,R,Data,Taal,Count,PRNr,KortText,IdentNr,Aantal,Space,KLNaam,LevAdr,LevTerm
 Set %J=$$%J^vhRtn1(),Count=8
 Kill ^HULP(%J)
 Do KLANT^DCFAX2(2671)
 Set:$L($P(^KKL(^KK1(2671),6),D,1)) Data("Verantw")=$P($P(^KKL(^KK1(2671),6),D,1),"(")
 Set Data("Tav")=Data("Verantw")
 Set Taal=Data("Taal")
 Set R=$P(^KKL(^KK1(KC),0),D,2),KLNaam=$E(R)_$$LOCASE^vhRtn1($E(R,2,99))
 Set Data("Betreft")="Bestelling voor "_KLNaam
 For  Do  Quit:LevTerm=""  Quit:%TC
 .Set LevTerm=$$ASKL^vhINP("RPLKL","VMBLEVTERM")
 .If $L(LevTerm) Do VALDATE^vhDTyp(LevTerm,"DK") If %TC Set LevTerm=%EXT
 Set LevTerm=$S(LevTerm="":$$TXT("Asap"),1:$$TXT("Op"))_LevTerm
 Set R=^RES("HAEFELE","PI","FAX","D","OPEN TEXT",Taal),R=$P(R,"#1")_LevTerm_$P(R,"#1",2)
 If $L(R) Do STORE(R_"~~")
 Do STORE("         Klant : "_KLNaam)
 Set R=$P(^KKL(^KK1(KC),0),D,7),R=$E(R)_$$LOCASE^vhRtn1($E(R,2,99))
 Do STORE("~                 "_R)
 Set R=$P(^MBLOG("D",$$IO^cQ5,KC),D,3)
 Do STORE("~~    Referentie : "_R)
 Set LevAdr=$$LEVADR^KLANT(KC,0)
 If LevAdr=0 Set LevAdr=^KKL(^KK1(KC),0)
 Else  If 'LevAdr Set LevAdr=""
 Else  Set LevAdr=^KKL(^KK1(KC),"L"_$J(LevAdr,3))
 If $L(LevAdr) Do
 .Set R=$P(LevAdr,D,4) Set:$L(R) R=R_" " Set R=R_$P(LevAdr,D,2)
 .Do STORE("~~Leveringsadres : "_R)
 .Set R=$P(LevAdr,D,5)
 .Do STORE("~                 "_R)
 .Set R=$P(LevAdr,D,6) Set:$L(R) R=R_" " Set R=R_$P(LevAdr,D,7)
 .Do STORE("~                 "_R)
 Do FAXTITEL
 Set I="",Space=0
 For  Set I=$O(^HULP($J,"K"_KC,"VP",I)) Quit:I=""  Do
 .Set R=^HULP($J,"K"_KC,"VP",I),PRNr=$P(R,D) Quit:'PRNr  Quit:PRNr<0
 .Set KortText=$P(R,D,2),IdentNr=$P(R,D,3),Aantal=$P(R,D,12)
 .If Space Set R=$J("",13)_"|",R=R_$J("",54-$L(R))_"|"_$J("",11),R="~|"_R_" |" Do STORE(R)
 .Set Space=1
 .Set R=" "_IdentNr,R=R_$J("",13-$L(R))_"| "_KortText,R=R_$J("",54-$L(R))_"|"_$$EXTNUM^vhDTyp(Aantal,11,"",0),R="~|"_R_" |"
 .Do STORE(R)
 Do TITELLIN
 Set R=^RES("HAEFELE","PI","FAX","D","SLOT TEXT",Taal)
 If $L(R) Do STORE("~~"_R)
 Do EXTERN^DCFAX(.Data,"^HULP("_%J_",""T"")")
 Set $P(^MBLOG("D",$$IO^cQ5,KC),D,6)=1
 Set I=""
 For  Set I=$O(^HULP($J,"K"_KC,"VP",I)) Quit:I=""  Do
 .Set R=^HULP($J,"K"_KC,"VP",I),PRNr=$P(R,D) Quit:'PRNr  Quit:PRNr<0
 .Set Aantal=$P(R,D,12)
 .Do STAT^MBSTAT(KC,PRNr,Aantal)
 Kill ^HULP(%J)
 Quit
 
TITELLIN 
 New R
 Set R=$TR($J("",13)," ","-")_"|",R=R_$TR($J("",54-$L(R))," ","-")_"|"_$TR($J("",12)," ","-"),R="~|"_R_"|"
 Do STORE(R)
 Quit
 
FAXTITEL 
 New R
 Do STORE("~")
 Do TITELLIN
 Set R=" "_$$TXT("IdentNr"),R=R_$J("",13-$L(R))_"| "_$$TXT("KortTxt"),R=R_$J("",54-$L(R))_"|"_$J($$TXT("Aantal"),11),R="~|"_R_" |"
 Do STORE(R)
 Do TITELLIN
 Quit
 
STORE(R) 
 New Next
 Set Count=Count+$L(R,"~")-1
 Set Next=$O(^HULP(%J,"T",""),-1)+1,^HULP(%J,"T",Next)=R
 Quit
 
 ; Ophalen taalafhankelijke tekst
TXT(Ref,Piece) 
 If '$D(Piece) Set Piece=2
 Quit $P($P($T(@("T"_Ref)),U,Piece),D,$F("NFDE",Taal)-1)
 
TKortTxt ;Korttekst\Korttekst\Korttekst\Korttekst
TIdentNr ;Identnummer\Identnummer\Identnummer\Identnummer
TAantal ;Aantal\Aantal\Aantal\Aantal
TOp ;op \op \op \op 
TAsap ;ZO SPOEDIG MOGELIJK\ZO SPOEDIG MOGELIJK\ZO SPOEDIG MOGELIJK\ZO SPOEDIG MOGELIJK