SynchroniseerOpenstaandeFacturen() ; AX synchronisatie van de openstaande verkoopfacturen
	// Do ##class(APPS.common.RuntimeInitialiser).Initialise("AX.Caretaker"_$job)
	// Do Execute("AX.Uitgaand.BKH.OpenstaandeVerkoopFactuur.impl.Synchroniser","Synchroniseer")
	Quit

CollectResponses() ; AX verwerken van de responses
	Do ##class(APPS.common.RuntimeInitialiser).Initialise("AX.Caretaker"_$job)
	
	Lock +^AX.Caretaker("CollectResponse"):0 
	Else  Quit
	
	While $get(^AX.Caretaker("CollectResponse")) {
		Do Execute("AXimpl.ResponseCollector","Process")
		Hang 1
	}
	
	Lock -^AX.Caretaker("CollectResponse")
	
	Quit	

CollectRequests() ; AX verwerken van de requests
	Do ##class(APPS.common.RuntimeInitialiser).Initialise("AX.Caretaker"_$job)
	
	Lock +^AX.Caretaker("CollectRequests"):0 
	Else  Quit
	
	While $get(^AX.Caretaker("CollectRequests")) {
		Do Execute("AXimpl.MessageInCollector","Process")
		Hang 1
	}
	Lock -^AX.Caretaker("CollectRequests")	
	
	Quit	

Execute(Classname,Method) 
	try {
		#dim ObjectApi As TECH.Object.ObjectAPI = ##class(TECH.Context).Instance().GeefObjectAPI()
		#dim Instance As %Base = ObjectApi.New(Classname)
		do $method(Instance,Method)
	} catch {
		#dim Exception As TECH.Exceptions.Exception = ##class(TECH.ExceptionHandler).Catch()
		Do ##class(vhLib.Logger).%New("AX.CARETAKER").Error("Caretaker",Exception.ToString())
	}
	quit