cTEA8	;Controlelijst budget rekening - analytische rekening ;cTEA8 ;
	;
T0	;Controlelijst rekening-anal. rekening ;
T1	;Nummer\Naam van de rekening\Nummer\Naam van de anal.rekening
T10	;Boekjaar\"-[] = einde programma   [] = ;
T11	;Boekjaar;
T12	;Totaal;
	;
T0F	;Liste de contrôle compte-compte analytique ;
T1F	;Numéro\Nom du compte\Numéro\Nom du compte anal.
T10F	;Année comptable\"-[] = fin du programme   [] = ;
T11F	;Année comptable;
T12F	;Total;
	;
1	D P^cA612(2,1,20,80,1,0,1,1,$P($T(@("T0"_QT)),U,2),0,0,7,1,1)
11	W /CUP(2,2),@F1
	S J=@("^"_Q_"BA(2)"),K=^(7),PAT="",I=$P(J,D,2),BJ=I\1,I=I\1*12+(I#1*100),J=J-1 
	D BJ G YZ:K="-"
	S BMAAND=""
12	S J=J+1 I J<I S BJ=J\12,PAT=PAT_$$LC^cAFA1(^cBA(2,$E(QT_"N"),J#12+1)_D) S:(BMAAND="") BMAAND=BJ_$TR($J(J#12+1,2)," ",0) G 12
	S EMAAND=BJ_$TR($J((J-1)#12+1,2)," ",0)
	S $P(PAT,D,$L(PAT,D))=$P($T(@("T12"_QT)),U,2) 
	;
2	W /CUP(2,2),@F6,$P($T(@("T11"_QT)),U,2),@F9,": "_BJ
21	D ^cAN003(4,"AR") G 11:K="-"
	;
3	D ^cAN003(9,"ARA") G 21:K="-"
	;
4	D ^cAN3223("","1#4#5",">80") G 3:K="-"
	;
5	K ^TEMP(boot,$J) 
	S j=0
51	D ^cAN004("UI1ARA","ARA") G 6:UI1ARA="" S j=j+1
	S ^TEMP(boot,$J,1,j_" "_UI1ARA)=UI1ARA G 51
	;
6	S HD(1)=D,HD(2)=D_$P($T(@("T0"_QT)),U,2)_BJ_";C;F82;2",HD(3)=D 
	S TAB="7\30\37\60",TIT(1)=$P($T(@("T1"_QT)),U,2,99)
	;F t=1:1:$L(PAT,D) S TAB=TAB_D_(9*t+60),TIT(1)=TIT(1)_D_$P(PAT,D,t)_U_"2" 
	F t=1:1:$L(PAT,D) S TAB=TAB_D_(9*t+60),TIT(1)=TIT(1)_D_$$FM($P(PAT,D,t))  
	; SW - 01.07.05 : -kolomtitels steeds links aligneren.
	;                 -kolommen met maanden moeten in excel ongeveer even breed zijn
	;                 -maanden als kolomtitel met hoofdletter 
	;
7	D ^cAN004("UI1AR","AR") G 79:UI1AR=""
	D GD("AR",UI1AR,.ARNR,.AROMSCH)
	S TXT(1)=ARNR
	S TXT(2)=AROMSCH
	S IARA="" F  S IARA=$O(^TEMP(boot,$J,1,IARA)) Q:IARA=""  D
	. S IARAMS=^(IARA)
	. D GD("ARA",IARAMS,.ARANR,.ARAOMSCH)
	. S TXT(3)=ARANR
	. S TXT(4)=ARAOMSCH
	. S TOTM=0
	. S HMAAND=BMAAND
	. S COMBFOUND=0
	. F  Q:HMAAND>EMAAND  D
	.. S BSALDO=$$GA("BUD.AR.ARA",HMAAND,UI1AR,IARAMS)
	.. ; I $L(BSALDO) D ; SW 01.07.05 - Saldo's gelijk aan 0 voor alle maanden worden niet getoond 
	.. ; vroeger stond er "..." vanaf S COMBFOUND=1 tot en met S TOTM=TOTM+BSALDO
	.. ;S COMBFOUND=1
	.. S:BSALDO COMBFOUND=1 ; SW 01.07.05 
	.. S:'$L(BSALDO) BSALDO=0
	.. S TXTSUB=$$MI(HMAAND,BMAAND)
	.. S TXT(TXTSUB+4)=$$FN(BSALDO)
	.. S TOTM=TOTM+BSALDO
	.. S HMAAND=$$VO(HMAAND) 
	. S:(COMBFOUND) TXT($L(PAT,D)+4)=$$FN(TOTM)
	. D:(COMBFOUND) ^cA334
	G 7
79	S END=1 D ^cA334 
	;
Y	K ^TEMP(boot,$J) 
YZ	D E^cA612 Q
	;
	; Vraagstelling naar boekjaar
BJ	S R="K\22\3\"_$P($T(@("T10"_QT)),U,2)_(BJ+1)_"   .[] = "_(BJ)_"""\1\\""-.""[K" D R0 
BJZ	S:'$L(K) J=I-1,I=I+12 Q
	;
	;
	;
FM(MAAND)	; Formaat voor maanden : met hoofdletter beginnen en spaties toevoegen. SW - 01.07.05
	S $ZT="TRAP^cAN000"
	S MAAND=$$UC^cAFA1($E(MAAND))_$E(MAAND,2,$L(MAAND))
	F j=1:1:(7-$L(MAAND)) S MAAND=MAAND_"  "
FMZ	Q MAAND
	;
FN(NUMGEG)	; Formaat voor export Excel en interpunctie bij printen voor numeriek gegeven
	S $ZT="TRAP^cAN000"
	S NUMGEG=NUMGEG_"\\\\1\"_$P($$MNTC^cAFE1(Q,BJ),D,2)
FNZ	Q NUMGEG
	;       
MI(HMAAND,BMAAND)	; Bepaal volgnummer van de huidige maand tov de beginmaand van het boekjaar
	N RETMI,HM,BM
	S $ZT="TRAP^cAN000"
	S HM=HMAAND\100*12+(HMAAND#100),BM=BMAAND\100*12+(BMAAND#100)
	S RETMI=HM-BM+1
MIZ	Q RETMI
	;       
GA(GLSUB,HMAAND,I1,I2)	; Ophalen saldo van actieve records
	N SALDO,RETSTR  
	S $ZT="TRAP^cAN000"
	S SALDO=""
	S RETSTR=$G(^DBH(Q,GLSUB,HMAAND_" "_I1_I2_"0 0",0))  ;I1 , I2 doorgeven met spatie achteraan (key)
	I '$L($G(RETSTR)) G GAZ
	I ($P($G(RETSTR),D,30)) G GAZ
	S SALDO=$P(RETSTR,D,6)-$P(RETSTR,D,7)
GAZ	Q SALDO
	;
VO(HMAAND)	; bepaal volgende maand
	N RETVO
	S $ZT="TRAP^cAN000"
	S RETVO=HMAAND+1
	I $E(RETVO,5,6)>12 S RETVO=RETVO+88
VOZ	Q RETVO
	;
GD(GLOB,IREK,OREK,OMSCH)	; Ophalen rekening nummer en omschrijving van de rekening
	S $ZT="TRAP^cAN000"
	S OREK=$$SIG^cAFA1(GLOB,IREK,101)
	S OMSCH=$P(^(0),D,2)
GDZ	Q
	;
R0	S $P(R,D,12)=$T(+0) D ^cAN1000 Q  ; v12 23.01.95
	;
ZZ	; 01.07.05 - 13 u 55 * V8.04