cAT26 ;Openstaand saldo ;%AT26 ; [ 01/19/01  10:13 AM ]
 ;
T0 ;Openstaand saldo ;
T1 ;Totaal ;
 ;
T0F ;Solde ouvert ;
T1F ;Total  ;
 ;
T0E ;Outstanding balance ;
T1E ;Total ;
 ;
 ; som openstaande facturen
1 S U3=0 G YZ:'$D(J1),YZ:'$L(J1),YZ:'$D(R1) S R=9999
11 S R=$O(@("^"_Q_R1_"(J1,R)")) I R'?5N,R'?6N G YZ
13 S R2=^(R),R3=$P(R2,D,10)
 I R1="KL" S R3=R3-($$BET(J1,R,$P(R2,D,9))*($P(R2,D)="F"*2-1))
 I $P(R2,D)="C" S R3=-R3
15 S U3=U3+R3 G 11
 ;
 ; som vervallen facturen
2 S U3=0 G YZ:'$D(J1),YZ:'$L(J1),YZ:'$D(R1) S R=9999
21 S R=$O(@("^"_Q_R1_"(J1,R)")) I R'?5N,R'?6N G YZ
23 S R2=^(R),R3=$P(R2,D,10)
 I R1="KL" S R3=R3-($$BET(J1,R,$P(R2,D,9))*($P(R2,D)="F"*2-1))
 I $P(R2,D)="C" S R3=-R3
25 I $$DH^cAFD1($P(R2,D,3))'>$H S U3=U3+R3
27 G 21
 ;
YZ K R,R1,R2,R3 Q
 ;
 ; aantal facturen, voorschotten ?
S1 S U3=0 G S1Z:'$D(J1),S1Z:'$L(J1),S1Z:'$D(R1) S R=9999
S1A S R=$O(@("^"_Q_R1_"(J1,R)")) I R?5.6N S:$P(^(R),D,10) U3=U3+1 G S1A
S1Z K R,R1 Q
 ;
 ; betaalde bedrag via kassabewerkingen, omgerekend naar BF
BET(I1,FNR,VM) 
 ; I1 = index1 van de klant
 ; FNR= factuurnummer
 ; VM = muntcode factuur
 N BET S $ZT="TRAP^cAN000"
 S BET=$P($G(@("^"_Q_"PVF")@(FNR,$P(I1," ",2))),D,2)
 I BET D
 . N MNTO
 . S MNTO=$$MNTO^cAFE1(Q,$$BJ^cAFE1(Q,DJ_"."_DM))
 . S BET=$$OMREK^cAFE1(Q,BET,VM,$P(MNTO,D),"F","")
BETZ Q BET
 ;
TOP(DMS,UI1)       ; aanvullen TOP in DMH
 N UQC,USC,UREF,I,J,K,NV,VV
 D DMS^cAN000("UQC","USC",DMS) I UQC=""!(USC="") G TOPZ
 S UREF=^DMC(UQC,USC,"DATA","REF")
 S (NV,VV)=0,I=9999 F  S I=$O(@UREF@(I)) Q:I'?5.6N  D
 . S J=^(I),K=$P(J,D,10)
 . I DMS="KL" S K=K-($$BET(UI1,I,$P(J,D,9))*($P(J,D)="F"*2-1))
 . I $P(J,D)="C" S K=-K
 . S NV=NV+K                                       ; openstaand
 . I $$DH^cAFD1($P(J,D,3))'>$H S VV=VV+K           ; vervallen
 I DMS="LE" S NV=-NV,VV=-VV
 S UTOP(100)=3_D_38_D_$P($T(@("T1"_QT)),U,2)_$$BF^cAFA1_D_4
 S UTOP(100.1)=3_D_49_D_":"_$$IP^cAFA1(NV,QD,14)_" "_$$IP^cAFA1(VV,QD,14)
TOPZ Q
 ;
ZZ ; 05.02.01 - 16 u 23 * V7.84