e(zn,fl) ;Routine editor - logging jobs [ 08/04/94  8:39 AM ]
 ;
 If '$D(^[UCI,VOL]LOGJOB(0,"DEV",$I)) Quit
 If '+^[UCI,VOL]LOGJOB(0,"DEV",$I) Quit
 If "versie : ["_$P($P($T(+1),"[",2),"]")_"]"'=$P(^[UCI,VOL]e,";",2) Do  Quit
 .Write *27,"[22;1f",*7,"No log !!!",!,"Wrong version of ""e"""
DEV Set dev=$P(^[UCI,VOL]LOGJOB(0,"DEV",$i),"\",2)
 If $L(dev),'$D(^[UCI,VOL]LOGJOB(0,"INI",dev)) Set dev=$I
 If dev="" Set dev=$I
 Write *27,"[22;1f","Initials ? ",*27,7,*27,"[0J"
 Write !,"[] = ",dev,"   .[] = no log",*27,8
 Read k If k="-" Xecute "zl @zn x ^[UCI,VOL]e(2)" Goto DEV:$L(zn) Quit
 If k="." Write *27,"[0J" Quit
 If $L(k),$D(^[UCI,VOL]LOGJOB(0,"INI",k)) s dev=k
 Write *27,8,dev,*27,"[0J"
COM Set (t,com)=""
 For  Set t=$o(^[UCI,VOL]LOGJOB(dev,t),-1) Quit:t=""!($P(t,",")<($h-1))  Do
 .Set r=^[UCI,VOL]LOGJOB(dev,t)
 .If $P(r,"\",2)=zn Set com=$P(r,"\",4),t=0
 Write *27,"[23;1f","Comment ? ",*27,7,*27,"[0J"
 Write !,"[] = ",$E($S($L(com):com,1:"***"_$P($P(fl,";",2),"[")),1,75) w *27,8
 Read k If k="-" Goto DEV
 If $L(k) Set com=k
 Write *27,8,$E($S($L(com):com,1:"***"_$P($P(fl,";",2),"[")),1,70),*27,"[0J"
 Set t=$o(^[UCI,VOL]LOGJOB(dev,""),-1)
 If $P(t,",")=$P(h,",") Do
 .If $P(t,",",3)'>44100,$P(h,",",2)'<45900 Quit
 .Set r=^[UCI,VOL]LOGJOB(dev,t)
 .If $P(r,"\",2)'=zn Quit
 .If $P(r,"\",4)'=com Quit
 .Kill ^[UCI,VOL]LOGJOB(dev,t)
 .Set h=$P(t,",",1,2)
 Set t=$P($P(fl,";",2),"[")
 For  Quit:$E(t)'=" "  s t=$E(t,2,999)
 If $P(t," ")=zn s t=$p(t," ",2,99)
 Set h=h_","_$P($h,",",2),^[UCI,VOL]LOGJOB(dev,h)="x ^cE\"_zn_"\"_t_"\"_com_"\"_$I
 Quit
 ;
GLOBAL 
 Kill ^e
 Set ^e="n  s UCI=""LVH"",VOL=""DEV"" x ^[UCI,VOL]e(1) ;versie : ["_$P($P($T(+1),"[",2),"]")_"]"
 Set ^e(1)="s h=$h x ^[UCI,VOL]e(2) i $L(zn) d ^e(zn,fl) zl @zn"
 Set ^e(2)="x ^[UCI,VOL]e(3) s zn=$zn,fl=$t(+1) s:zn="""" zn=$P($P(fl,"" ""),""("")"
 Set ^e(3)="n  x ^cE"
 Quit