ATKINUSE ; Afstand-toegang voor klanten [ 05/26/98  9:08 AM ]
 ;
 New
 Do INIT,CHECK
 Quit
 ;
INUSE() 
 New
 Do INIT
 Set Function=1
 Do CHECK
 Quit $G(Enter)
 ;
CHECK 
 Set Function=$G(Function),Devices=$TR($G(^ATK("INUSE")),"\",",")
 If $L(Devices) For  Do  Quit:Quit
 .Xecute "For Device="_Devices_" Set Quit=$$INUSE^cS(,Device) Quit:Quit"
 .Set Quit='Quit
 .Quit:Quit
 .Do TITEL
 .Xecute "For Device="_Devices_" Do DISPLAY(Device)"
 .If 'Function Do
 ..Read *R:5 Set Quit=$T
 .If Function Hang 5 Set Quit=$$INUSE^cS(,1) Set:'Quit Quit=$$INUSE^cS(,5) Set:'Quit Quit=$$INUSE^cS(,6)
 .Set:Function Enter=Quit
 .If Function,Enter
 .Else  Do CLEAR
 Quit
 ;
DISPLAY(Device) 
 New (Device)
 Quit:'$$INUSE^cS(,Device)
 Do VAR^cS(,Device)
 Quit:'$G(%J)  Quit:'$D(^HULP(%J,"KLINIT"))
 Set R=$G(^HULP(%J,"KLINIT",0))
 Quit:R=""
 Set KLNr=$P(R,"\"),Naam=$P(R,"\",2),Woonpl=$P(R,"\",7),LcUser=$G(^HULP(%J,"KLINIT","LcUser"))
 Write !!," Device ",Device
 Write !?1,KLNr," ",Naam Write:$L(LcUser) " (",LcUser,")"
 Write !?1,Woonpl
 Write:$L($G(Screens)) !?1,"Schermen : ",Screens
 Quit
 ;
INIT 
 Set D="\",U=";",(Q,QN)=""
 Do INIT^vhTERMINA
 Set (I,DevTyp)="ATK"
 For  Set I=$O(^vhDEV(I)) Quit:$E(I,1,$L(DevTyp))'=DevTyp  Set @($E(I,$L(DevTyp)+1,9))=^(I)
 Quit
 ;
CLEAR 
 Write @F11,@F1
 Quit
 ;
TITEL 
 Do CLEAR
 Write @FMTI," ",$$GETTXT^ATK("ATK","LVHNV",$S($G(Taal)="":"N",1:Taal))," - Logon ",@FMTCL
 Quit
 ;