cT47 ;Exploitatiestaat ;%T47 ; [ 01/03/01  10:07 AM ]
 G 1
 ;
T0 ;Exploitatiestaat ;
T1 ;Gewenste maand\"jjjj.mm[] = bepaalde maand   -[] = einde programma";
T3 ;Bedragen;realisatie;budget;evaluatie;
T4 ;Cumulatie;neen;ja;
 ;
T0F ;Etat d'exploitation ;
T1F ;Mois\"aaaa.mm[] = mois spécifique    -[] = fin du programme";
T3F ;Montants;réalisation;budget;évaluation;
T4F ;Cumuls;non;oui;
 ;
T0E ;Exploitation survey ;
T1E ;Desired month\"yyyy.mm[] = particular month   -[] = end program";
T3E ;Amounts;realisation;budget;evaluation;
T4E ;Global amount;no;yes;
 ;
S1(S1,S2,S3)       ;saldoberekening: S1=wat, S2=boekjaar, S3=veld in cumulnode
S1A S S4=$G(^(S2)),S5=$G(^(S2+.02)) F S6=2:1:S3 S BE=$P(S4,D,S6)-$P(S5,D,S6) D S5 S $P(S(S1),D)=$P(S(S1),D)+BE
S1Z K S1,S2,S3,S4,S5,S6 Q
 ;
S2(S1,S2,S3)       ;maandcijfers
S2A S S4=$G(^(S2)),S5=$G(^(S2+.02)),S6=S3,BE=$P(S4,D,S6)-$P(S5,D,S6) D S5 S $P(S(S1),D)=$P(S(S1),D)+BE
S2Z K S1,S2,S3,S4,S5,S6 Q
 ;
S3(S1,S2,S3)       ;budgetberekening
S3A S S4=$G(^(S2+.04)),S5=$G(^(S2+.05)) F S6=2:1:S3 S BE=$P(S4,D,S6)-$P(S5,D,S6) D S5 S $P(S(S1),D,2)=$P(S(S1),D,2)+BE
S3Z K S1,S2,S3,S4,S5,S6 Q
 ;
S4(S1,S2,S3)       ;maandcijfers budget
S4A S S4=$G(^(S2+.04)),S5=$G(^(S2+.05)),S6=S3,BE=$P(S4,D,S6)-$P(S5,D,S6) D S5 S $P(S(S1),D,2)=$P(S(S1),D,2)+BE
S4Z K S1,S2,S3,S4,S5,S6 Q
 ;
 ; omrekening BEF/EUR
S5 I BE S BE=$$BEDR^cAFE1(Q,BE,$P($S(S2=BJ:MNTC,1:MNTC1),D),$P(MUNT,D),"F")
S5Z Q
 ;
 ; vraagstelling
1 D ^cT489 S BP=DJ_"."_DM I 'QP S BP=PP(1),BEDR=PP(2),CUM=PP(3),MUNT=PP(4)_D_PP(5),PTS=0 G 3
11 S K=$P($T(@("T0"_QT)),U,2)_QN_" ",FP=203+$L(K) W @F61,@F11,@F1,@F,@F5 S FP=202 W @F,@F4,K,@F5
13 S R="BP\22\3\"_$P($T(@("T1"_QT)),U,2)_"\7\\K?4N1"".""2N&(K#1)&(K#1<.13)!(K=""-"")!(K="","")\\\\\1" D R0 G YZ:K="-"!(K=",")
14 S FP=403 W @F,$P($P($T(@("T1"_QT)),U,2),D)," : ",BP
15 S BJ=$$BJ^cAFE1(Q,BP),MNTC=$$MNTC^cAFE1(Q,BJ) D ^cAFE6($S($P(MNTC,D)="EUR":1,1:3)) G 13:K="-"
16 S MUNT=$$S1^cAFE6(K) W /CUP(4,60),MUNT,@F2
17 S R="BEDR\22\3\"_$P($T(@("T3"_QT)),U,2)_"\C1\1\\""-,12""[K" D R0 G 15:K="-",13:K=","
19 W /CUP(6,3),$P($T(@("T3"_QT)),U,2)," : ",$P($T(@("T3"_QT)),U,3+BEDR),@F1
 ;
2 S CUM=0 I BEDR<2 G 17:K="-",25
21 S R="CUM\22\3\"_$P($T(@("T4"_QT)),U,2)_"\C2\1\\""-,1""[K" D R0 G 17:K="-",11:K=","
23 W /CUP(8,3),$P($T(@("T4"_QT)),U,2)," : ",$P($T(@("T4"_QT)),U,3+CUM),@F1
25 D ^cAN3223("","1#2",$S(BEDR=2:80,1:">80"),0) G 2:K="-",11:K=","
 ;
 ; berekening
3 S QD=$P(MUNT," ",2),MUNT=$P(MUNT,",")
31 S BJ=$$BJ^cAFE1(Q,BP),MNTC=$$MNTC^cAFE1(Q,BJ)
33 G YZ:BJ=0 S I=KM1(BJ) F BX=2:1 Q:I=BP  S I=$E(I+.01_0,1,7) S:I#1>.12 I=I+.88
35 S BP1=$E(BP-1_0,1,7),BJ1=$$BJ^cAFE1(Q,BP1),MNTC1=$$MNTC^cAFE1(Q,BJ1)
37 I BJ1 S I=KM1(BJ1) F BX1=2:1 Q:I=BP1  S I=$E(I+.01_0,1,7) S:I#1>.12 I=I+.88
 ;
 ; opbouw per exploitatiecode
4 K ^HULP(boot,$J) S I1=" "
41 S I1=$O(@("^"_Q_"AR(I1)")) I I1="" G ^cT470
43 S B(1)=$G(^(I1,0)),EK=$P(B(1),D,16),FP=2203 W:QP @F,I1,EK,@F1 I EK="" G 41
45 F I=BJ,BP,BJ1,BP1 S S(I)=D
46 I BEDR'=1 D         ; berekening realisatie
 . I '$P(B(1),D,20)&0 S S(BJ)=$$BSAL^cAFE1(Q,BJ,"AR",I1),S(BJ)=$$BEDR^cAFE1(Q,S(BJ),$P(MNTC,D),$P(MUNT,D),"F")
 . D S1(BJ,BJ,BX),S2(BP,BJ,BX)
 . I BJ1 D
 .. I '$P(B(1),D,20)&0 S S(BJ1)=$$BSAL^cAFE1(Q,BJ1,"AR",I1),S(BJ1)=$$BEDR^cAFE1(Q,S(BJ1),$P(MNTC1,D),$P(MUNT,D),"F")
 .. D S1(BJ1,BJ1,BX1),S2(BP1,BJ1,BX1)
47 I BEDR D            ; berekening budget
 . D S3(BJ,BJ,BX),S4(BP,BJ,BX)
 . I BJ1 D S3(BJ1,BJ1,BX1),S4(BP1,BJ1,BX1)
48 F I=BJ,BP,BJ1,BP1 S J=$G(^HULP(boot,$J,EK,I)),^(I)=J+S(I)_D_($P(J,D,2)+$P(S(I),D,2))
49 G 41
 ;
YZ Q
 ;
 ; commentaar BEDR
C1 W !?2 F I=0:1:2 W:I $J(I,4) W "[] = ",$P($T(@("T3"_QT)),U,I+3)
C1Z Q
 ;
 ; commentaar CUM
C2 W !?2 F I=0,1 W:I $J(I,4) W "[] = ",$P($T(@("T4"_QT)),U,I+3)
C2Z Q
 ;
R0 S $P(R,D,12)=$T(+0) D ^cAN1000 Q  ; v12 23.01.95
 ;
ZZ ; 05.02.01 - 16 u 23 * V7.84