vhVHMCG ;Copieren van MSM naar Cache (Globals) [ 12/29/2003  2:17 PM ]
 ;
 ; CW dead code
 ;
 ; Global save (MSM)
 ; Global = ""       (alle ooit gecopieerde globals copieren)
 ;           Global+ (alle ooit gecopieerde globals vanaf global)
 ;           Global  (Bepaalde global)
 ;           "?"     (Global opvragen via ^%GSEL)
GS(Global,BackGrnd) 
 New (Global,BackGrnd)
 Do:$ZV["MSM"
 .Set BackGrnd=$G(BackGrnd)
 .Do INITPAR
 .If $ZOS(10,Dir_Ready01)=-2 Do  Quit
 ..Write:'BackGrnd !,$P(System,"\",2)," global restore niet gestart!"
 .Set Global=$G(Global)
 .If Global=""!($E(Global,$L(Global))="+") Do  ; Copieren van alle globals (eventueel bepaalde en volgende)
 ..Set Global=$E(Global,1,$L(Global)-1),MTUci=$S($P($ZU(5),",")="MGR":"M",1:"T")
 ..If BackGrnd Set R="J"
 ..Else  Do
 ...Write !!!!!!!!!!!!!!!!!!!!!!!
 ...If $L(Global),'$D(^vhVHMC(MTUci,"CGS","G",Global)) Write "Node ",$ZR," onbekend" Quit
 ...Write "Wenst u alle ooit gecopieerde globals "
 ...Write:$L(Global) "vanaf ",Global," "
 ...Write !,"van "_$ZU(5)_" naar "_$P(System,"\",2)_" te copieren ? <NEEN> "
 ...Read R
 ..Set R=$$UPCASE^vhRtn1(R)
 ..If R'="J" Write !,"Geen globals gecopieerd!" Quit
 ..Set:$L(Global) Global=$O(^vhVHMC(MTUci,"CGS","G",Global),-1)
 ..For  Set Global=$O(^vhVHMC(MTUci,"CGS","G",Global)) Quit:Global=""  Do  Quit:$ZOS(10,Dir_Ready01)=-2
 ...If $ZOS(10,Dir_Ready01)=-2 Write:'BackGrnd !,$P(System,"\",2)," global restore gestopt!" Quit
 ...Do GS(Global,BackGrnd)
 ...If $ZOS(10,Dir_Ready01)=-2 Write:'BackGrnd !,$P(System,"\",2)," global restore gestopt!" Quit
 .Else  If Global="?" Do  ; Copieren van bepaalde geselekteerde globals
 ..Do ^%GSEL
 ..If '$D(^UTILITY($J)) Write !,"Geen globals geselekteerd!" Quit
 ..Merge Utility=^UTILITY($J)
 ..Set Global=""
 ..For  Set Global=$O(Utility(Global)) Quit:Global=""  Do  Quit:$ZOS(10,Dir_Ready01)=-2
 ...If $ZOS(10,Dir_Ready01)=-2 Write:'BackGrnd !,$P(System,"\",2)," global restore gestopt!" Quit
 ...Do GS(Global,BackGrnd)
 ...If $ZOS(10,Dir_Ready01)=-2 Write:'BackGrnd !,$P(System,"\",2)," global restore gestopt!" Quit
 ..Kill ^UTILITY($J)
 .Else  Do  ; Copieren van één global
 ..If '$D(@("^"_Global)) Write:'BackGrnd !,"Global ",Global," onbekend" Quit
 ..Set %P=$V(20,$J,2)
 ..Do
 ...New %P
 ...Do LOW^%HL
 ..Do INITPAR
 ..Set FromUci=$S($P($ZU(5),",")="MGR":"M",1:"L"),ToUci=$S($E(Global)="%":"M",1:"L")
 ..Do:ToUci'=FromUci @(ToUci_"^vhSW")
 ..If $D(@("^"_Global)) Do
 ...If $$GNOCOPY(Global,"GS") Do  Quit
 ....Write:'BackGrnd !,"Global ",Global," mag niet gecopieerd worden!!!"
 ....Kill ^vhVHMC($S($E(Global)="%":"M",1:"T"),"C","G",Global)
 ....Kill ^vhVHMC($S($E(Global)="%":"M",1:"T"),"CGS","G",Global)
 ....Kill ^vhVHMC($S($E(Global)="%":"M",1:"T"),"M2C","G",Global)
 ...Write:'BackGrnd !,"Global: ",Global
 ...Set CFiles=0
 ...For  Do  Quit:CFiles  Hang 1
 ....Set CFiles=$ZOS(10,Dir_File01)=-2
 ....Set:CFiles CFiles=$ZOS(10,Dir_Check01)=-2
 ...Do
 ....Set R=Global
 ....New (R)
 ....Set Global=R
 ....If '$D(^vhVHMC($S($E(Global)="%":"M",1:"T"),"GS",Global)) Do
 .....Do INITPAR
 .....Do BLIND^cABIELVH($S($E(Global)="%":"M",1:"T"),"G",Dir_$P(File01,"."),"^"_Global)
 ....Else  Do
 .....Do INITPAR
 .....Set (Dev,vhDEV)=$$OPEN^vhDEV(Dir,File01,"W","M")
 .....If 'Dev Write:'BackGrnd """",Dir,File01,""" niet beschikbaar!" Quit
 .....Kill ^UTILITY($J)
 .....Set ^UTILITY($J,Global)=""
 .....Set $ZT="ERR^%GS",(%TAP,%TAPV)=0
 .....Xecute "Set %SIZE=1024*1024*#100000"
 .....Set vhDEVTYPE="HFS",%GTEMP="^UTILITY($J)",%QUIT=0
 .....Set %CMT="Blind: ^"_Global_" from "_"???"_" to "_File01
 .....Do START^%GS
 ...Set:Global'="vhVHMCGT" ^vhVHMC($S($E(Global)="%":"M",1:"T"),"CGS","G",Global)=""
 ...For  Set Dev=$$OPEN^vhDEV(Dir,Check01,"W","M") If Dev Use Dev Write Global Close Dev Quit
 ...Do:$ZOS(10,Dir_Ready02)'=-2  ; Indien Cache02 GR opgestart, dan copie naar Cache02
 ....Set CFiles=0
 ....For  Do  Quit:CFiles  Hang 1
 .....Set CFiles=$ZOS(10,Dir_File02)=-2
 .....Set:CFiles CFiles=$ZOS(10,Dir_Check02)=-2
 ....Set R=$ZOS(3,Dir_File01,Dir_File02)
 ....Set R=$ZOS(3,Dir_Check01,Dir_Check02)
 ....Hang 30
 ...Set CFiles=0
 ...For  Do  Quit:CFiles  Hang 1
 ....Set CFiles=$ZOS(10,Dir_File01)=-2
 ....Set:CFiles CFiles=$ZOS(10,Dir_Check01)=-2
 ...Write:'BackGrnd ?18,"--Copied"
 ..Do:FromUci'=ToUci @(FromUci_"^vhSW")
 ..Do SET^%HL
 Quit
 ;
GT 
 Do:$ZV["MSM"
 .Do SELECT^%GSEL("URP1S")
 .Do:$D(@%GTEMP)  
 ..Kill ^vhVHMCGT
 ..Set I1=$O(%UTILITY(""))
 ..Do:$D(%UTILITY(I1,1))
 ...Set Global=I1_"("
 ...For I3=1:1 Quit:'$D(%UTILITY(I1,1,I3))  Set Global=Global_""""_%UTILITY(I1,1,I3,2)_""","
 ...Set Global="^"_$E(Global,1,$L(Global)-1)_")"
 ..Set ^vhVHMCGT=Global,vhVHMCGT=Global,$P(vhVHMCGT,"(")="^vhVHMCGT"
 ..Merge @vhVHMCGT=@Global
 ..Do GS("vhVHMCGT")
 ..Kill ^vhVHMCGT
 Do:$ZV["Cache"
 .New I1,Global
 .Set Global=^vhVHMCGT
 .Kill @Global
 .Set Global=$P(Global,"("),I1=""
 .For  Set I1=$O(^vhVHMCGT(I1)) Quit:I1=""  Merge @(Global_"("""_I1_""")")=^vhVHMCGT(I1)
 .Kill ^vhVHMCGT
 Quit
 ;
 ; Global restore (Cache)
GR(BackGrnd) 
 New (BackGrnd)
 Do:$ZV["Cache"
 .Set $ZT="ERRDEV^%GI",$ZE="" ;no variables escape!
 .Do INITPAR
 .Set TRFIL=Dir_File,ASN="A"
 .Set IO=TRFIL,OIBS="*8",OIF="#",OIM=132,IOPAR="(""R"")",IOSL=66,IOST="RMS",IOT="RMS",MSYS="M/WNT"
 .Open IO:"R":0
 .Set OK=$T
 .If 'OK Write:'BackGrnd !,"Could not open file",! Quit
 .If IO=$I Write:'BackGrnd !,"(cannot load from THIS device)" Quit
 .For  Use TRFIL Read R If $E(R)="^" Set Global=$P(R,"(") Quit
 .Use 0
 .Write:'BackGrnd !,"Restore global ",Global
 .Use TRFIL
 .Set Index=""
 .For  Set Index=$O(@Global@(Index)) Quit:Index=""  Kill @Global@(Index)
 .Do A^%GI
 .Do:Global="^RES" CONVRES
 .Do:Global="^vhVHMCGT" GT
 Quit
 ;
 ; Opstarten global restore (Cache)
CGRSTART(BackGrnd) 
 New (BackGrnd)
 Do:$ZV["Cache"
 .Set BackGrnd=$G(BackGrnd)
 .Do INITPAR
 .Xecute "Set R=$ZUTIL(140,1,Dir_Ready)"
 .If R'=-2 Write:'BackGrnd !,"Global restore is reeds gestart!!!" Quit
 .Xecute "Set R=$ZUTIL(140,5,Dir_File)"
 .Xecute "Set R=$ZUTIL(140,5,Dir_Check)"
 .Xecute "Set R=$ZUTIL(140,5,Dir_Ready)"
 .Open Dir_Ready:"NW":0
 .Quit:'$T
 .Use Dir_Ready
 .Write $P(System,"\")_" GR ready"
 .Close Dir_Ready
 .For  Xecute "Set R=$ZUTIL(140,1,Dir_Ready)" Quit:R=-2  Do
 ..For  Xecute "Set R=$ZUTIL(140,1,Dir_Ready)" Quit:R=-2  Xecute "Set R=$ZUTIL(140,1,Dir_File)" Quit:R>51  Hang 1
 ..Xecute "Set R=$ZUTIL(140,1,Dir_Ready)"
 ..Quit:R=-2
 ..Open Dir_File
 ..Use Dir_File
 ..For  Read R If $E(R,1,6)="Blind:" Set Global=$P(R," ",2) Quit  ; ontvangen van de global
 ..For  Xecute "Set R=$ZUTIL(140,1,Dir_Check)" Quit:R'<$L($E(Global,2,99))  Hang 1 ; wachten op bevestiging GS complete
 ..Open Dir_Check
 ..Use Dir_Check
 ..Read R
 ..Close Dir_File,Dir_Check
 ..If R='$E(Global,2,99),BackGrnd Do  Quit  ; Foutieve data
 ...Write !,"Global ",Global," foutief!!!"
 ...Read R
 ..Do GR(BackGrnd) ; Wegschrijven van de global
 ..Xecute "Set R=$ZUTIL(140,5,Dir_File)"
 ..Xecute "Set R=$ZUTIL(140,5,Dir_Check)"
 .Xecute "Set R=$ZUTIL(140,5,Dir_File)"
 .Xecute "Set R=$ZUTIL(140,5,Dir_Check)"
 .Xecute "Set R=$ZUTIL(140,5,Dir_Ready)"
 Quit
 ;
 ; Stoppen global restore (Cache)
CGRSTOP 
 Do INITPAR
 Xecute "Set R=$ZUTIL(140,5,Dir_Ready)"
 Quit
 ;
 ; Routine directory op printer (MSM)
 ; Copie = ""  (alle routines)
 ;         "C" (alle gecopieerde routines)
 ;         "N" (alle niet gecopieerde routines)
 ;         "S" (alle niet te copieeren routines)
 ; Global directory op printer (MSM)
 ; Copie = ""     (alle globals)
 ;         "C"    (alle gecopieerde globals)
 ;         "GS"   (alle gecopieerde globals via ^%GS (geen vertaling nodig, sneller))
 ;         "ABIE" (alle gecopieerde globals via ^cABIE (met vertaling, trager))
 ;         "M"    (alle gecopieerde globals via M2CCOPY)
 ;         "N"    (alle niet gecopieerde globals)
 ;         "S"    (alle niet te copieeren globals)
GD(Copie) 
 Set Copie=$G(Copie)
 Do:$ZV["MSM"
 .If "\\C\N\S\GS\ABIE\M2C\CGS\"'[("\"_Copie_"\") Write "???" Quit
 .Do INIT^vhPRINTER()
 .Do:$D(Print)
 ..Write !!?30,"MSM -> Caché ",$$EXTDATE^vhDTyp(,"DL")
 ..Write !?30
 ..If "\C\GS\ABIE\M2C\"[("\"_Copie_"\") Write "Gekopieërde"
 ..Write:Copie="N" "Niet gekopieërde"
 ..Write:Copie="S" "Niet te kopieëren"
 ..Write:Copie="" "Alle"
 ..Write " globals"
 ..Write:Copie="GS" " (niet vertaald)"
 ..Write:Copie="ABIE" " (vertaald)"
 ..If "\M2C\CGS\"[("\"_Copie_"\") Write " via ",Copie
 ..Write !!
 ..Set (Count,Bold)=0,Print=Copie="",Global="^"
 ..For  Set Global=$O(@Global) Quit:Global=""  Quit:$E(Global)="a"  Do  Set Global="^"_Global
 ...If Copie="S" Do
 ....Set Print=$$GNOCOPY(Global) Set:Print Print=$$GNOCOPY(Global,"GS")
 ...If Copie="C" Do
 ....Set Print=$D(^vhVHMC($S($E($ZU(5),1,3)="MGR":"M",1:"T"),"C","G",Global))
 ....Set:'Print Print=$D(^vhVHMC($S($E($ZU(5),1,3)="MGR":"M",1:"T"),"CGS","G",Global))
 ...If Copie="N" Do
 ....Set Print='$D(^vhVHMC($S($E($ZU(5),1,3)="MGR":"M",1:"T"),"C","G",Global))
 ....Set:Print Print='$D(^vhVHMC($S($E($ZU(5),1,3)="MGR":"M",1:"T"),"CGS","G",Global))
 ...If Copie="GS" Do
 ....Set Print=$D(^vhVHMC($S($E($ZU(5),1,3)="MGR":"M",1:"T"),"GS",Global))
 ...If Copie="ABIE" Do
 ....Set Print='$D(^vhVHMC($S($E($ZU(5),1,3)="MGR":"M",1:"T"),"GS",Global))
 ....Quit:'Print
 ....Set Print=$D(^vhVHMC($S($E($ZU(5),1,3)="MGR":"M",1:"T"),"C","G",Global))
 ....Set:'Print Print=$D(^vhVHMC($S($E($ZU(5),1,3)="MGR":"M",1:"T"),"CGS","G",Global))
 ...If Copie="M2C" Do
 ....Set Print=$D(^vhVHMC($S($E($ZU(5),1,3)="MGR":"M",1:"T"),"M2C","G",Global))
 ...If Copie="CGS" Do
 ....Set Print=$D(^vhVHMC($S($E($ZU(5),1,3)="MGR":"M",1:"T"),"CGS","G",Global))
 ...Quit:'Print
 ...Set Count=Count+1
 ...If Copie="" Do
 ....Set Bold=$D(^vhVHMC($S($E($ZU(5),1,3)="MGR":"M",1:"T"),"C","G",Global))
 ....Set:'Bold Bold=$D(^vhVHMC($S($E($ZU(5),1,3)="MGR":"M",1:"T"),"CGS","G",Global))
 ....Write:Bold @FMTB
 ...Write "^",Global,$J("",9-$L(Global))
 ...Write:Bold @FMTb
 ...Write:'(Count#8) !
 ..Write #
 ..Do CLOSE^vhPRINTER
 Quit
 ;
 ; Conversie van de global ^RES
CONVRES 
 New I,%Nodes,%Node,vhNode
 Do:$ZV["Cache"
 .Set %Nodes="PRINTER\RES\WACHTW"
 .For I=1:1:$L(%Nodes,"\") Do
 ..Set %Node=$P(%Nodes,"\",I)
 ..Quit:%Node=""
 ..Set vhNode="vh"_%Node,%Node="%"_%Node
 ..Quit:$D(^RES(vhNode))  Quit:'$D(^RES(%Node))
 ..Kill ^RES(vhNode)
 ..Merge ^RES(vhNode)=^RES(%Node)
 ..Kill ^RES(%Node)
 Quit
 ;
 ; Conversie van de global ^vhMAIL
CONVMAIL 
 Do:$ZV["Cache"
 .Set %Node="LVH"_","_"ADM",vhNode="ADMIN1"
 .Merge ^vhMAIL("IK",vhNode)=^vhMAIL("IK",%Node)
 .Merge ^vhMAIL("IL",vhNode)=^vhMAIL("IL",%Node)
 .For %Node="LVH"_","_"ADM","LVH"_","_"BAD","MGR"_","_"ADM" Kill ^vhMAIL("IK",%Node),^vhMAIL("IL",%Node)
 Quit
 ;
INITPAR 
 Do:$ZV["MSM"
 .Set Dir=^vhVHMC("P","DIR")
 .Set File01=^vhVHMC("P","DIR","GLOB","CACHE01","FILE")
 .Set File02=^vhVHMC("P","DIR","GLOB","CACHE02","FILE")
 .Set Check01=^vhVHMC("P","DIR","GLOB","CACHE01","CHECK")
 .Set Check02=^vhVHMC("P","DIR","GLOB","CACHE02","CHECK")
 .Set Ready01=^vhVHMC("P","DIR","GLOB","CACHE01","READY")
 .Set Ready02=^vhVHMC("P","DIR","GLOB","CACHE02","READY")
 .Set System=^vhVHMC("P","SYSTEM")
 Do:$ZV["Cache"
 .Set Dir=^vhVHMC("P","DIR")
 .Set File=^vhVHMC("P","DIR","GLOB","FILE")
 .Set Check=^vhVHMC("P","DIR","GLOB","CHECK")
 .Set Ready=^vhVHMC("P","DIR","GLOB","READY")
 .Set System=^vhVHMC("P","SYSTEM")
 Quit
 ;
 ; Nakijken of een global mag gecopieerd worden
 ; Node = GS is alles overkoepelend,
 ;        indien deze opstaat dan geen copy onder geen enkel beding
 ;        Indien enkel beperking op M2CCOPY, dan kan men wel nog copieren via GS
GNOCOPY(Global,Node) 
 New %P,%gs,X,FIRST,LAST,NoCopy
 Set Node=$G(Node),NoCopy=0,%gs=""
 For  Set %gs=$O(^vhVHMC($S($E(Global)="%":"M",1:"T"),"S"_Node,"G",%gs)) Quit:%gs=""  Do  Quit:NoCopy
 .Set %P=$$%SRCHPAT^cSRCHPAT(%gs)
 .Quit:'$D(FIRST)
 .Set X=Global
 .If $L(FIRST),X'=FIRST,FIRST]X Quit
 .If $L(LAST),X]LAST Quit
 .Xecute %P
 .Set NoCopy=$T
 If 'NoCopy,Node="" Set NoCopy=$$GNOCOPY(Global,"GS")
 Quit NoCopy
 ;
 ; Global copy (MSM)
 ; Global = ""       (alle ooit gecopieerde globals copieren)
 ;           Global+ (alle ooit gecopieerde globals vanaf global)
 ;           Global  (Bepaalde global)
 ;           "?"     (Global opvragen via ^%GSEL)
M2CCOPY(Global,BackGrnd) 
 New (Global,BackGrnd)
 If $ZV["MSM" Do
 .Set BackGrnd=$G(BackGrnd)
 .Do INITPAR
 .Set Global=$G(Global)
 .If Global=""!($E(Global,$L(Global))="+") Do  ; Copieren van alle globals (eventueel bepaalde en volgende)
 ..Set Global=$E(Global,1,$L(Global)-1),MTUci=$S($P($ZU(5),",")="MGR":"M",1:"T")
 ..If BackGrnd Set R="J"
 ..Else  Do
 ...Write !!!!!!!!!!!!!!!!!!!!!!!
 ...If $L(Global),'$D(^vhVHMC(MTUci,"C","G",Global)) Write "Node ",$ZR," onbekend" Quit
 ...Write "Wenst u alle ooit gecopieerde globals "
 ...Write:$L(Global) "vanaf ",Global," "
 ...Write !,"van "_$ZU(5)_" naar "_$P(System,"\",2)_" te copieren ? <NEEN> "
 ...Read R
 ..Set R=$$UPCASE^vhRtn1(R)
 ..If R'="J" Write !,"Geen globals gecopieerd!" Quit
 ..If $L(Global) Set Global=$O(^vhVHMC(MTUci,"C","G",Global),-1)
 ..Else  Kill ^vhVHMC(MTUci,"M2C","G")
 ..For  Set Global=$O(^vhVHMC(MTUci,"C","G",Global)) Quit:Global=""  Do M2CCOPY(Global,BackGrnd)
 .Else  If Global="?" Do  ; Copieren van bepaalde geselekteerde globals
 ..Do ^%GSEL
 ..If '$D(^UTILITY($J)) Write !,"Geen globals geselekteerd!" Quit
 ..Merge Utility=^UTILITY($J)
 ..Set Global=""
 ..For  Set Global=$O(Utility(Global)) Quit:Global=""  Do M2CCOPY(Global,BackGrnd)
 ..Kill ^UTILITY($J)
 .Else  Do  ; Copieren van één global
 ..If '$D(@("^"_Global)) Write:'BackGrnd !,"Global ",Global," onbekend" Quit
 ..Set %P=$V(20,$J,2)
 ..Do
 ...New %P
 ...Do LOW^%HL
 ..If $$GNOCOPY(Global) Do  Quit
 ...Write:'BackGrnd !,"Global ",Global," mag niet gecopieerd worden!!!"
 ...Kill ^vhVHMC($S($E(Global)="%":"M",1:"T"),"C","G",Global)
 ..Set FromUci=$P($ZU(5),","),FromVol=$P($ZU(5),",",2)
 ..Quit:FromUci'="LVH"  Quit:FromVol'="ADM"
 ..Write:'BackGrnd !,"Global: ",Global
 ..Set StartTime=$H,CacheUci=$G(^vhVHMC($S($E(Global)="%":"M",1:"T"),"UCI",Global),"LVH")
 ..Set ToCache="CAD" ; Kan meerdere referenties bevatten ";" gescheiden
 ..For I=1:1:$L(ToCache,";") Set $P(ToCache,";",I)=CacheUci_","_$P(ToCache,";",I)
 ..Set Convert='$D(^vhVHMC($S($E(Global)="%":"M",1:"T"),"GS",Global))
 ..Do:Convert  ; Ophalen van de convert parameters
 ...Set TRF="M",TRT="C",TRW="G"
 ...Do RULES^cABIE
 ..; Kill van het oude Caché bestand
 ..For I=1:1:$L(ToCache,";") Do
 ...Set CacheUci=$P($P(ToCache,";",I),","),CacheVol=$P($P(ToCache,";",I),",",2)
 ...Quit:CacheUci=""  Quit:CacheVol=""
 ...Set CacheGlob="^|"""_CacheUci_","_CacheVol_"""|"_Global
 ...Kill @CacheGlob
 ..Set FromGlob="^|"""_FromUci_","_FromVol_"""|"_Global
 ..Do:"\1\11\"[("\"_$D(@FromGlob)_"\") TOCACHE(FromGlob,ToCache,Convert,.GLOTR)
 ..For  Set FromGlob=$Q(@FromGlob) Quit:FromGlob=""  Do TOCACHE(FromGlob,ToCache,Convert,.GLOTR)
 ..Set:Global'="vhVHMCGT" ^vhVHMC($S($E(Global)="%":"M",1:"T"),"C","G",Global)=""
 ..Set ^vhVHMC($S($E(Global)="%":"M",1:"T"),"M2C","G",Global)=StartTime_"\"_$H
 Quit
 ;
 ; Indien MSM,'Recalc -> geen CRC^MSMCOMP, enkel lijst
MSMCOMP(Recalc,BackGrnd) 
 New R,Global,MSMComp
 Set Recalc=$G(Recalc),BackGrnd=$G(BackGrnd)
 Do:$ZV["MSM"
 .Do:Recalc
 ..Kill ^MSMCOMP
 ..Set Global=""
 ..For  Set Global=$O(^vhVHMC("T","M2C","G",Global)) Quit:Global=""  Set ^MSMCOMP("T",Global)=""
 ..Set Global=""
 ..For  Set Global=$O(^vhVHMC("T","CGS","G",Global)) Quit:Global=""  Set ^MSMCOMP("T",Global)=""
 ..Merge ^MSMCOMP("GS")=^vhVHMC("T","GS")
 .Write:'BackGrnd !,?12,"MSM",?41,"Cache"
 .Set Global=""
 .For  Set Global=$O(^MSMCOMP("T",Global)) Quit:Global=""  Do
 ..Set MSMComp=$G(^MSMCOMP("T",Global)),MSM=$P(MSMComp,"#"),Cache=$P(MSMComp,"#",2)
 ..Set:Recalc MSM=$$CRC^MSMCOMP("^"_Global),$P(MSMComp,"#")=MSM,^MSMCOMP("T",Global)=MSMComp
 ..Do:'BackGrnd
 ...Write !,Global,?11,MSM,?38,Cache
 ...Quit:Cache=""
 ...Write ?65
 ...If MSM=Cache Write "Ok"
 ...Else  If '$D(^MSMCOMP("GS",Global)) Do
 ....Write "Vertaald ("
 ....Write $S($P(MSM,D)=$P(Cache,D):" ",1:"n")
 ....Write $S($P(MSM,D,2)=$P(Cache,D,2):" ",1:"d")
 ....Write $S($P(MSM,D,3)=$P(Cache,D,3):" ",1:"i")
 ....Write ")"
 ...Else  Write "Niet Ok"
 Do:$ZV["Cache"
 .Write:'BackGrnd !,?12,"MSM",?41,"Cache"
 .Set Global=""
 .For  Set Global=$O(^|"MSMADM"|MSMCOMP("T",Global)) Quit:Global=""  Do
 ..Set MSMComp=$G(^|"MSMADM"|MSMCOMP("T",Global)),MSM=$P(MSMComp,"#"),Cache=$P(MSMComp,"#",2)
 ..Set Cache=$$CRC^MSMCOMP("^"_Global),$P(MSMComp,"#",2)=Cache,^|"MSMADM"|MSMCOMP("T",Global)=MSMComp
 ..Do:'BackGrnd
 ...Write !,Global,?12,MSM,?41,Cache
 ...Write:$L(MSM) ?70,$S(MSM=Cache:"Ok",'$D(^|"MSMADM"|MSMCOMP("GS",Global)):"Vertaald",1:"Niet Ok")
 Quit
 ;
 ; Copieren naar Caché
TOCACHE(FromGlob,ToCache,Convert,GLOTR) 
 New I,%DATA,CacheUci,CacheVol,CacheGlob
 Set Convert=$G(Convert)
 If Convert,'$D(GLOTR) Do  ; Ophalen van de convert parameters
 .Set TRF="M",TRT="C",TRW="G"
 .Do RULES^cABIE
 Set %DATA=@FromGlob
 Xecute:Convert GLOTR
 For I=1:1:$L(ToCache,";") Do
 .Set CacheUci=$P($P(ToCache,";",I),","),CacheVol=$P($P(ToCache,";",I),",",2)
 .Quit:CacheUci=""  Quit:CacheVol=""
 .Set CacheGlob="^|"""_CacheUci_","_CacheVol_"""|"_$P(FromGlob,"|",3,99)
 .Set @CacheGlob=%DATA
 Quit
 ;
 ; Aanpassen van bepaalde globals na de dataoverdracht
UPDATE 
 Do:$ZV["Cache"
 .Write !,"Bent u zeker dat de dataoverdracht afgewerkt is?"
 .Read !,"Bent u zeker dat de UPDATE nog niet gadaan is? <Neen>? ",Update
 .Quit:Update'="Ja"
 .; Conversie van de "RES" global "%" indexen
 .Write !!,"Update ^RES (""%""-indexen)"
 .Do CONVRES
 .; Conversie van de "vhMAIL" global "ADMIN1" indexen
 .Write !!,"Update ^vhMAIL (""ADMIN1""-indexen)"
 .Do CONVMAIL
 .; Copieren van de opzoekindexen voor klanten, leveranciers, ...
 .Write !,"Update ^INDEX(""K"") (opzoekindexen voor klanten, leveranciers, ...)"
 .Kill ^INDEX("K")
 .Merge ^INDEX("K")=^|"MSMADM"|INDEX("K")
 .Write !,"Update ^INDEX(0,""PN"") (indexen op postcode)"
 .Kill ^INDEX(0,"PN")
 .Merge ^INDEX(0,"PN")=^|"MSMADM"|INDEX(0,"PN")
 .Write !,"Update ^DATA(0,""PN"") (de postcodes)"
 .Kill ^DATA(0,"PN")
 .Merge ^DATA(0,"PN")=^|"MSMADM"|DATA(0,"PN")
 .; Copieren van de nodige nodes van ^HULP
 .Write !,"Update ^HULP(X) (X = ""EURO"", ""LVHI39M"", ""LVHI39M2"", ""RC"", ""TR"" en ""ZKB"")"
 .For Node="EURO","LVHI39M","LVHI39M2","RC","TR","ZKB" Do
 ..Kill ^HULP(Node)
 ..Merge ^HULP(Node)=^|"MSMADM"|HULP(Node)
 .Set Node="LVH"_","_"ADM"
 .Write !,"Kill ^DIN(""",Node,""")"
 .Kill ^DIN(Node,"LOGIN")
 .Write !,"Kill ^INDEX(""ADMIN1"",""LOGIN"")"
 .Kill ^INDEX("ADMIN1","LOGIN")
 Quit
 ;