cA314 ;BESTANDEN WIJZIGEN ;%A314; [ 02/21/00  2:43 PM ]
 ;
T0 ;Bestanden wijzigen ;
T1 ;Bestandsnaam;
T2 ;Geef de bestandsnaam (met of zonder ^).;
T3 ; index[] = normale index;      [] = einde indexen;     -[] = naar het vorige niveau;
T4 ;+input[] = index die volgt op input;     ,[] = hernemen;
T5 ;  ongeldige UCI-notatie;
T6 ;  bestand bestaat niet;
T7 ;Index ;
T8 ;Geen data voor node ;
T9 ;Vervang   [] = einde: ;
T10 ;Met                 : ;
T11 ; ..ongeldige bestandsnaam.;
T12 ; ...UCI niet gevonden.;
T13 ; ...Volume Groep niet gevonden.;
T14 ; fout opgetreden;
 ;
T0F ;Modification des fichiers ;
T1F ;Nom du fichier;
T2F ;Donnez un nom de fichier valable (avec ou sans ^).;
T3F ; index[] = index normale;[] = fin des index;-[] = vers un niveau supérieur;
T4F ;+index[] = index qui suit celui donné;,[] = reprendre;
T5F ;  Désignation UCI invalable;
T6F ;  uci n'existe pas;
T7F ;Index ;
T8F ;Pas de données pour node ;
T9F ;Remplacez   [] = fin: ;
T10F ;Par                 : ;
T11F ; ..nom de fichier invalable;
T12F ; ...UCI pas trouvé.;
T13F ; ...'Volume Group' pas trouvé;
T14F ; rencontré une erreur;
 ;
T0E ;Bestanden wijzigen ;
T1E ;Bestandsnaam;
T2E ;Geef de bestandsnaam (met of zonder ^).;
T3E ; index[] = normale index;      [] = einde indexen;     -[] = naar het vorige niveau;
T4E ;+input[] = index die volgt op input;     ,[] = hernemen;
T5E ;  ongeldige UCI-notatie;
T6E ;  bestand bestaat niet;
T7E ;Index ;
T8E ;Geen data voor node ;
T9E ;Vervang   [] = einde: ;
T10E ;Met                 : ;
T11E ; ..ongeldige bestandsnaam.;
T12E ; ...UCI niet gevonden.;
T13E ; ...Volume Groep niet gevonden.;
T14E ; fout opgetreden;
 ;
1 K I S QT=$G(QT),T=1,SW1=0 W !,$P($T(@("T1"_QT)),";",2)
11 R " (?): ",%GN G YZ:%GN=""!(%GN="^")!(%GN="-") S:$E(%GN)="^" %GN=$E(%GN,2,99)
12 I %GN="?" W !!,$P($T(@("T2"_QT)),";",2),! G 1
 S %S=$P(%GN,"(",2,999),%GN=$P(%GN,"(",1) D CHECK G 1:%Q
 ;
2 S:'T T=1 S SW=0 W !,$P($T(@("T7"_QT)),";",2),T,": " R I(T)
 I I(T)="?" W ! D  W ! G 2
 . F I=2:1:4 W !,$P($T(@("T3"_QT)),";",I)
 . F I=2:1:3 W !,$P($T(@("T4"_QT)),";",I)
20 I I(T)="-" K I(T) S T=T-1 G 2:T>0,1
21 G 1:I(T)="," I I(T)="" K I(T) S SW1=1,T=T-1
22 I T,$E(I(T))="+" S SW=1,I(T)=$E(I(T),2,99)
23 S NM="^"_%GN S:T NM=NM_"("""_I(1)_"""" F X=2:1:10 I $D(I(X)) S NM=NM_","""_I(X)_""""
24 I SW S NMX=NM_")",I(T)=$O(@NMX) W "--->",I(T) G 2:I(T)="" S SW=0 G 23
25 S:T NM=NM_")" S DEF=$D(@NM) I 'DEF W "  ???" G 2
26 S T=T+1 G 2:'SW1 S SW1=0
27 S T=T-1 I '(DEF#10) W $P($T(@("T8"_QT)),";",2),NM G 2
 ;
3 S A=@$ZR W !!,$ZR,"=",! D CC W !
31 W !,$P($T(@("T9"_QT)),";",2) R A1 G 2:A1="",4:A1="END"!(A1="end")
32 G 4:A[A1 I A1'["..." G 34
33 S A2=A S:$L($P(A1,"...",1)) A2=$P(A,$P(A1,"...",1),2,999) S:$L($P(A1,"...",2)) A2=$P(A2,$P(A1,"...",2),1) S A1=$P(A1,"...",1)_A2_$P(A1,"...",2,999) G 32
34 I $E(A1)="[",$E(A1,5)="]",$E(A1,2,4)?3N S A1=$C($E(A1,2,4)) G 4:$F(A,A1)
35 I A'[A1 W "  ???" G 31
 ;
4 W !,$P($T(@("T10"_QT)),";",2) R A2 I A2?.E1C.E G 4
41 I $E(A2)="[",$E(A2,5)="]",$E(A2,2,4)?3N,$E(A2,2,4)<256 S A2=$C($E(A2,2,4))
42 S A=$P(A,A1,1)_A2_$P(A,A1,2,999),@$ZR=A G 3
 ;
YZ K A,A1,A2 Q
 ;
CHECK ; Check validity of UCI, VGP, and global name
 N %XUCI S (%Q,%XUCI)=0,%U="" I %GN["[" S %U=$P(%GN,"]",1)
 I %GN["|" S %U="|"_$P(%GN,"|",2),%XUCI=1
 S %U=$TR(%U,"""","") ; strip quotes
 I %U'="",%U'?1(1"[",1"|")3U1","3U,%U'?1(1"[",1"|")3U W $P($T(@("T5"_QT)),";",2),%U S %Q=1 Q
 I %U'="" S:$L(%U)<5 %U=%U_","_$P($ZU($ZV'["MSM"*5),",",2) S %GN=$S(%XUCI:"|",1:"[")_""""_$P(%U,$S(%XUCI:"|",1:"["),2)_""""_$S(%XUCI:"|",1:"]")_$S(%XUCI:$P(%GN,"|",3),1:$P(%GN,"]",2))
 I %U'="" S $ZT="CHECK2" I $D(^[$E(%U,2,8)]TESTUCI) S $ZT="" ; does UCI exist?
CHECK1 ; check syntax of global name only
 S %U=$S(%U="":%GN,%XUCI:$P(%GN,"|",3),1:$P(%GN,"]",2)) I $L(%U)<9 Q:%U?1A.AN!(%U?1"%".AN)
 W $P($T(@("T11"_QT)),";",2) S %Q=1 Q
CHECK2 ; error handler for CHECK subroutine
 I $ZV["MSM",$ZE["<NOUCI" W $P($T(@("T12"_QT)),";",2) S %Q=1 Q
 I $ZV'["MSM",$ZE["<NAMESPACE>" W $P($T(@("T12"_QT)),";",2) S %Q=1 Q
 I $ZV["MSM",$ZE["<NOSYS" W $P($T(@("T13"_QT)),";",2) S %Q=1 Q
 I $ZV'["MSM",$ZE["<NAMESPACE>" W $P($T(@("T13"_QT)),";",2) S %Q=1 Q
 I $ZV["MSM",$ZE["<PROT" G CHECK1   ; ^TESTUCI exists and is protected
 I $ZV'["MSM",$ZE["<PROTECT>" G CHECK1
 I $ZV["MSM",$ZE["<SBSCR" G CHECK1  ; DSM system with all 7-bit globals
 I $ZV'["MSM",$ZE["<SUBSCRIPT>" G CHECK1
 W "   ",$P($ZE,":",1,6),$P($T(@("T14"_QT)),";",2) S %Q=1 Q
 ;
CC N %I,%K F %I=1:1:$L(A) S %K=$E(A,%I) W $S(%K'?1C:%K,1:"["_$E($A(A,%I)+1000,2,4)_"]")
CCZ Q
 ;
ZZ ; 05.02.01 - 16 u 23 * V7.84