cAFA62(CTLG) ; Prijswijzigingen catalogus ;%AFA62 [ 06/30/00  3:39 PM ]
 ; opgeroepen via ^DMM("CTLG",code cat_".PW",67
 ;
T0 ; Prijswijzigingen catalogus ;
T1 ; Update catalogus ;
T2 ;Er zijn geen gegevens gewijzigd;
T3 ;Update cataloog is beëindigd;
 ;
T0F ; Mise à jour catalogue ;
T1F ; Mise à jour catalogue ;
T2F ;Aucune donnée à été modifiée;
T3F ;Mise à jour du catalogue terminée;
 ;
T0E ; Prijswijzigingen catalogus ;
T1E ; Update catalogus ;
T2E ;Er zijn geen gegevens gewijzigd;
T3E ;Update cataloog is beëindigd;
 ;
1 D P^cA612(19,1,5,80,1,0,0,0,$P($T(@("T1"_QT)),U,2),0,0,0,0,0)
 N SWUPD,PRG,B,A
 S $ZT="TRAP^cAN000"
 ; ophalen basisgegevens catalog
 D B^cAFA61(CTLG)
 S PRG=$P(B(1),D,25)            ; specifiek uit te voeren voor update
 ;
2 D UPDATE($P(B(1),D)_".PW")     ; update catalog
 S K=$P($T(@("T3"_QT)),U,2) D TXT^cAFA1(250)
 I $G(SWUPD) S TAB(206)=DT,TAB(207)=QU D B^cAN220("PW","CTLG",CTLG,"TAB")
 I '$G(SWUPD) S K=$P($T(@("T2"_QT)),U,2) D TXT^cAFA1(250)
 ;
YZ D C^cA612 Q
 ;
UPDATE(DMSPW)       ;
 I $L(PRG) D @PRG Q
 N CTLGUQC,CTLGUSC,UQC,USC,CTLGUSA,CTLGUQA,CTLGDMS,I,B,TAB,UI1,PW,I1,IREF,SW3
 S $ZT="TRAP^cAN000"
 D CTLGDEF^cAFA6(CTLG)    ; catalog-definitie
 D DMS^cAN000("UQC","USC",CTLGDMS) I '$L(UQC)!'$L(USC) Q
 S CTLGUQC=UQC,CTLGUSC=USC
 D DMS^cAN000("UQC","USC",DMSPW) I '$L(UQC)!'$L(USC) Q
 S IREF=$G(^DMC(UQC,USC,"DATA","INDEX")) I '$L(IREF) Q
 S I1="",SW3=1 F  S I1=$O(@IREF@(101,I1)) Q:I1=""  D
 . S UI1=^(I1) K PW,B
 . D R^cAN000 M PW=B K B
 . w /CUP(3,3),$P(PW(1),D),/EL
 . I $$UNIEK^cAFA1(CTLGDMS,101,$P(PW(1),D)) D CREATE Q
 . E  D UPD
 Q
 ;
CREATE ; openen nieuw catalogusproduct
 S $P(PW(1),D,28)=$H,$P(PW(1),D,29)=$G(QU)
 D P^cAN220(CTLGUSA,CTLGUQA,"","PW","")
 S SWUPD=1
 Q
 ;
UPD ; update 
 N UQC,USC
 S UQC=CTLGUQC,USC=CTLGUSC
 K TAB
 S UI1=$$UI1^cAFA1(CTLGDMS,101,$P(PW(1),D))
 D R^cAN000
 F I=1:1:$L(PW(1),D)  I $P(B(1),D,I)'=$P(PW(1),D,I) S TAB(100+I)=$P(PW(1),D,I)
 I $D(TAB) D B^cAN220(CTLGUSA,CTLGUQA,UI1,"TAB") S SWUPD=1
 Q
 ;
ZZ ; 05.02.01 - 16 u 23 * V7.84