cICHKAS(S,JBD) ;Copieren bestanden via schijf ;%ICHKA; [ 02/04/98  11:57 AM ]
 ;
T0 ;Automatisch copieren bestanden ;
T1 ;Foutieve bestandslocatie ;
T2 ;Fout bij het schrijven (schijf beschadigd?) ;
T3 ;De schijf is vol ;
T4 ;Het bestand werd niet overgezet ;
T5 ;Het bestand werd volledig overgezet\"[] = ok";
T6 ;Er zijn geen Host File Servers beschikbaar;
 ;
T0F ;Copie automatique des fichiers ;
T1F ;Lieu du fichier fautif ;
T2F ;Erreur à l'écriture (disque abimé ?);
T3F ;Le disque est plein ;
T4F ;Le fichier n'a pas été transféré ;
T5F ;Le fichier a été transféré intégralement\"[] = ok";
T6F ;Il n'a pas Host File Servers disponibles;
 ;
1 S $ZT="^cA406",D="\",%LOG="^cLOG(boot,""CHANGE"",""G"",S)"
 S LOG="^|home|ZZLOG(""CHANGE"",""G"",S)"
 S LOGC="^|home|ZZLOG(""GCOPY"",""G"",S)"
 ;
 S UCS=$ZU(5) D MASTER^cQ5,IN^cQMSMSW("MGR,"_boot)
 S home=$G(@%LOG@(0,"HOME")) G YZ:'$L(home) 
 L +@LOG@(0,UCS,S):15 E  G YZ
 D ^cA105,^cA106
 ;
 ; ophalen systemen die via schijf gaan
 S SYS=""
 F  S SYS=$O(@%LOG@(0,"FILE",SYS)) Q:SYS=""  S SYS("MGR,"_SYS)=^(SYS)
 ;
 S TU=""
 F  S TU=$O(SYS(TU)) Q:TU=""  D
 . S TUI=$P(TU,",",2),B=SYS(TU) I '$L(B) Q
 . S HFS=$$HFS^cQ9 I HFS<51!(HFS>54) S ER=$P($T(@("T6"_QT)),U,2) D F1 Q
 . O HFS:(B:"W"::::$C(13,10)) U HFS D S1
 . I ZC'=0 C HFS S ER=$P($T(@("T1"_QT)),U,2) D F1 Q
 . S OUT(1)=DT_" - "_TD,OUT(2)=$ZU(5)_" -> "_TU S ER=$$OUT I $L(ER) C HFS D F1 Q
 . S G=0
 . F  S G=$O(@%LOG@(G)) Q:G=""  D  Q:$L($G(ER))
 .. I G["^SYS",TUI'=$P(TU,",",2)!(TU=$ZU(5)) Q
 .. I G'["^SYS",TU=$ZU(5),TUI=boot Q
 .. S NA=@%LOG@(G),$ZT="ERRT",(GF,GT)=G
 .. I G["boot" D
 ... S GF=$P(G,"boot",1)_""""_$P($ZU(5),",",2)_""""_$P(G,"boot",2,$L(G,"boot"))
 ... S GT=$P(G,"boot",1)_""""_TUI_""""_$P(G,"boot",2,$L(G,"boot"))
 .. S GX=GF S:$E(GT)="^" GT=$E(GT,2,$L(GT))
 .. F  S GX=$Q(@GX) Q:GX=""  Q:$NA(@GX,NA)'=$NA(@GF,NA)  D  I $L(ER) Q
 ... I GF["^SYS(0,""DDB""",$P(@GX,",")'="LATP" Q
 ... S OUT(1)="^|"""_TU_"""|"_$E(GT,1,$L(GT)-1)_$E(GX,$L(GT)+1,$L(GX))
 ... S OUT(2)=@GX
 ... S ER=$$OUT I $L(ER) D F1 Q
 .. S @LOGC@(G,TU,TUI)=DT_D_TD_"  via "_B
 .. S OUT(1)="*",OUT(2)="*" S ER=$$OUT I $L(ER) D F1
 . I '$L(ER) S OUT(3)="**" S ER=$$OUT I $L(ER) D F1
 . C HFS
 ;
 L -@LOG@(0,UCS,S):1
 ;
YZ D IN^cQMSMSW(UCS) Q
 ;
S1 S ZA=$ZA,ZB=$ZB,ZC=$ZC
S1Z Q
 ;
F1 S ER=$P($T(+0),U)_" : "_$G(TUI)_" : "_ER
 I '$G(JBD) U $P S K=ER D TXT^cAFA1(250)
 I $G(JBD) S %=ER D ^cA400
 D ERRT
 Q
 ;
OUT() ; schrijven naar schijf
 N I,R
 S I="" F  S I=$O(OUT(I)) Q:I=""  D
 . U HFS
 . W OUT(I),!
 . D S1
 . I ZA<0!(ZC<0) S R=$P($T(@("T3"_QT)),U,2) Q
 . I ZC S R=$P($T(@("T2"_QT)),U,2) Q
 K OUT
 I $L($G(R)) C HFS
 Q $G(R)
 ;
IN(S,JBD,home) ; inlezen van schijf
 D
 . N S,JBD,home
 . D ^cA604
 S home=$G(home,$ZU(5))
 S SYS=""
 F  S SYS=$O(^cLOG(boot,"CHANGE","G",S,0,"FILE",SYS)) Q:SYS=""  D
 . S B=^(SYS),LOC=$P(B,"/",1,$L(B,"/")-1)
 . D IN^cICHKIN(LOC,home,S)
 Q
 ;
ERRT S @LOGC@(G,TU,TUI)=DT_D_TD_D_$G(ER,$ZE)
 I $G(HFS) C HFS
 Q
 ;
ZZ ; 04.02.98 - 16 u 38 * V6.5.01