DCOFFD ;AFDRUKKEN OFFERTES (Detailoffertes) [ 01/17/2002   4:06 PM ]
 ;
 Do TOTALS,FTITEL,FHEADER,BODY,VOORW,LFOOTER,PPRINT
 Quit
 ;
FN(Number,Fraction,Format) 
 Quit $$FN^DCALG(Number,Fraction,$G(Format))
 ;
PASTEB(R,AddBlank) 
 New NewPage
 Set NewPage="Do FOOTER^"_$ZN_",TITEL^"_$ZN_",HEADER^"_$ZN
 Do PASTEB^DCALG(R,NewPage,$G(AddBlank))
 Quit
 ;
BLOCK(R) 
 Do BLOCK^DCALG(R)
 Quit
 ;
CACHE(R) 
 Do CACHE^DCALG(R)
 Quit
 ;
PASTE(Page,Line,Text,BPos,EPos,Attr) 
 Do PASTE^DCALG(Page,Line,Text,BPos,EPos,Attr) 
 Quit
 ;
 ; Afdruk body
BODY 
 New B,R,BCount,OLNr,HoofdGr,Groep,SubGroep,SelTyp,SelLnr,Paste,OffRef
 Set R=^KOFKL(KLNr,"F",OFFNr,1),OffRef=$P(R,D,3),MaxWeek=0
 If $L(OffRef) Do
 .Do CACHE(L("B","B"))
 .Set T=$$TXT("Ref")_": "_OffRef
 .Do PASTE(PCount,LCount,T,3,"","U")
 .Do CACHE(L("B","B"))
 Set BCount=0
 Set OLNr=100
 For  Set OLNr=$O(^KOFKL(KLNr,"F",OFFNr,OLNr)) Quit:OLNr=""!(OLNr'?.N)  Do
 .Set Paste=$$OFFERTE^DCDETAIL(OFFNr,OLNr) ; 0=neen, 1=ja, 2=ja en bladsprong
 .If Paste Do PASTEB(L("B","B"),Paste=1) If Paste=2 Do FOOTER,TITEL,HEADER
 If $D(B) Do PASTEB(L("B","B"),1)
 Set HoofdGr=10000
 For  Set HoofdGr=$O(^KOFKL(KLNr,"F",OFFNr,HoofdGr)) Quit:"ZZZZ"[$E(HoofdGr,1,4)  Do
 .Set Groep=""
 .For  Set Groep=$O(^KOFKL(KLNr,"F",OFFNr,HoofdGr,Groep)) Quit:Groep=""  Do
 ..If Groep=0 Do OFFERTE^DCDETAIL(OFFNr,OLNr,HoofdGr) Quit
 ..Set SubGroep=""
 ..For  Set SubGroep=$O(^KOFKL(KLNr,"F",OFFNr,HoofdGr,Groep,SubGroep)) Quit:SubGroep=""  Do
 ...If SubGroep=0 Do OFFERTE^DCDETAIL(OFFNr,OLNr,HoofdGr,Groep) Quit
 ...Set PRNr=""
 ...For  Set PRNr=$O(^KOFKL(KLNr,"F",OFFNr,HoofdGr,Groep,SubGroep,PRNr)) Quit:PRNr=""  Do
 Set SelTyp="ZZZZ"
 For  Set SelTyp=$O(^KOFKL(KLNr,"F",OFFNr,SelTyp)) Quit:SelTyp=""  Do
 .Set SelLnr=0
 .For  Set SelLnr=$O(^KOFKL(KLNr,"F",OFFNr,SelTyp,SelLnr)) Quit:SelLnr=""  Do
 ..Set Paste=$$OFFERTE^DCDETAIL(OFFNr,SelTyp,SelLnr)
 ..If Paste Do PASTEB(L("B","B"),1)
 If $D(B) Do PASTEB(L("B","B"),1)
 Quit
 ;
 ; Verwerking groeperingslijn
GROEPOFF(R,I4,Paste) 
 If '$D(Totals(I4)) Quit
 Set Omschr=$P(R,D,5),Bedrag=$P(Totals(I4),D)
 Set R=Omschr_"`3``TB"
 Set R=R_D_$$FN(Bedrag,2)_"``78`B"
 Do BLOCK(R)
 If OffMunt="MTL" Do
 .Set R=$P(Totals(I4),D,2)_"``"_$S(OffTyp="C":62,1:77)_"`B"
 .Do BLOCK(R)
 Set R=$O(^KOFKL(KLNr,"F",OFFNr,I4)) If R?.N,R Do
 .If Paste=2 Do BLOCK($E(L("B","B"),2-VPerfo+1,99)_"`1``N") Quit
 .Do BLOCK($E(L("B",$P("B\S",D,Prefs("Totals"))),2-VPerfo+1,99)_"`1``N")
 Quit
 ;
 ; Afdruk hoofding (volgende bladzijden)
HEADER 
 New T
 If $D(VPerfoT) New VPerfo Set VPerfo=VPerfoT
 Do CACHE(L("B","F"))
 Do CACHE(L("B","B"))
 Set T=$$TXT("Art")
 Do PASTE(PCount,LCount,T,3,"","")
 Set T=$$TXT("Aant")
 Do PASTE(PCount,LCount,T,"",50,"")
 Set T=$$TXT("Prijs") If OffMunt'="MTL" Set T=T_" "_OffMunt
 Do PASTE(PCount,LCount,T,"",63,"")
 If OffTyp'="C" Do
 .Set T=$$TXT("Bedr") If OffMunt'="MTL" Set T=T_" "_OffMunt
 .Do PASTE(PCount,LCount,T,"",77,"")
 If OffTyp="C" Do
 .Set T=$$TXT("BestIp")
 .Do PASTE(PCount,LCount,T,"",71,"")
 .Set T=$$TXT("AfnPer")
 .Do PASTE(PCount,LCount,T,"",78,"")
 Do CACHE(L("B","B"))
 If OffTyp'="C" Do
 .Set T=$$TXT("LevTrm")
 .Do PASTE(PCount,LCount,T,"",50,"")
 If OffTyp="C" Do
 .Set T=$$TXT("BestIp",3)
 .Do PASTE(PCount,LCount,T,"",71,"")
 .Set T=$$TXT("AfnPer",3)
 .Do PASTE(PCount,LCount,T,"",78,"")
 If NetBrutP Do
 .Set T=$$TXT("Kort")
 .Do PASTE(PCount,LCount,T,"",63,"")
 If $D(L("B","S")) Do CACHE(L("B","S"))
 Quit
 ;
 ; Afdruk hoofding (eerste blad)
FHEADER 
 New T
 Do HEADER
 Set BCount=0
 Set T="" For I=1:1:5 Do  ; Openingstekst op offerte
 .If $G(^KBA(22,"O",Taal,I))="" Quit
 .Set T=^KBA(22,"O",Taal,I)
 .Set T=T_$J("",48-$L(T))_"`3`42`CT"
 .Do BLOCK(T)
 If $L(T) Do PASTEB(L("B","B"),1)
 Quit
 ;
 ; Afdruk titel (volgende blazijden)
TITEL 
 New OffDat,KlantInd,R,T,Blank,Titel,Allign,VPerfo
 New Aanspr,Naam,Woonpl
 Do PPRINT
 Set PCount=PCount+1,LCount=0
 If $G(%Fax),$G(%FaxNr) Set LCount=$$FLINES^vhFAX("LOGO_ORD")
 Set R=^KOFKL(KLNr,"F",OFFNr,1),OffDat=$TR($P(R,D,2),".","-")
 Set KlantInd=^KK1(KLNr),R=^KKL(KlantInd,0)
 Set Naam=$P(R,D,2),Aanspr=$P(R,D,4),Woonpl=$P(R,D,7)
 For Blank=1:1:6 Do CACHE("")
 Set T=$$FIRMANM^DCALG("K",KLNr)
 Do PASTE(PCount,Blank-1,T,40,"","")
 Do PASTE(PCount,Blank,Woonpl,40,"","")
 Set Titel=$$TXT("Offer"_OffTyp),Allign=$L(Titel)
 If OffTyp="K" Set Titel=$$TXT("Offer"_OffTyp,3),Allign=$L(Titel)
 Set T=$$TXT("Date") Set:$L(T)>Allign Allign=$L(T)
 Do PASTE(PCount,Blank,T,2,"","")
 Do PASTE(PCount,Blank,OffDat,Allign+4,"","")
 Set T=Titel_$J("",Allign-$L(Titel)+2)_$TR($FN(OFFNr,","),",",".")
 If $G(%Fax),$G(%FaxNr) Set T=" "_T_" "
 Do PASTE(PCount,Blank-1,T,2-$G(%Fax),"","B")
 If OffTyp="K" Do
 .Set T=$$TXT("Offer"_OffTyp)
 .If $G(%Fax),$G(%FaxNr) Set T=" "_T_" "
 .Do PASTE(PCount,Blank-2,T,2-$G(%Fax),"","B")
 If PCount>1 Do
 .Set T=$$TXT("Vervg")_" ("_(PCount-1)_")"
 .Do PASTE(PCount,Blank,T,"",79,"")
 Quit
 ;
 ; Afdruk titel (eerste blad)
FTITEL 
 New OffDat,KlantInd,R,T,Blank,Titel,Allign,VPerfo
 New Aanspr,Naam,Toenaam,Straat,PostNr,Woonpl,Land
 Set PCount=PCount+1,LCount=0
 If $G(%Fax),$G(%FaxNr) Set LCount=$$FLINES^vhFAX("LOGO_ORD")
 Set R=^KOFKL(KLNr,"F",OFFNr,1),OffDat=$TR($P(R,D,2),".","-")
 Set KlantInd=^KK1(KLNr),R=^KKL(KlantInd,0)
 Set Naam=$P(R,D,2),Toenaam=$P(R,D,3),Aanspr=$P(R,D,4)
 Set Straat=$P(R,D,5),PostNr=$P(R,D,6),Woonpl=$P(R,D,7)
 Set Land=$$LAND^vhRtn1($P(R,D,8))
 Do VHPB^DCALG(PCount,.Blank)
 Set T=$$FIRMANM^DCALG("K",KLNr)
 If KLNr=8545,$L(T),$L(Toenaam) Set R=T,T=Toenaam,Toenaam=R
 Do PASTE(PCount,AdresPos,T,40,"","")
 If '$L(Toenaam) Do
 .Do PASTE(PCount,AdresPos+1,Straat,40,"","")
 .Do PASTE(PCount,AdresPos+3,PostNr_"   "_Woonpl,40,"","")
 .If Land'="BE" Do PASTE(PCount,AdresPos+4,$$LAND^vhRtn1(Land,2,Taal),40,"","")
 If $L(Toenaam) Do
 .Do PASTE(PCount,AdresPos+1,Toenaam,40,"","")
 .Do PASTE(PCount,AdresPos+2,Straat,40,"","")
 .Do PASTE(PCount,AdresPos+4,PostNr_"   "_Woonpl,40,"","")
 .If Land'="BE" Do PASTE(PCount,AdresPos+5,$$LAND^vhRtn1(Land,2,Taal),40,"","")
 Set Titel=$$TXT("Offer"_OffTyp),Allign=$L(Titel)
 If OffTyp="K" Set Titel=$$TXT("Offer"_OffTyp,3),Allign=$L(Titel)
 Set T=$$TXT("Date") Set:$L(T)>Allign Allign=$L(T)
 Do PASTE(PCount,Blank-1,T,2,"","")
 Do PASTE(PCount,Blank-1,OffDat,Allign+4,"","")
 Set T=Titel_$J("",Allign-$L(Titel)+2)_$TR($FN(OFFNr,","),",",".")
 If $G(%Fax),$G(%FaxNr) Set T=" "_T_" "
 Do PASTE(PCount,Blank-3,T,2-$G(%Fax),"","B")
 If OffTyp="K" Do
 .Set T=$$TXT("Offer"_OffTyp)
 .If $G(%Fax),$G(%FaxNr) Set T=" "_T_" "
 .Do PASTE(PCount,Blank-4,T,2-$G(%Fax),"","B")
 Do VHPD^DCALG(PCount,.Blank,.VH)
 Quit
 ;
 ; Afdruk afsluiting (eerste bladzijden)
FOOTER 
 Set C(PCount,LCount)=C(PCount,LCount)_P("D",0)
 If P("Type")'="CA",P("Type")'="BL",P("Type")'="TK" For I=LCount+1:1:MaxLines-1 Do CACHE(L("B","B"))
 Do CACHE(L("B","L"))
 Set T=" "_$$TXT("Vervt")_" "
 Do PASTE(PCount,LCount,T,"",77,"")
 Set C(PCount,LCount)=P("D",1)_C(PCount,LCount)
 Quit
 ;
 ; Afdruk afsluiting (laatste blad)
LFOOTER 
 Do CACHE(L("A","L"))
 Quit
 ;
 ; Afdruk van de voorwaarden
VOORW 
 New B,I,R,R1,T,BCount,Land,%KontKrt,TKontKrt,BetVw,Rembours,VoorBet,LeverVw,GeldVan,GeldTot,VPerfoT
 New KlantInd,Naam,LTemp
 Set VPerfoT=VPerfo
 New VPerfo
 Set BCount=0
 Set R=^KOFKL(KLNr,"F",OFFNr,1),GeldVan=$TR($P(R,D,2),".","-"),GeldTot=$TR($P(R,D,16),".","-")
 Set KlantInd=^KK1(KLNr),R=^KKL(KlantInd,0),Naam=$P(R,D,2),Land=$$LAND^vhRtn1($P(R,D,8)),%KontKrt=$P(R,D,17),BetVw=$P(R,D,18)
 Set R=^KKL(KlantInd,2),TKontKrt=$P(R,D,2)
 Set R=^KKL(KlantInd,3),Rembours=$P(R,D),VoorBet=$P(R,D,2),LeverVw=$P(R,D,3)
 If "CAK"[OffTyp Do  ; Voorwaarden voor contracten, afroep en klantgebonden
 .Set J=""
 .If OffTyp="C" Do
 ..Set J=MaxWeek_D_D
 ..If $L(GeldTot) Set J=J_GeldTot
 ..Else  Set J=J_$$EXTDATE^vhLib.DataTypes($$CALCDATE^vhLib.DataTypes($$INTDATE^vhLib.DataTypes(GeldVan),"W",26+MaxWeek,"LD")-2)
 ..Set J=J_D_Naam
 .For R=1:1:9 If $D(^KBA(22,OffTyp_R)) Do
 ..Do WRAP^vhRtn1(73,"^KBA(22,OffTyp_R,Taal,",J,.I)
 ..If R=1,OffTyp'="C" Do
 ...Set T=$$TXT("BijzVw")
 ...Do BLOCK(T_"`3``U\:`"_($L(T)+3))
 ..For I=1:1:I Do BLOCK(I(I)_"`3``"_$S(R=1&(OffTyp="C"):"B",1:""))
 ..If R=1,OffTyp="C" Do
 ...Do BLOCK("")
 ...Set T=$$TXT("ContVw")
 ...Do BLOCK(T_"`3``U\:`"_($L(T)+3))
 .Do BLOCK(L("V","S")_"`1")
 If OffTyp'="C" Do
 .Set T=$$TXT("Geldig")_" "
 .If $L(GeldTot) Do
 ..Set T=T_$$TXT("Geldig",4)_" "_GeldVan
 ..Set T=T_" "_$$TXT("Geldig",5)_" "_GeldTot
 .Else  Set T=T_$$TXT("Dagen")
 .Do:$$LAND^vhRtn1(KLNr,"K",1,2)="B"
 ..If $L(GeldTot) Do
 ...Set T=T_"."
 ...Do BLOCK(T_"`3``B")
 ...Set T=$$TXT("ExclBTW"),$E(T)=$$UPCASE^vhRtn1($E(T))
 ..Else  Set T=T_", "_$$TXT("ExclBTW")
 .Set T=T_"."
 .Do BLOCK(T_"`3``B"),BLOCK("")
 .Quit:OffMunt="EUR"
 .Do WRAP^vhRtn1(75,"^KBA(22,""S"",Taal,","",.I,4) ; Tekst op offerte
 .For I=1:1:I Do BLOCK(I(I))
 .If I Do BLOCK("")
 Set R=$$LEVVW^KLANT(LeverVw,Taal) ; Leveringsvoorwaarde
 If $L(R) Do
 .Set T=$$TXT("LevVw")
 .Set R=T_"`3``U\:`"_($L(T)+3)_D_R
 .For I=1:1:$L(R,"#") Set $P(R,"#",I)=$P(R,"#",I)_"`"_($L(T)+5)
 .For I=1:1:$L(R,"#") Do BLOCK($P(R,"#",I))
 .Do BLOCK("")
 Set T=$$TXT("BetVw") ; Betalingsvoorwaarde
 Set R=$$BETVW^KLANT(BetVw,%KontKrt,TKontKrt,Rembours,VoorBet,Taal)
 Set R=T_"`3``U\:`"_($L(T)+3)_D_R
 For I=1:1:$L(R,"#") Set $P(R,"#",I)=$P(R,"#",I)_"`"_($L(T)+5)
 For I=1:1:$L(R,"#") Do BLOCK($P(R,"#",I))
 Do BLOCK("")
 If 0,Land="NL" Do  ; Deze voorwaarde is niet meer nodig afgedrukt
 . Do BLOCK($P($T(TVwNl1),U,2)),BLOCK($P($T(TVwNl2),U,2)),BLOCK("") ; Export
 Do MEMO^DCALG("A")
 If Prefs("OrdBev") Do  ; ok voor order
 .If "CAK"[OffTyp Do BLOCK($$TXT("VoorAk")_"   "_$$TXT("Date")_" :"_$J("",15)_$$TXT("HandT")_" :") Quit
 .Set T=$$TXT("GVOrd") Do BLOCK(T_"``53")
 .Set T=$$TXT("Date")_" :" Do BLOCK(T_"``53")
 .Set T=$$TXT("HandT")_" :" Do BLOCK(T_"``53")
 .Do BLOCK("")
 If B(BCount)="" Kill B(BCount) Set BCount=BCount-1
 Set LTemp=L("B","S") If P("Type")="CA"!(P("Type")="BL")!(P("Type")="TK") Kill L("B","S")
 If LCount+BCount+2>MaxLines Do FOOTER,TITEL,HEADER
 Set L("B","S")=LTemp
 Set C(PCount,LCount)=C(PCount,LCount)_P("D",0)
 If P("Type")'="CA",P("Type")'="BL",P("Type")'="TK" For I=LCount+1:1:MaxLines-2-BCount Do CACHE(L("B","B"))
 Do CACHE(L("V","F"))
 Set C(PCount,LCount)=P("D",1)_C(PCount,LCount)
 Do PASTEB(L("V","B"))
 Quit
 ;
 ;
 
#define KLRec(%i)   ^KKL(KLID,%i)
 
 ; Afdruk van de voorwaarden v - via proxy objects - Added by WimV on 10/09/2007
VOORWVhisiePROXY(KLNr,oOfferte,Cache,Taal)   ; Cache als .local doorgeven --> wordt opgevuld met teksten
 New KLID,Naam,Land
 New D,Q,U
 Set D="\",Q="K",U=";"
 Set KLID=^KK1(KLNr)
 Set:($G(Taal)="") Taal=$P(^KKL(KLID,0),"\",9)  Set:(Taal="") Taal="N"
 ; Leveringsvoorwaarde & Betalingsvoorwaarde
 Do vwpAlgVoorw(KLNr,KLID,Taal,.Cache)
 ; Memo
 Do MEMOPROXY^DCALG("A",Taal,.Cache)
 Quit
 ;
 ; Afdruk van de voorwaarden - via proxy objects - Added by WimV on 10/09/2007
VOORWPROXY(KLNr,OFFNr,OffType,Cache,Taal)   ; Cache als .local doorgeven --> wordt opgevuld met teksten
 New KLID,Rec,LeverVw,R,i,arTxt,J,TypeVW,Naam,Land,GeldigVan,GeldigTot,MaxWeek
 New LeverVw,BetVw,PctKontKrt,TKontKrt,Rembours,VoorBet
 New D,Q,U
 Set D="\",Q="K",U=";"
 Set KLID=^KK1(KLNr)
 Set Rec=$G(^KOFKL(KLNr,"F",OFFNr,1))
 Set GeldigVan=$TR($P(Rec,"\",2),".","-")
 Set GeldigTot=$TR($P(Rec,"\",16),".","-")
 Set:($G(Taal)="") Taal=$P($$$KLRec(0),"\",9) Set:(Taal="") Taal="N"
 Set Naam=$P($$$KLRec(0),"\",2)
 Set Land=$$LAND^vhRtn1($P($$$KLRec(0),"\",8))
 ; Voorwaarden voor contracten, afroep en klantgebonden
 If OffType?1(1"C",1"A",1"K") Do
 . If OffType="C" Do
 . . Set MaxWeek=$$vwpCalcLeverTermijn(KLNr,OFFNr)
 . . Set J=MaxWeek_D_D
 . . Set J=J_$S($L(GeldigTot):GeldigTot, 1:$$EXTDATE^vhLib.DataTypes($$CALCDATE^vhLib.DataTypes($$INTDATE^vhLib.DataTypes(GeldigVan),"W",26+MaxWeek,"LD")-2))
 . . Set J=J_D_Naam
 . Else  Set J=""
 . For R=1:1:9 If $D(^KBA(22,OffType_R)) Do
 . . Set TypeVW=$S(OffType'="C":"BIJZVOORWAARDE", R=1:"CONTRACTGELDIG" ,1:"CONTRACTVOORWAARDE")
 . . Kill arTxt
 . . Do WRAP^vhRtn1(9999,"^KBA(22,OffType_R,Taal,",J,.arTxt)
 . . For i=1:1:arTxt Set Cache(TypeVW,$O(Cache(TypeVW,""),-1)+1)=arTxt(i)_$C(13,10)
 ; Leveringsvoorwaarde & Betalingsvoorwaarde
 Do vwpAlgVoorw(KLNr,KLID,Taal,.Cache)
 ; Memo
 Do MEMOPROXY^DCALG("A",Taal,.Cache)
   ;d WL^vhDBG($$ArrayToText^vhLib("Cache"))
 Quit
vwpCalcLeverTermijn(KLNr,OFFNr)
#define Max(%v1,%v2)   $S(%v1>%v2:%v1, 1:%v2)
 New OLNr,MaxWeek
 Set MaxWeek=0
 Set OLNr=100
 For  Set OLNr=$O(^KOFKL(KLNr,"F",OFFNr,OLNr)) Quit:OLNr=""  Do
 . Set R=^KOFKL(KLNr,"F",OFFNr,OLNr)
 . Set:($P($P(R,D,17),"#",1)?1(1"KOF0",1"KOF1925")) MaxWeek=$$$Max(MaxWeek,$P(R,D,25))   ; Maximum levertermijn bepalen
 Quit MaxWeek
 ;
vwpAlgVoorw(KLNr,KLID,Taal,Cache)   ; Cache als .local doorgeven
 New R,i,LeverVw,BetVw,PctKontKrt,TKontKrt,Rembours,VoorBet
 Set KLID=$G(KLID,^KK1(KLNr))
 ; Leveringsvoorwaarde
 Set LeverVw=$P($$$KLRec(3),"\",3)
 Set R=$$LEVVW^KLANT(LeverVw,Taal)
 For i=1:1:$L(R,"#") Set Cache("LEVERINGSVOORWAARDE",i)=$P(R,"#",i)
 ; Betalingsvoorwaarde
 Set PctKontKrt=$P($$$KLRec(0),"\",17), BetVw=$P($$$KLRec(0),"\",18)
 Set TKontKrt=$P($$$KLRec(2),"\",2)
 Set Rembours=$P($$$KLRec(3),"\",1), VoorBet=$P($$$KLRec(3),"\",2)
 Set R=$$BETVW^KLANT(BetVw,PctKontKrt,TKontKrt,Rembours,VoorBet,Taal)
 For i=1:1:$L(R,"#") Set Cache("BETALINGSVOORWAARDE",i)=$P(R,"#",i)
 Quit
 
 
 ;
TOTALS 
 New I,R,OLNr,AlgTot,SubTot,Temp,AlgMunt,SubMunt,Munt,KlMunt,AlgBedr,SubBedr,KlantPar,Pariteit,Land
 Kill Totals
 If 'Prefs("Totals") Quit
 Set KlMunt=$P(^KKL(^KK1(KLNr),0),D,11) Set:KlMunt="" KlMunt=$$FADEF^vhRtn1()
 Set OLNr=100,(SubTot,AlgTot)=0,(SubMunt,AlgMunt)="",Land=$$LAND^vhRtn1($P(^KKL(^KK1(KLNr),0),D,8))
 Set:KlMunt="MTL" KlMunt=$$LANDMUNT^KLANT(Land)
 Set KlantPar=$$MUNT^vhRtn1(KlMunt,,12)
 For  Set OLNr=$O(^KOFKL(KLNr,"F",OFFNr,OLNr)) Quit:OLNr=""  Do
 .Set R=^KOFKL(KLNr,"F",OFFNr,OLNr),(SubBedr,AlgBedr)=$P(R,D,9),Munt=$P(R,D,22)
 .If $L(Munt) Do
 ..Set:SubMunt="" SubMunt=Munt
 ..If Munt'=SubMunt Do
 ...Set Pariteit=$$MUNT^vhRtn1(Munt,,12)
 ...Set SubBedr=$J(SubBedr*Pariteit,0,2),SubBedr=$J(SubBedr/KlantPar,0,2)
 ...If SubMunt'=KlMunt Do
 ....Set Pariteit=$$MUNT^vhRtn1(SubMunt,,12)
 ....Set SubTot=$J(SubTot*Pariteit,0,2),SubTot=$J(SubTot/KlantPar,0,2),SubMunt=KlMunt
 ..Set SubTot=SubTot+SubBedr
 ..Set:AlgMunt="" AlgMunt=Munt
 ..If Munt'=AlgMunt Do
 ...Set Pariteit=$$MUNT^vhRtn1(Munt,,12)
 ...Set AlgBedr=$J(AlgBedr*Pariteit,0,2),AlgBedr=$J(AlgBedr/KlantPar,0,2)
 ...If AlgMunt'=KlMunt Do
 ....Set Pariteit=$$MUNT^vhRtn1(AlgMunt,,12)
 ....Set AlgTot=$J(AlgTot*Pariteit,0,2),AlgTot=$J(AlgTot/KlantPar,0,2),AlgMunt=KlMunt
 ..Set AlgTot=AlgTot+AlgBedr
 .Quit:$P($P(R,D,17),"#")'="KOFGRP"
 .If $P($P(R,D,17),"#",2) Set Totals(OLNr)=SubTot_D_SubMunt,SubTot=0,SubMunt=""
 .Else  Set Totals(OLNr)=AlgTot_D_AlgMunt,(SubTot,AlgTot)=0,(SubMunt,AlgMunt)=""
 Quit
 ;
 ; Afdrukken van een bladzijde
PPRINT 
 Do PPRINT^DCPRINT(PCount)
 Kill C(PCount)
 Quit
 ;
 ; Ophalen taalafhankelijke tekst
TXT(Ref,Piece) 
 If '$D(Piece) Set Piece=2
 Quit $P($P($T(@("T"_Ref)),U,Piece),D,$F("NFDE",Taal)-1)
 ;
TOfferD ;OFFERTE\OFFRE\ANGEBOT\OFFER
TOfferC ;CONTRACT\CONTRAT\CONTRACT\CONTRACT;CONTRACTORDER\CONTRAT\CONTRACT\CONTRACT
TOfferA ;AFROEPORDER\AFROEPORDER\AFROEPORDER\AFROEPORDER
TOfferK ;KLANTGEBONDEN\COMMANDE PRODUITS\KLANTGEBONDEN\KLANTGEBONDEN;ORDER\SPECIFIQUES CLIENT\ORDER\ORDER
TDate ;Datum\Date\Datum\Date
TRef ;Ref\Ref\Ref\Ref
TVervg ;vervolg\suite\fortsetzung\continue
TVervt ;vervolgt\à suivre\fortgesetzt\t.b.continued
TArt ;Artikel\Article\Artikel\Article
TAant ;Aantal\Quant.\Menge\Quant.
TPrijs ;E.Prijs\Prix U\E.Preis\U.Price
TBedr ;Bedrag\Montant\Betrag\Amount
TLevTrm ;Termijn\Delai\Termin\Deliv
TKort ;Korting\Remise\Rabat\Discount
TBestIp ;Bestel\Appel\Bestel\Bestel;impuls\de cde\impuls\impuls 
TAfnPer ;Min.\Quant.\Min.\Min.;afname\min.\afname\afname
TStock ;Stock\Stock\Lager\Stock
TWeek ;wk\se\wo\we
TVwNl1 ;Verkopen en leveringen in Nederland volgens BELUNED-condities, gedeponeerd
TVwNl2 ;bij de Kamer van Koophandel en Fabrieken te 's Gravenhage onder nummer 1287.
TBijzVw ;Bijzondere voorwaarden\Conditions spéciales\Bijzondere voorwaarden\Bijzondere voorwaarden
TContVw ;Contractvoorwaarden\Conditions du contrat\Contractbedingungen\Contractvoorwaarden
TLevVw ;Leveringsvoorwaarde\Conditions de livraison\Lieferbedingung\Betalingsvoorwaarde
TBetVw ;Betalingsvoorwaarde\Conditions de paiement\Zahlungsbedingung\Betalingsvoorwaarde
TGVOrd ;Goed voor order\Bien pour commande\Gut fur auftrag\Ok to order
TVoorAk ;Voor akkoord\Pour accord\Voor akkoord\Voor akkoord
TGeldig ;Geldig\Valable\Gueltig\Valid;op\le\den\on;van\du\vom\from;tot\jusqu a\bis\until
TDagen ;30 dagen\30 jours\30 tage\30 days
THandT ;Handtekening\Signature\Unterschrift\Handtekening
TKlRef ;Uw ref\Votre ref\Ihre ref\Uw ref
TExclBTW ;alle opgegeven prijzen zijn exclusief BTW\tous les prix mentionnés s'entendent hors TVA\alle opgegeven prijzen zijn exclusief BTW\alle opgegeven prijzen zijn exclusief BTW\