cABVBA01	; Algemene functies DDP ; cABVBA01
	;
	;
YZ	Q
	;
OMS(TYPE,DDPS,TABEL)	; Ophalen titel \ label
	; Input: TYPE: Gescheiden door "~"
	; 		1. Type 
	; 		   0 of "": Grid (=kolomtitel)
	;                  1: Form (=label)
	;               2. Taal
	;               3. Switch
	;                  "",0 = ophalen vanuit DDP
	;                  1= ophalen vanuit DDC
	;        DDPS: schakel van DDPId's (gescheiden door "#")      
	;        TABEL: Als referentie door te geven
	; 
	; Output: Indien taal doorgegeven: Label of kolomtitel \ Tooltip
	; 	  Indien TABEL doorgegeven:
	; 	  	TABEL(TK,0)=Label\kolomtitel
	; 	  	        ,1)=Tooltip
	S $ZT="^dmERROR"
	N @$$INITVAR^cAFVBA01("TYPE,DDPS,TABEL")
	K TABEL
	;
	; Controle op input 
	S OUT="" I '$L($G(DDPS)) G OMSZ
	I '$L($G(TYPE)) S TYPE="0"
	S TK1=$P(TYPE,"~",2),TYPE=$P(TYPE,"~")
	S UI1ID=$P(DDPS,"#",$L(DDPS,"#"))
	;
	; Variabelen opzetten	
	S DMSPP="DP.PROP" I $P(TYPE,"~",3) S DMSPP="DC.PROP"
	D DMS^cAN000("UQC","USC",DMSPP_".TAAL",1) I '$L(UQC)!'$L(USC) G OMSZ
	S UREF=^DMC(UQC,USC,"DATA","REF")
	;
	; Eerste deel omschrijving	
OMSA	S TKI1="" F  S TKI1=$O(^DTEXT(0,"TEXT.9000",TKI1)) Q:TKI1=""  D
	. S TKB=^(TKI1,0) I $P(TKB,D,30) Q          ; BG of verwijderd
	. I $L(TK1) I TKI1'=TK1 Q                   ; Opgevraagd voor één taal
	. S TK=TKI1,UI1=UI1ID_" "_TK
	. S K=$P($G(@UREF@(1)),D,13) ; Foreign Key (eventueel afkorting ingevuld)
	. I '$L(K) S K=$P($G(@UREF@(1)),D,11+($G(TYPE)*10))  ; Label of kolomtitel
	. I $$SIG^cAFA1(DMSPP,UI1ID,113)=1 S K=""   ; Eerste zoeksleutel
	. S TFORK(TK,0)=K
	. ; Tooltip
	. I TYPE=1 Q
	. S K=$P($G(@UREF@(1)),D,12) ; Tooltip
	. I $L($$SIG^cAFA1(DMSPP,UI1ID,113)) Q    ; Zoeksleutel
	. S TFORK(TK,1)=K
	;
	; Eventueel volgende delen omschrijving
	I TYPE=1 G OMSD  ; indien form : niets meer ophalen
	S PC=$L(DDPS,"#")
OMSB	S PC=PC-1 S UI1C=$P(DDPS,"#",PC),UI1=UI1C_" " I '$L(UI1C) G OMSD
OMSC	S UI1=$O(@UREF) I $P(UI1," ",1,2)'=UI1C G OMSB
	S TK=$P(@UREF@(0),D,2),K=$P(^(1),D,13)   ; Foreign Key (eventueel afkorting ingevuld)
	I $L(TK1) I TK'=TK1 G OMSC               ; Opgevraagd voor één taal
	I '$L(K) S K=$P(^(1),D,11+($G(TYPE)*10)) ; Label of kolomtitel
	I $L(TFORK(TK,0)),(TK'="E"),$L(K),$$LC^cAFA1($E(K,2,$L(K)))=$E(K,2,$L(K)) S K=$$LC^cAFA1(K) ; Enkel in het Engels initcap
	S TFORK(TK,0)=$S($L($G(TFORK(TK,0))):TFORK(TK,0)_" ",1:"")_K 
	; Tooltip
	I '$D(TFORK(TK,1)),(PC=($L(DDPS,"#")-1)) S TFORK(TK,1)=$P(@UREF@(1),D,12)
	G OMSC
	;
	; Output opzetten
OMSD	I $L(TK1) S OUT=$G(TFORK(TK1,0))_D_$G(TFORK(TK1,1))
	M TABEL=TFORK
	;
OMSZ	Q OUT
	;
ZZ	; 29.08.07 - 10 u 22 * V8.09