cICHKSGP ;CONTROLE GELIJKHEID BESTANDEN ;%ICHKSGP; [ 02/22/00  9:32 AM ]
 G 1
 ;
SPEC(T0,T4,T6)        ; ingang voor spec. progr. T0 = titel, T4 = vervanging voor 
              ; $P($T(T4),U,3), T6 : vervanging T6
 G 1
 ;
T0 ;CONTROLE GELIJKHEID BESTANDEN ;
T1 ;PLAATS BREED BLANKO PAPIER OP DE PRINTER EN SCHAKEL HEM AAN\"[] = OK   ,[] = HERNEMEN";
T2 ;Blz :;
T3 ;Bestand                        Systeem         Checksum   Aantal nodes     Vgl.Schema's;
T4 ;Totaal    ;bestanden;
T5 ;De systemen staan exact gelijk.;
T6 ;Schema ;
T7 ;Vergelijkingschema's : ;
 ;
T0F ;CONTROLE EGALITE DES FICHIERS ;
T1F ;PLACEZ DU PAPIER LARGE SUR L'IMPRIMAMTE ET METTEZ-LA EN MARCHE\"[] = OK   ,[] = REPRENDRE";
T2F ;Page:;
T3F ;Fichier                        Système         Checksum   Nombres d'ind.   Schemas de comp.;
T4F ;Total     ;fichiers;
T5F ;Les systèmes sont des copies identiques.;
T6F ;Schema ;
T7F ;Vergelijkingschema's : ;
 ;
1 S NM1=$G(@("^"_Q_"BA(99,1)")),NM2=$G(^(2)),NM3=$G(^(3)),LOG=$G(LOG,"^|home|ZZLOG(""CHECK"",""G"")")
 S R="K\22\3\"_$P($T(@("T1"_QT)),U,2)_"\1\\""-,""[K\" D R0 I K="-"!(K=",") G YZ
 S %G="",B=130,C=38,BLZ=1 X F70 W @F80 D HDR,NL
 ;
2 S COMP=""
 F I=1:1 S COMP=$O(@LOG@(S,0,"COMPARE",COMP)) Q:COMP=""  D
 . S K=^(COMP)
 . I I=1 W $P($T(@("T7"_QT)),U,2) S V=$L($P($T(@("T7"_QT)),U,2))+1
 . W ?V,$P(K,U),"  ",$P(K,U,2) D NL
 I I>1 D NL
 ;
 F  S %G=$O(@LOG@(S,%G)) Q:%G=""  D  D NL
 . W ?1,$S(%G=0:$P($T(@("T4"_QT)),U,2),1:%G_$J("",10-$L(%G)))
 . F I=1:1:IU I $D(@LOG@(S,%G,UCS(I))) D  D NL
 .. S K=$G(^(UCS(I)))
 .. W ?31,UCS(I),"  "
 .. I $P(K,D)'?1.N W $P(K,D)
 .. I $P(K,D)?1.N D
 ... W $$INTERP^cQ9($P(K,D),0,16),"  "
 ... W $$INTERP^cQ9($P(K,D,2),0,$S(%G=0:6,1:12))
 ... I %G'=0 W "    ",$P($P(K,D,3),",",1,$L($P(K,D,3),",")-1)
 .. I %G=0 D
 ... I $P(K,D)?1.N W $S($D(T4):T4,1:$P($T(@("T4"_QT)),U,3))
 ... W ?80,$P(K,D,3),"  ",$P(K,D,4)," -> ",$P(K,D,5),"  ",$P(K,D,6)
 . I $O(@LOG@(S,0))="" W !!!?1,$P($T(@("T5"_QT)),U,2)
 ;
3 W # X F71
 ;
YZ Q
 ;
HDR S K=$S($D(T0):$P(T0,U),1:$P($T(@("T0"_QT)),U,2))
 W !,NM1,?B-8,$P($T(@("T2"_QT)),U,2),$J(BLZ,3)
 W !,NM2,$C(13) S $X=0 W ?B\2-$L(K),@F82,K,@F83,$C(13) S $X=0 W ?B-8,DT
 W !,NM3,$C(13) S $X=0 W ?B\2-$L($P($G(T0),U,2)),$P($G(T0),U,2),?B-7,TD,! W:$D(ISO) ?B-$L(ISO),ISO S $Y=0
 W !,$S($D(T6):T6,1:$P($T(@("T6"_QT)),U,2)),S," -> " F II=1:1:IU W UCS(II),$S(II'=IU:" - ",1:"")
 S K="",$P(K,"-",B)="-" W !,$P($T(@("T3"_QT)),U,2),!,K,! S K=""
 Q
 ;
NL W ! I $Y-8>LNMAX W # S BLZ=BLZ+1 D HDR
 Q
 ;
R0 S R0=$P(R,D,5) I $L(R0),R0'["""" S $P(R,D,5)=R0_"^"_$T(+0)
R0A S R0=$P(R,D,7) I $L(R0),R0'="DCTR" S $P(R,D,7)="",R1=$P(R,D,8),R0=$P($T(@R0),U,2,99) S:$L(R1) R0=R0_"&("_R1_")" S $P(R,D,8)=R0
R0Z S $P(R,D,12)=$T(+0) K R0,R1 D ^cA100 Q  ; V11 30.05.94
 ;
ZZ ; 13.03.00 - 17 u 31 * V7.3