TKINIT ;PG&A,TK-CONFIG,2.25,TOOLKIT INITIALIZATION;7NOV94 3:41P;;;20JUL99  03:48
 ;Copyright (C) 1985,6,7 Patterson, Gray and Assoc., Inc.
 D LINE W !,"PG&A Toolkit Initialization - Version ",$P($T(TKINIT),",",3),!,"Copyright (C) 1985,7,8 Patterson, Gray & Assoc., Inc.",!,"Schaumburg, IL  60173",! D LINE
 S B=$ZV,OS=$S(B["M3":9,B["DSM-1":3,B["DSM":7,B["MSM":6,B["M/S":4,B["DTM":5,B["V1.":1,B["ISM":4,B["Cache":4,B["Open M":4,B["UNIMP":4,B["<SYNTAX>":4,1:0)
 S B="^TKINIT1"_$E("ABCDEFGHI",OS) D @B
 W !!,"***> Initializing Code Portion of ^TKREAD" D ^TKREAD
 W !!,"***> Initializing Terminal Parameters",!!?4,"Please respond YES or NO to each of the following devices.  A YES"
 W !?4,"response will initialize device parameters, a NO or RETURN response will",!?4,"not.  The Toolkit Initialization can be run again to add further types.",!?4,"It is best to define only the types you are going to use.",!
 S ^TK="D:'$D(TK) INIT^TKDEV W:TK(""CSR"")]"""" @TK(""CSR"") S TK(1)=1 X ^TK(""TERM-OFF"") W:$L($P($G(^TK(.1,TK,7)),""\"",4)) @$P(^(7),""\"",4)"
 D:OS="DTM" ^TKINTD2 D:OS="MSM" ^TKINTM2
 D ^TKINT01,^TKINTVT,^TKINT02A,^TKINT13,^TKINT13C,^TKINT13D,^TKINT06,^TKINT18,^TKINT08,^TKINT16A,^TKINT16
 S ^TK("REST")="S TK(1)=1 X ^TK(""TERM-ON"")",^TK("MARGIN")=0 W !
X D LINE W !,"***> Menu Driver Option" S X=$S($D(^TK("MENU")):^("MENU"),1:0) W !!?5,"The PG&A Toolkit menu drivers provide the option of requiring that",!?5,"RETURN be pressed to complete a selection.  If you prefer either"
 W !?5,"mode, select it here.  Currently, RETURN is ",$S(X:"",1:"NOT "),"required.",!!?5,"Require RETURN at Toolkit Menus? > "
 R A#5 S:A="" A=$E("NY",X+1) S ^TK("MENU")="Yy"[A W "...RETURN ",$S(^("MENU"):"Required",1:"Not Required"),!
 D LINE W !,"***> Use of $I in a Network" S X=$S($D(^TK("$I")):1,1:0) W !!?5,"If your system is using a local area network, the value of $I may not",!?5,"reflect the same device at every logon.  If that is the case, the TK"
 W !?5,"routines will need to use alternate means for determining device types.",!?5,"Enter ""Y"" if your $I values are inconsistent.  Current definition is ",$S($D(^TK("$I")):"Y",1:"N"),!!?5,"Inconsistent $I values (Y or N)? > "
 R A#5 I A'="","Yy"[A S ^TK("$I")=""
 E  I A'="" K ^TK("$I")
 W ! D LINE W !,"***> Date Format" S X=$S($D(^TK("DATEF")):^("DATEF"),1:0) W !!?5,"What format is to be used for dates, US or International.",!
 W ?5,"The current definition is ",$S('$D(^TK("DATEF")):"US",^("DATEF"):"International",1:"US"),!!?5,"Enter U or I > "
 R A#1 I A'="","UIui"[A S ^TK("DATEF")=$S("Uu"[A:0,1:1) W $S(^("DATEF"):"nternational",1:"S")
 W ! D LINE W !,"PG&A Toolkit Initialization completed",!! G GETPARM^TKINIT2
 ;
LINE F J=1:1:19 W "----"
 Q
COPY R "From Device-",DV,!,"To Device-",DV1,! S A="" F J=1:1 S A=$O(^TK(0,DV,A)) Q:A=""  S ^TK(0,DV1,A)=^(A)
 F J=1:1 S A=$O(^TK(.1,DV,A)) Q:A=""  S ^TK(.1,DV1,A)=^(A)
 S ^TK(.3,DV1,0)=^TK(.3,DV,0) W "done",! Q
 ;
PRESET S OS="M3" D ^TKINIT1I,^TKREAD S T="VT220" D ENT^TKINTVT S ^TK("MENU")=0,^TK("MARGIN")=0 M ^cT=^TK
 S GN="^cTKEDHLP" W !?8,"Initializing TK-WORKS" D ^cTKEDH01,SETUP^cTKEDIN1,SETUP^cTKEDIN2
 S ^cTKED="X ^cTKED(""ED"") Q  ;^TKEDE`^TKEDU`^TKEDW`^TKEDL`^TKEDA`^TKEDP`^TKEDR`1"
 W !?8,"Initializing TK-SQL" D INIT^TKSQL2
 Q