cT721	;Verkoopdagboek naar Excel ;%T72;   [ 25/11/09  11:12:39 ]
	G 1
	;
	; Aanpassing afdrukken verkoopdagboek : nov. 2002 (GD - FB)
	; opbouwen van ^HULP(boot,$J+.01,journaalnummer,factuur) = inhoud VE
	; aflopen van facturen per journaal, afdrukken per journaal met eindoverzicht
	; per journaal (lijnen 4 tot 66+2) en helemaal op het einde een algemeen overzicht 
	; (lijnen 7 tot 86+2 : "kopie" van lijnen 4 tot 66+2), 
	; journaal - overkoepelend, maar per BTW - nummer (was vroeger reeds ingebouwd)
	; 
T0	;Verkoopdagboek ;
T1	;JRN\ \Document\Datum\Nummer\Naam van de klant\Totaal doc.;\Totaal BTW\Speciale taks\Korting contant\Verschil\IC\BTW-nummer\Ini;\Datum;
T2	;0% (IC);0%(44) (IC);
T3	;\Boekingsmaand;
	;
T0F	;Journal des ventes ;
T1F	;JRN\ \Document\Date\Numéro\Nom du client\Total doc.;\Total TVA\Taxes spéciales\Escompte comptant\Comptant\IC\N° de TVA\Ini;\Date;
T2F	;0% (IC);0%(44) (IC);
T3F	;\Mois comptable;
	;
T0E	;Sales journal ;
T1E	;JRN\ \Document\Date\Number\Customer Name\Total Doc.;\Total VAT\Special Tax\In cash discount\Difference\IC\VAT-number\Ini;\Date;
T2E	;0% (IC);0%(44) (IC);
T3E	;\Fiscal month;
	; 
T0D	;Verkaufjournal ;
T1D	;JRN\ \Dokument\Datum\Nummer\Kundename\Total dok.;\Total MWSt\Spezielle taks\Skonto\Differenz\IC\MWst-nummer\Ini;\Datum;
T2D	;0% (IC);0%(44) (IC);
T3D	;\Buchungsmontat;
	;
	; start
1	S HD(1)=D,HD(2)=D_MNM_";C;F82",HD(3)=D_TIT
11	S (TEF,TEC)=0 K A,AA,^HULP(boot,$J),^HULP(boot,$J+.01)
	;
	; Opbouwen PBTW met mogelijke BTW-codes
14	D S1^cA305
	;  Samen stellen van de kolom titels
15	S TIT(1)=$P($T(@("T1"_QT)),U,2),TAB="4\8\15\24\31\60\71",VNR=0
16	S I1="",NR=0,MAANT=0
	F  S I1=$O(PBTW(I1)) Q:I1=""  D
	. ;  Enkel de opertationele BTW-codes worden getoond
	. I $P(@("^"_Q_"BA(18,I1)"),D,3) Q
	. S VNR=VNR+1,TIT(1)=TIT(1)_D_PBTW(I1),TAB=TAB_D_($P(TAB,D,$L(TAB,D))+11),BTW(I1)=VNR,MAANT=MAANT+1
	. I PBTW(I1)="0%" S VNR=VNR+1,TIT(1)=TIT(1)_D_$P($T(@("T2"_QT)),U,2),TAB=TAB_D_($P(TAB,D,$L(TAB,D))+11),BTW(I1_"IC")=VNR,MAANT=MAANT+1
	. I BP>2010,PBTW(I1)="0%(44)" S VNR=VNR+1,TIT(1)=TIT(1)_D_$P($T(@("T2"_QT)),U,3),TAB=TAB_D_($P(TAB,D,$L(TAB,D))+11),BTW(I1_"IC")=VNR,MAANT=MAANT+1
17	S TAB=TAB_D_($P(TAB,D,$L(TAB,D))+11),TAB=TAB_D_($P(TAB,D,$L(TAB,D))+14),TAB=TAB_D_($P(TAB,D,$L(TAB,D))+16)
170	S TAB=TAB_D_($P(TAB,D,$L(TAB,D))+11),TAB=TAB_D_($P(TAB,D,$L(TAB,D))+3),TAB=TAB_D_($P(TAB,D,$L(TAB,D))+21),TAB=TAB_D_($P(TAB,D,$L(TAB,D))+4)
171	S TIT(1)=TIT(1)_$P($T(@("T1"_QT)),U,3)
	I $P($G(QU(0,2)),D,39) S TAB=TAB_D_($P(TAB,D,$L(TAB,D))+8),TIT(1)=TIT(1)_$P($T(@("T1"_QT)),U,4)
172	I $G(PTS)=3!($G(PTS)=4) S TAB=TAB_"\"_($P(TAB,"\",$L(TAB,"\"))+8),TIT(1)=TIT(1)_$P($T(@("T3"_QT)),U,2)
	; 
	; opbouwen ^HULP(boot,$J+.01,... per journaal - FB - 20.11.02
18	S I1="" F  S I1=$O(@Q6) Q:I1=""  I I1'["." D
	. S INH=^(I1),JRN=$P(INH,D,21) S:'JRN JRN=0 I SRT="A"!(SRT=JRN) S ^HULP(boot,$J+.01,JRN,I1)=INH
	;
	; aflopen van opgebouwde ^HULP en afdrukken per journaal - FB - 20.11.02
19	S JRN=""
191	S JRN=$O(^HULP(boot,$J+.01,JRN)) G YZ:JRN="" S I1="",Q6="^HULP(boot,$J+.01,JRN,I1)"
	;
	; dagboek
2	K A
	S JRNNR=$E("000",1,3-$L(JRN))_JRN
	S JRNC=$$JRN^cAFO2("V",JRNNR)
	S JRNCODE="V"_$S('JRN:"",1:$E("000",1,3-$L(JRN)))_$S('JRN:"",1:JRN)
	S JRNOMS=$P(@("^"_Q_"BA(""%T"",JRNCODE)"),D,2)_" "_$P(^(JRNCODE),D)
	F  S I1=$O(@Q6) Q:'$L(I1)  I '(I1#1) S Z=^(I1) D
	. S SWIC=$$ICVE^cT00A(Q,BP,I1)
	. K TXT
	. S VVNR=8,AANT=VVNR+$P($O(PBTW(""),-1),D)+4
	. I AANT>VVNR F I=VVNR:1:AANT S $P(TXT(I),D,8)=1,$P(TXT(I),D,27)=0 I QD>0 S $P(TXT(I),D,27)="0." F J=1:1:QD S $P(TXT(I),D,27)=$P(TXT(I),D,27)_"0"
	. ;  JRN
	. S TXT(1)=JRNC
	. ;  F/C
	. S TXT(2)=$P(Z,D)
	. ;  Document
	. S TXT(3)=I1
	. ;  Datum
	. S TXT(4)=$P(Z,D,2)
	. ;  Nummer klant
	. S TXT(5)=$P(Z,D,4)
	. ;  Naam klant
	. S TXT(6)=$$SG^cAFA1("KL",$P(Z,D,4),102)
	. ;  Totaal bedrag document
	. S TXT(7)=$S($P(Z,D)="C":-$P(Z,D,6),1:$P(Z,D,6))_"\\\\1\"_QD_"\\1"
	. ;  Maatstaf van heffing per BTW-percentage
	. S MST=$P(Z,D,11)
	. S SWBTW=0
	. S VNR=7
	. F I=1:2 Q:'$L($P(MST,"#",I))  D
	.. S NR=$P(MST,"#",I)
	.. I $P(@("^"_Q_"BA(18,NR)"),D,3) S SWBTW=1 Q
	.. S AANT=BTW(NR)
	.. ; I NR=0,$$ICVE^cT00A(Q,BP,I1) S AANT=BTW(NR_"IC")
	.. I SWIC,(U_$P(SWIC,D,2)_U)[(U_NR_U) S AANT=BTW(NR_"IC")  ; KU : 25.11.09
	.. S TXT(VNR+AANT)=$S($P(Z,D)="C":-$P(MST,"#",I+1),1:$P(MST,"#",I+1))_"\\\\1\"_QD_"\\1"
	. S NR=MAANT
	. S VNR=VNR+NR
	. ;  Totaal BTW
	. S VNR=VNR+1 I +$P(Z,D,8)'=0 S TXT(VNR)=$S($P(Z,D)="C":-$P(Z,D,8),1:$P(Z,D,8))_"\\\\1\"_QD_"\\1"
	. ;  Speciale taks
	. S VNR=VNR+1 I +$P(Z,D,18)'=0 S TXT(VNR)=$S($P(Z,D)="C":-$P(Z,D,18),1:$P(Z,D,18))_"\\\\1\"_QD_"\\1"
	. ;  Korting contant
	. S VNR=VNR+1 I +$P(Z,D,10)'=0 S TXT(VNR)=$S($P(Z,D)="C":-$P(Z,D,10),1:$P(Z,D,10))_"\\\\1\"_QD_"\\1"
	. ;  Verschil
	. S SMST=0
	. ; optelling
23	. F I=2:2 Q:'$L($P(MST,"#",I))  D
	.. S SMST=SMST+$P(MST,"#",I)
	. S VNR=VNR+1 I +($P(Z,D,7)-SMST-$P(Z,D,10))'=0 S TXT(VNR)=$S($P(Z,D)="C":-($P(Z,D,7)-SMST-$P(Z,D,10)),1:$P(Z,D,7)-SMST-$P(Z,D,10))_"\\\\1\"_QD_"\\1"
	. ;  IC
	. S VNR=VNR+1,TXT(VNR)="" I $$ICVE^cT00A(Q,BP,I1) S TXT(VNR)=1
	. ;  BTW-nr
	. S BTWNR=$P(Z,D,36) I BTWNR="" S BTWNR=0
	. S VNR=VNR+1,TXT(VNR)=$$BTW^cAFO1($S(BTWNR'=0:BTWNR,1:$P($G(@("^"_Q_"BTW(0,0)")),D,7)))
	. I SWBTW S TXT(VNR)=""
	. ; Initialen
	. S VNR=VNR+1,TXT(VNR)=$P(Z,D,29)
	. ; Datum
	. I $P($G(QU(0,2)),D,39) S VNR=VNR+1,TXT(VNR)=$S($L($P(Z,D,28)):$$HD^cAFD1($P(Z,D,28)),1:"")
	. I $G(PTS)=3!($G(PTS)=4) S VNR=VNR+1,TXT(VNR)=BP
	. D ^cA334
21	G 191
	;
YZ	S END=1 D ^cA334 Q
	;
ZZ	; 22.06.04 - 16 u 32 * V8