cAT100 ;Openstaande klantenfacturen ;%AT10 ;%AT10* ; [ 03/06/01  6:00 PM ]
 ;
T0 ;Openstaande klantenfacturen ;
T1 ;\Eindtotaal alle geselecteerde klanten;
T2 ;Klant : ;Tel.  : ;Ref : ;Lim : ;
T3 ;Document   Datum   Vervald.   Munt      Bedrag     Openstaand      Vervallen ;
T4 ;Blz :;FCW;FCW;
T5 ;Openstaande;klantenfacturen;
T6 ;Vervolg ;Volgende klant ;
T7 ;V e r v o l g t;V e r v o l g;
 ;
T0F ;Factures de client non soldées ;
T1F ;\Total global de tous les clients sélectionnés;
T2F ;Client: ;Tél.  : ;Réf : ;Lim : ;
T3F ;Document   Date    Echéance   Mon.     Montant         Impayé           Echu ;
T4F ;Page:;FCW;FCT;
T5F ;Documents impayés;des clients;
T6F ;Suite ;Client suivant ;
T7F ;A   s u i v r e;S u i t e;
 ;
T0E ;Outstanding invoice ;
T1E ;\Final total all selected customers;
T2E ;Customer : ;Tel.  : ;Ref : ;Lim : ;
T3E ;Document   Date    Due date   Cur.      Amount    Outstanding        Overdue ;
T4E ;Pge :;ICB;ICB;
T5E ;Outstanding;Invoices;
T6E ;Next ;Next customer ;
T7E ;T o   b e   c o n t i n u e d;C o n t i n u a t i o n;
 ;
 ; initialisatie
1 S BLZ=0,NM2=@("^"_Q_"BA(99,2)"),NM3=^(3),SWH=1 I TP X F70 W @F80
11 S (SWE,ETONB,ETVER)=0,LN=5,LNMAX=$G(LNMAX,55) I $G(QW) S $P(QW(QW),D,7)=1
13 S SORT=$P(@("^"_Q_"BA")@("%T",2),D)
 ;
 ; volgende klant
2 G YZ:ESW=2 S R="LIM1\KL" D ^cA327 I LIM1="" G Y
 ;
 ; per klant
3 S (SWE,SWV)=0 S:'TP LN=5 I ESW<2 S I1=LIM1,B(1)=^(0),B(3)=$G(^(2)),COR=SWC&$P(B(3),D,30),(ONB,VER)=0 D ^cAT101
31 S FNR="" F  S FNR=$O(@QH1) Q:FNR=""  D
 . I '$P(^(FNR),D,5) K ^(FNR)                      ; openstaand = 0
 . I DOCS=1,FNR?5N K ^(FNR)                        ; geen wissels
 . I DOCS=2,FNR?6N K ^(FNR)                        ; enkel wissels
32 I ACT=2 S A=0 D  I 'A G 2                         ; enkel met CN
 . S FNR="" F  S FNR=$O(@QH1) Q:FNR=""  I $P(^(FNR),D)="C" S A=1 Q
33 S FNR="" I 'ACT,'$L($O(@QH1)) D  I 'COR G 2       ; enkel met bedragen
 . I COR S R=^HULP(boot,$J+.02) I '$P(R,D),'$P(R,D,2) S COR=0
35 I TP D S2
37 E  S LYN=F7_","_$P(FG,D,10)_","_F8 D S1
39 K ^HULP(boot,$J+.09) F  S FNR=$O(@QH1) Q:FNR=""  S A=^(FNR),I3=$$DC^cAFD1($S(SORT<2:$P(A,D,2+SORT),1:DT))*1E6+FNR,^HULP(boot,$J+.09,I3)=FNR
 ;
 ; facturen weergeven (gesorteerd)
4 S I3=$O(^HULP(boot,$J+.09,"")) G 6:I3=""
40 S FNR=^(I3) K ^(I3)
41 S A=@QH1,VVD=$P(A,D,3),OPE=+$P(A,D,5) S FC=$P(A,D),MNT=$P(A,D,7),OPV=+$P(A,D,6) S:MNT="" MNT=BF,OPV=+$P(A,D,4) G 4:'OPE
42 S:FC="C" OPV=-OPV S ONB=ONB+OPE,LN=LN+1
43 I COR+LN>21&'TP S K=$P($T(@("T6"_QT)),U,2) D F1 G YZ:K="-" S FP=501,LN=6 W @F,!,@F1,@F
45 I COR+LN>LNMAX W !,@LIN,!!?60,$P($T(@("T7"_QT)),U,2),$$FF^cA334 S LN=6,(SWH,SWV)=1 D S2
 ;
 ; 1 lijn per factuur
5 S FC=$TR(FC,$P($T(@("T4"_QT)),U,3),$P($T(@("T4"_QT)),U,4))
50 W !?1,$P(A,D,8),?2,FC,$J(FNR,7),?13,$E($P(A,D,2),1,5),?21,VVD,?32,MNT
51 S R=OPV_"\12\36\"_$$DEC^cAFA1(MNT) D R3 S R=OPE_"\12\51\"_QD D R3 S ETONB=ETONB+OPE
53 S R=VVD_D_RFD D ^cA326 I R'>0 S R=OPE_"\12\66\"_QD,VER=VER+R D R3 S ETVER=ETVER+OPE
55 D S3 G 4
 ;
 ; einde klant
6 I COR+LN>LNMAX W !,@LIN,!!?60,$P($T(@("T7"_QT)),U,2),$$FF^cA334 S LN=6,(SWH,SWV)=1 D S2
61 W !,?51,"+-----------   +-----------" S LN=LN+1 D S3
63 W ! S LN=LN+1,R=ONB_D_12_D_51_D_QD D R3 S R=VER_D_12_D_66_D_QD D R3,S3
64 I COR W !,$J($P(TEXT,D,7)_" "_$P(B(3),D,30),48) S LN=LN+1,R=$P(^HULP(boot,$J+.02),D)_D_12_D_51_D_QD D R3 S R=$P(^($J+.02),D,2)_D_12_D_66_D_QD D R3,S3
65 I TP W !,@LIN,! W:COR+LN+10>LNMAX!PSW $$FF^cA334 S:COR+LN+10>LNMAX!PSW LN=3,SWH=1,SWE=1 S LN=LN+2 G 2
67 S LN=LN+1 G 69:LN>22 W !,@F7,@$P(FG,D,3) W:$G(QW) /cDR(2,78),/WWR(0) I '$G(QW) F I=1:1:78 W @$P(FG,D,9)
68 W @$P(FG,D,4) F I=12,20,31,50,65 S FP=LN*100+I W @F,@$P(FG,D,8)
69 W @F8 S K=$P($T(@("T6"_QT)),U,3) D F1 G YZ:K="-",2
 ;
 ; eindtotaal
Y I ESW=1 S ESW=2,B(1)=$P($T(@("T1"_QT)),U,2),COR=0,ONB=ETONB,VER=ETVER,ACT=1 K ^HULP(boot,$J),^($J+.01),^($J+.02) G 3
YZ W:TP&BLZ&'PSW&'SWE $$FF^cA334 X:TP F71 K ^HULP(boot,$J),^($J+.01) Q
 ;
R3 S R1=$P(R,D,2),R2=$P(R,D,4),R0=$J($P(R,D),0,R2),R3=" ",R4="" S:R2 R4=","_$P(R0,".",2),R1=R1-1-R2 S:R0<0 R3="-",R0=-R0
R3A S R0=+$P(R0,".") F R5=3,7 S R6=$L(R0) Q:R6'>R5  S R0=$E(R0,1,R6-R5)_"."_$E(R0,R6-R5+1,R6)
R3B W ?$P(R,D,3),$J(R0,R1),R4,R3
R3Z K R0,R1,R2,R3,R4,R5,R6 Q  ;V3 05.07.88
 ;
 ; hoofding op scherm
S1 I SWH S K=$T(@("T2"_QT)),FP=202 W @F11,@F1,@F,@F4,$P(K,U,2),@F5 S FP=302 W @F,@F4,$P(K,U,3),@F5 
S1A I SWH S FP=332 W @F,@F4,$P(K,U,5),@F5 S FP=351 W @F,@F4,$P(K,U,4),@F5,RFD S FP=502 W @F,@F4,$P($T(@("T3"_QT)),U,2),@F5,/CUP(3,75),@F92,$P(MUNT,D),@F93
S1B I SWH S RH="101#180\401#480",RV="101#501\412#512\420#520\431#531\450#550\465#565\180#580" K R D ^cA319
S1C S FP=212 W @F,$E($P(B(1),D)_" "_$P(B(1),D,2)_" "_$P(B(1),D,5)_" "_$P(B(1),D,7)_$J("",67),1,67)
S1D S FP=312 W @F,$E($P(B(1),D,13)_$J("",18),1,18) S FP=340 W @F,$E($P(B(3),D,7)_$J("",10),1,10),!!!,@F1 S FP=501 W @F
S1Z S SWH=0 Q
 ;
 ; hoofding op printer
S2 I SWH!PSW S BLZ=BLZ+1 W !,QN,?72,$P($T(@("T4"_QT)),U,2),$J(BLZ,3),!,NM2,?30,@F86,$P($T(@("T5"_QT)),U,2),@F87,$$CR^cA334,?72,DT
S2A I SWH!PSW W !,NM3,?30,@F86,$P($T(@("T5"_QT)),U,3),@F87,$$CR^cA334,?73,TD,! W:SWV ?60,$P($T(@("T7"_QT)),U,3) S SWV=0,LN=LN+4
S2B W !,@LINE,!,@F30," ",$P($T(@("T2"_QT)),U,2),$E($P(B(1),D)_" "_$P(B(1),D,2)_" "_$P(B(1),D,5)_" "_$P(B(1),D,7),1,60),?79,@F30
S2C W !,@F30," ",$P($T(@("T2"_QT)),U,3),$P(B(1),D,13),?51,$P($T(@("T2"_QT)),U,4),RFD,?79,@F30,$$CR^cA334,?75,@F86,$P(MUNT,D),@F87
S2D W !,@LIN,!,?2,$P($T(@("T3"_QT)),U,2) D S3 W !,@LIN
S2Z S LN=LN+6,SWH=0 Q
 ;
S3 I TP W $$CR^cA334 F K=0,11,19,30,49,64,79 W ?K,@F30
S3A E  F K=1,12,20,31,50,65,80 S FP=LN*100+K W @F,@LYN
S3Z Q
 ;
F1 S R=250
F2 D TXT^cAFA1(R)
FZ K R Q
 ;
ZZ ; 30.03.01 - 13 u 39 * V7.85