cT323	;Aankoopdagboek naar Excel;%T32 ;%T32* ; [ 01/11/01  6:02 PM ]
	G 1
	;
T0	;Aankoopdagboek ;
T1	;JRN\ \Document\Datum\Nummer\Naam van de leverancier\Totaal doc.\Goederen\Diensten\Investering\Andere\MVH G\MVH D\MVH I\MVH A\Aftrekbare BTW\O.H.\I.C.\M.C.\Verlegging\Niet-aftrekbare BTW\IC\BTW-nummer\Ini;\Datum;
T2	;\Boekingsmaand;
T3	;Aftrekbare BTW overige;
	;
T0F	;Journal des achats ;
T1F	;JRN\ \Document\Date\Numéro\Nom du fournisseur\Total doc.\Marchandises\Services\Investissements\Autres\Mes. tax. M\Mes. tax. S\Mes. tax. I\Mes. tax. A\TVA déduct.\Imm.\I.C.\C.C.\Rep.\TVA non déduct\IC\N° de TVA\Ini;\Date;
T2F	;\Mois comptable;
T3F	;TVA déduct. rest.;
	;
T0E	;Purchase journal ;
T1E	;JRN\ \Document\Date\Number\Supplier Name\Total Doc.\Goods\Services\Invest.\Other\Base of Tax. G\Base of Tax. S\Base of Tax. I\Base of Tax. O\Decuctible VAT\ImCh\ImCh\CoCo\TrCh\Non decuctible VAT\IC\VAT-number\Ini;\Date;
T2E	;\Fiscal month;
T3E	;Ohter decuctible VAT;
	; 
T0D	;Einkaufsjournal ;
T1D	;JRN\ \Dokument\Datum\Nummer\Name des Lieferanten\Total dok.\Waren\Diensten\Investierung\Andere\MVH G\MVH D\MVH I\MVH A\Abz. MWST\O.H.\I.C.\M.C.\Verlegging\Nicht-Abz. MWST\IC\MWST-nummer\Ini;\Datum;
T2D	;\Rechnungsmonat;
T3D	;Abz. MWST Ubrige;
	;
1	S HD(1)=D,HD(2)=D_MNM_";C;F82",HD(3)=D_TIT
11	S TIT(1)=$P($T(@("T1"_QT)),U,2)
	; GM 17.01.04 Aanpassingen ivm "Aftrekbare BTW overige" (Hannecard Zw.)
	S AFBTWA="" I $L($G(@("^"_Q_"BA(15,20)"))) S AFBTWA=1 S $P(TIT(1),D,21)=$P($T(@("T3"_QT)),U,2)
	;
12	S TAB="4\8\15\24\31\60\71\82\93\104\115\126\137\148\159\170\181\192\203\214\225\228\249\253"
	I $P($G(QU(0,2)),D,39) S TAB=TAB_D_($P(TAB,D,$L(TAB,D))+8),TIT(1)=TIT(1)_$P($T(@("T1"_QT)),U,3)
	I PTS=3!(PTS=4) S TIT(1)=TIT(1)_$P($T(@("T2"_QT)),U,2),TAB=TAB_"\"_($P(TAB,"\",$L(TAB,"\"))+8)
13	K A
	;
	; opbouwen ^HULP(boot,$j+.99,... per journaal (FB - 10.12.02)
	; 
131	K ^HULP(boot,$J+.99) S I1=""
	F  S I1=$O(@Q6) Q:I1=""  I I1'["." D
	. S INH=^(I1),JRN=$P(INH,D,21) S:'JRN JRN=0 
	. I SRT="A"!(JRN=SRT) S ^HULP(boot,$J+.99,JRN,I1)=INH
	;
	; aflopen ^HULP(boot,$J+.99,... voor afdruk per journaal (FB - 10.12.02)
	; 
14	S JRN=""
141	S JRN=$O(^HULP(boot,$J+.99,JRN)) G YZ:JRN="" S I1="",Q6="^HULP(boot,$J+.99,JRN,I1)"
143	K A
	S JRNNR=$E("000",1,3-$L(JRN))_JRN
	S JRNC=$$JRN^cAFO2("A",JRNNR)
	S JRNCODE="A"_$S('JRN:"",1:$E("000",1,3-$L(JRN)))_$S('JRN:"",1:JRN)
	S JRNOMS=$P(@("^"_Q_"BA(""%T"",JRNCODE)"),D,2)_" "_$P(^(JRNCODE),D)
	;
	;dagboek
2	S I1=$O(@Q6) G 141:'$L(I1),2:I1#1 S Z=^(I1) G 2:$P(Z,D,21)-SRT&(SRT'="A")
	; GM 17.01.04 Aanpassingen ivm "Aftrekbare BTW overige" (Hannecard Zw.)
	I AFBTWA S $P(Z,D,9)=$P(Z,D,38)
	;
21	S BTWNR=$P(Z,D,36) S:'$L(BTWNR) BTWNR=0
	S BTWNR=$$BTW^cAFO1($S(BTWNR'=0:BTWNR,1:$P($G(@("^"_Q_"BTW(0,0)")),D,7)))
	S K=0,A("JRN",JRN,1)=7 
	F I=7,14,13,15 S X=$P(Z,D,I) I +X!+$P(X,"#",2) S K=K+1,A("JRN",JRN,K)=I
25	S FC=$P(Z,D),KC=$P(Z,D,4),B(1)=@("^"_Q_"LE(^"_Q_"L1(KC),0)") F I=1:1:23 S TXT(I)=""
	;
	;printen
4	F I=7:1:21 S $P(TXT(I),D,27)=0 I QD>0 S $P(TXT(I),D,27)="0." F J=1:1:QD S $P(TXT(I),D,27)=$P(TXT(I),D,27)_"0"
	;  Journaal
	S TXT(1)=$S(JRN:JRNC,1:"")
	; F/C
	S TXT(2)=FC
	; Document
	S TXT(3)=I1
	; Datum
	S TXT(4)=$P(Z,D,2)
	; Nummer
	S TXT(5)=KC
	; Naam
	S TXT(6)=$P(B(1),D,2)
	; Totaal document
	S TXT(7)=$S($P(Z,D)="C":-$P(Z,D,6),1:+$P(Z,D,6))_"\\\\1\"_QD_"\\1"
	; BTW-nummer
	S TXT(23)=BTWNR
	; Initialen
	S TXT(24)=$P(Z,D,33)
	; Datum
	S VNR=24
	I $P($G(QU(0,2)),D,39) S VNR=VNR+1 S TXT(VNR)=$S($L($P(Z,D,32)):$$HD^cAFD1($P(Z,D,32)),1:"")
	; Boekingsmaand
	I PTS=3!(PTS=4) S VNR=VNR+1 S TXT(VNR)=BP
	; Aftrekbare BTW
	S TXT(16)=$S($P(Z,D)="C":-$P(Z,D,8),1:$P(Z,D,8))_"\\\\1\"_QD_"\\1"
	; BTW-uitsplitsing
	F I=11,12,16,17 I $P(Z,D,I) S VNR=$S(I=11:17,I=12:18,I=16:20,1:19),TXT(VNR)=$S($P(Z,D)="C":-$P(Z,D,I),1:$P(Z,D,I))_"\\\\1\"_QD_"\\1" Q
	; Niet aftrekbare BTW
	S TXT(21)=$S($P(Z,D)="C":-$P(Z,D,9),1:$P(Z,D,9))_"\\\\1\"_QD_"\\1" I +$P(Z,D,9)=0 S $P(TXT(21),D)=""
	; I.C.
	S TXT(22)="" I I=12 S TXT(22)=1
	; Uitsplitsing bedrag en MVH
	S X=""
	F  S X=$O(A("JRN",JRN,X))  Q:(X="")  D
	. S Y=A("JRN",JRN,X),VNR1=$S(Y=7:8,Y=14:9,Y=13:10,1:11),VNR2=$S(Y=7:12,Y=14:13,Y=13:14,1:15)
	. S TXT(VNR1)=$S($P(Z,D)="C":-$P(Z,D,Y),1:+$P(Z,D,Y))_"\\\\1\"_QD_"\\1",TXT(VNR2)=$S($P(Z,D)="C":-$P($P(Z,D,Y),"#",2),1:$P($P(Z,D,Y),"#",2))_"\\\\1\"_QD_"\\1"
	K A("JRN",JRN)
	F I=7:1:21 S $P(TXT(I),D,8)=1
	;
5	D ^cA334 F I=1:1:23 S TXT(I)=""
51	G 2
	;
YZ	S END=1 D ^cA334 Q
	;
ZZ	; 19.03.07 - 15 u 31 * V8.08