cAFO1 ;Outputformaten ;%AFO1 ; [ 01/03/01  5:20 PM ]
 ;
T0 ;Outputformaten ;
 ;
T0F ;Formats externes ;
 ;
T0E ;Outputformaten ;
 ;
BANK(K) ; banknummer
 N R,RL I $L(K) D
 . S R=$P(K,"-"),RL=$P($G(@("^"_Q_"BA(39)")),D,3)
 . S:RL'?1.3U RL="BE" S:R'?1.3U R=RL I R?1.3U,$D(^BA(6,R,2)) X "S K="_^(2)
 Q K
 ;
BET(K) ; betalingstermijn
 N U3
 I K="" S U3=$P("contant#comptant#contant#in cash","#",QTU)
 I $L(K) S U3=K S:QT="F" U3=$TR(K,"DECW","JFDT")
 Q U3
 ;
BTW(K) ; BTW-nummer
 N R,RL I $L(K) D
 . S R=$E(K,1,2),RL=$P($G(@("^"_Q_"BA(39)")),D,4)
 . S:RL'?2U RL="BE" S:R'?2U R=RL I R?2U,$D(^BA(5,R,2)) X "S K="_^(2)
 Q K
 ;
DLOG(R) ; reconstructie "wat geprint"                    *** buiten gebruik ***
 N U3,UI1
 S R=^(R),U3=K,UI1=I1 I $L($P(R,D,10,99)) X $P(R,D,10,99)
 S K=$E(U3,1,$P(R,D,9))
 Q K
 ;
JN(K) ; 1=ja / 0=neen
 N R
 S R=$P($P("neen#non#nein#no\ja#oui#ja#yes",D,K+1),"#",QTU)
 Q R
 ;
KL(DMS,KC)         ; nummer, naam, adres, woonplaats of "geen"
 N R,UQC,USC,UTOP
 S R=$$Z I $L(KC) D
 . D DMS^cAN000("UQC","USC",DMS)
 . D TOP(UQC,USC,KC,1,101,102,105,107)
 . S R=UTOP(1.1)
 Q R
 ;
KO(UQC,USC,UI1)    ; omschrijving kode of "geen"
 N U3,UREF
 S U3=$$Z
 I $L(UI1) S UI1=$P(UI1," ")_" ",U3=UI1_"?" I $D(^DMC(UQC,USC)) D
 . S UREF=^DMC(UQC,USC,"DATA","REF") I $D(@UREF) S U3=$P(@UREF,D)
 Q U3
 ;
KODE(USC,UI1)      ; omschrijving kode of "geen"          *** niet meer gebr.***
 N U3,UREF
 S U3=$$Z
 I $L(UI1) S UI1=$P(UI1," ")_" ",U3=UI1_"?" I $D(^DMC(0,USC)) D
 . S UREF=^DMC(0,USC,"DATA","REF")
 . I $D(@UREF) S U3=$P(@UREF,D)
 Q U3
 ;
LAND(K) ; omschrijving ISO-landcode
 N L,R,TF,TL,UC
 S TF=$P(@("^"_Q_"BA(39)"),D,2),TL=$P(^(39),D,15),UC=$P(^(39),D,16)
 I TF="" S TF="N"    ; taalcode firma
 I TL="" S TL=TF     ; taalcode printen landcode
 S L=$G(^ISO(0,"ISO.LAND",+K,0))
 S R=$P(L,D,$S(TL="F":12,TL="D":22,TL="E":32,1:2))
 I R="" S R=$P(L,D,$S(TF="F":12,TF="D":22,TF="E":32,1:2))
 I R="" S R=$P(L,D,2)
 I UC S R=$$UC^cAFA1(R)
 Q R
 ;
NIV(K) ; niveau (0 = oper.   1 = b.g.   2 = verw.)
 N R
 S R=$P($P("operationeel#opérationel#operationeel#operational\buiten gebruik#hors usage#buiten gebruik#out of use\verwijderd#annulé#verwijderd#removed",D,K+1),"#",QTU)
 Q R
 ;
OW(K) ; 0=onderdrukken / 1=weergeven
 N R
 S R=$P($P("onderdrukken#supprimer##suppress\weergeven#afficher##represent",D,K+1),"#",QTU)
 Q R
 ;
PR(DMS,KC)         ; omschrijving in de taal van de gebruiker of geen *** BG ***
 N R,RQ2,UDD,UI1,UREF,UQC,USC
 D DMS^cAN000("UQC","USC",DMS)
 S R="" I $L(UQC),$L(USC),$D(^DMC(UQC,USC)) D
 . S UDD=^DMC(UQC,USC,"DATA"),UREF=^("DATA","REF"),RQ2=$G(^("OUD"))
 . I KC="" S R=$$Z
 . I $L(KC) S R=KC_" ?" D
 .. I UDD=1 S UI1=$G(@RQ2@(KC))
 .. I UDD=2 S UI1=KC_" "
 .. I UDD>2 S UI1=KC
 .. I $L(UI1),$D(@UREF) D
 ... S R=$P(@UREF@(0),D,QTU-1*10+2)
 Q R
 ;
TOP(UQC,USC,KC,V,B1,B2,B3,B4,B5,B6,B7,B8,B9)     ; opzetten UTOP
 N R,UDD,UI1,UREF
 S (UTOP(+V),UTOP(V+.1))="" I $L(UQC),$L(USC),$D(^DMC(UQC,USC)) D
 . S UDD=^(USC,"DATA"),UREF=^("DATA","REF"),UI1=KC I UDD<3 D
 .. I UDD=1 N Q2 S Q2=^("OUD"),UI1=$G(@Q2@(KC))
 .. I UDD=2 S UI1=KC_" "
 . S UTOP(+V)=$P(^DMC(UQC,USC,"TAAL",$E(QT_"N")),D),UTOP(V+.1)=KC_" ?"
 . I $L(UI1),UDD<5 S UTOP(V+.1)=$P($G(@UREF@(B1\100-1)),D,B1#100) D
 .. F R=2:1:9 Q:'$D(@("B"_R))  S UTOP(V+.1)=UTOP(V+.1)_" "_$P($G(^(@("B"_R)\100-1)),D,@("B"_R)#100)
 . I $L(UI1),UDD=5 S UTOP(V+.1)=$P($G(@UREF),D,B1#100) D
 .. F R=2:1:9 Q:'$D(@("B"_R))  S UTOP(V+.1)=UTOP(V+.1)_" "_$P($G(^(UI1)),D,@("B"_R)#100)
 . S UTOP(+V)=$$UC^cAFA1($E(UTOP(+V)))_$E(UTOP(+V),2,999)
 Q
 ;
Z(R) ; 'R of onbestaand : "zonder"
 ; R=1 : Alle
 S R=$P($P("zonder\aucun(e)\ohne\none#alle\tous\alle\all","#",$G(R)+1),D,QTU)
 Q R
 ;
ZZ ; 05.02.01 - 16 u 23 * V7.84