; Programmaboek Van Hoecke
 Quit
 
AllCust
 New %J,R,Dev,Rec,KLNr,Next,Aantal,Count
 ;Quit
 Set %J=$$%J^vhRtn1()
 Kill ^HULP(%J),^CVHPB
 Set Dev=$$OPEN^vhDEV(,"cwCVHPB.txt","R","M")
 Do:0'[Dev
 . Set Next=0
 . For  Use Dev Read Rec Quit:Rec=""  Do
 . . Set KLNr=$$TRIMN^vhRtn1($P(Rec,$C(9)))
 . . Quit:'KLNr
 . . Set Next=Next+1
 . . Set Aantal=$P(Rec,$C(9),3),^HULP(%J,Next)=KLNr_D_Aantal
 . Close Dev
 . Set Next="",Count=0
 . For  Set Next=$O(^HULP(%J,Next)) Quit:Next=""  Do
 . . Set R=^HULP(%J,Next),KLNr=$P(R,D),Aantal=$P(R,D,2)
 . . Do OneCust(KLNr,Aantal)
 . . Set Count=Count+1
 . Kill ^HULP(%J)
 . Write !!,Count," orders aangemaakt.",!
 Quit
 
OneCust(KLNr,Aantal)
 New L,R,Rec,PRNr,KlKey,OrdRef,FBProd,Taal
 Set KlKey=^KK1(KLNr),Rec=^KKL(KlKey,0),Taal=$$Taal(KLNr)
 Write !,$J(KLNr,5),?10,$P(Rec,D,2),?40,Aantal,?50,Taal
 Set PRNr(1)=$$PRNr(KLNr)_D_Aantal_"\"_$$EXTDATE^vhDTyp(,"DW")_"\\Z"
 Set OrdRef=$$OrdRef(KLNr)
 Do BUILDOBJ^FLOWORD(KLNr,,OrdRef,.PRNr,,1,"PF","FBProd")
 Set ORDNr=$P(FBProd($$PRNr(KLNr)),D,2),Rec=^KOD(KLNr,"F",ORDNr,1)
 Set $P(Rec,D,7)="INT",$P(Rec,D,8)="1043#1107#"_$H,$P(Rec,D,24)="1043#"_$H_"#"_ORDNr
 Set ^KOD(KLNr,"F",ORDNr,1)=Rec
 Set R=^KKL(KlKey,0)
 If $P(R,D,5)["POSTBUS" Set L=$O(^KKL(KlKey,"L")) If $E(L)="L" Set R=^KKL(KlKey,L),$P(R,D)=1,^KOD(KLNr,"F",ORDNr,3)=R
 Set ^CVHPB(KLNr,ORDNr)=""
 Quit
 
DelAll
 New Rec,KLNr,ORDNr,Count
 Set (KLNr,Count)=0
 For  Set KLNr=$O(^KOD(KLNr)) Quit:KLNr=""  Do
 . Set ORDNr=""
 . For  Set ORDNr=$O(^KOD(KLNr,"F",ORDNr)) Quit:ORDNr=""  Do
 . . Set Rec=^KOD(KLNr,"F",ORDNr,1)
 . . Quit:$P(Rec,D,3)'=$$OrdRef(KLNr)
 . . Write !,$ZR,?40,"--> verwijderd"
 . . Do DELOBJ^FLOWORD(ORDNr)
 . . Set Count=Count+1
 Write !!,Count," orders verwijderd.",!
 Quit
 
OrdRef(KLNr)
 New OrdRef
 Set OrdRef="Programmaboek 2010"
 Quit OrdRef
 
PRNr(KLNr)
 New Taal,PRNr
 Set Taal=$$Taal(KLNr)
 Set PRNr=$S(Taal="F":507419,Taal="D":507415,1:507415)
 Quit PRNr
 
SendAllWMS
 New Dev,Rec,KLNr,Next,Count,HULP
 Set Dev=$$OPEN^vhDEV(,"cwCVHPB.txt","R","M")
 Do:0'[Dev
 . Set Next=0
 . For  Use Dev Read Rec Quit:Rec=""  Do
 . . Set KLNr=$$TRIMN^vhRtn1($P(Rec,$C(9)))
 . . Quit:'KLNr
 . . Set Next=Next+1
 . . Set HULP(Next)=KLNr
 . Close Dev
 . Set Count=0,Next=""
 . For  Set Next=$O(HULP(Next)) Quit:Next=""  Do
 . . Set KLNr=HULP(Next)
 . . Do SendOneWMS(KLNr)
 . . Set Count=Count+1
 . Write !!,Count," orders verzonden.",!
 Quit
 
SendOneWMS(KLNr)
 New R,Rec,ORDNr,OLNr,PRNr,Aantal,OLUNr,LevWk,VerzW,DOutTime,VerzZ,LevAdr,CBLORDNr
 Write !,$J(KLNr,5),?10,$P(^KKL(^KK1(KLNr),0),D,2)
 Kill ^HULP($J)
 Set (ORDNr,LevAdr)=""
 For  Set ORDNr=$O(^KOD(KLNr,"F",ORDNr)) Quit:ORDNr=""  Do
 . Set Rec=^KOD(KLNr,"F",ORDNr,1),CVHPBORDNr=ORDNr
 . Quit:$P(Rec,D,3)'=$$OrdRef(KLNr)
 . Set OLNr=100
 . For  Set OLNr=$O(^KOD(KLNr,"F",ORDNr,OLNr)) Quit:OLNr=""  Do
 . . Set Rec=^KOD(KLNr,"F",ORDNr,OLNr),PRNr=$P(Rec,D,2)
 . . Quit:'PRNr
 . . Set Aantal=$P(Rec,D,3),OLUNr=$P(Rec,D,15),LevWk=$P(Rec,D,25)
 . . Set ^HULP($J,KLNr,"M","A",ORDNr,OLUNr)=Aantal_D_D_LevWk
 . If LevAdr="",$P(^KOD(KLNr,"F",ORDNr,3),D) Set LevAdr=^KOD(KLNr,"F",ORDNr,3)
 Do:$D(^HULP($J))
 . Set VerzW="INT",R=^RES("KLANT","PI","VERZENDWIJZE","D",VerzW),DOutTime=$P(R,"`",4),VerzZ=$P(R,"`",6)
 . Set CONSNr=$$GETNUM^FLOW("KUL","KU1") ; Tijdelijk
 . Do BLDCONS^EWORDS2(KLNr,$NA(^HULP($J,KLNr,"M")),CONSNr,"INT",$H+1,+$H_","_DOutTime,VerzZ,LevAdr)
 . Kill ^HULP($J)
 . Kill ^CVHPB(KLNr,CVHPBORDNr)
 Quit
 
FactBulkGroep
 New R,KLNr,BONNr,CONSNr,ORDNr,PRNr,Count
 Kill ^CVHPB
 Set (KLNr,Count)=0
 For  Set KLNr=$O(^KUL(KLNr)) Quit:KLNr=""  Do
 . Set BONNr=""
 . For  Set BONNr=$O(^KUL(KLNr,"F",BONNr)) Quit:BONNr=""  Do
 . . Set R=$G(^KUL(KLNr,"F",BONNr,101))
 . . Set:R[$$OrdRef(KLNr) $P(^KUL(KLNr,"F",BONNr,1),D,38)="PROGRAMMABK",Count=Count+1
 Write !,Count
 Quit 
 
ClearTest
 New R,KLNr,BONNr,CONSNr,ORDNr,PRNr
 Do:$ZU(5)="DEV-ADMIN1"
 . Kill ^CVHPB
 . Set KLNr=0
 . For  Set KLNr=$O(^KUL(KLNr)) Quit:KLNr=""  Do
 . . Set BONNr=""
 . . For  Set BONNr=$O(^KUL(KLNr,"F",BONNr)) Quit:BONNr=""  Do
 . . . Set R=$G(^KUL(KLNr,"F",BONNr,101))
 . . . Do:R[$$OrdRef(KLNr) DELOBJ^FLOWBON(BONNr)
 . Set CONSNr=""
 . For  Set CONSNr=$O(^ORDW("D",CONSNr)) Quit:CONSNr=""  Do
 . . Set ORDNr=$O(^ORDW("D",CONSNr,"D","")),PRNr=$P($G(^ORDW("D",CONSNr,"D",ORDNr,100)),D)
 . . Set KLNr=$P(^ORDW("D",CONSNr),D)
 . . If PRNr=$$PRNr(KLNr) Kill ^ORDW("D",CONSNr),^ORDW("IK",KLNr,CONSNr)
 Quit
 
ClearHULP(J)
 New I
 Set J=$G(J,$J)
 For I=1:1:999 Kill ^HULP(J*100000+I)
 Quit
 
Taal(KLNr)
 New KlKey,Rec,Taal
 Set KlKey=^KK1(KLNr),Rec=^KKL(KlKey,0),Taal=$P(Rec,D,9) Set:Taal="" Taal="N"
 ;Set Taal="N"
 Quit Taal