BeheerLeveringsAdres ;BEHEER LEVERINGSADRESSEN ;Do van %FA13,%FA14 [ 11/08/2003  3:05 PM ]

VerwerkLeverAdres
 N FG,F7,F8
 Set F7="$C(27),""(0""",F8="$C(27),""(B"""
 S FG="*108\*107\*109\*106\*119\*117\*116\*118\*113\*120\*110\*108\*107\*109\*106\*119\*117\*116\*118\*113\*120\*110\"
 D E^cA612
 S PNT="........................................",SL="\\\\\\\\\\\\\\\\\\\\\\\\\\",U=";",Q1="^"_Q_"K1(KC)",SW1=0,SW2=1
 D ToonTitel
 S X=@("^"_Q_"KL(0,0)"),X=10,K=100
 D WisScherm
 F  S X=$N(^(X)) Q:X<0!(X>99)  S U2=^(X),K=K+1,A(K)=U2
SelecteerKlant
 I $G(Extern) S KI1=^KK1(KC) G SelecteerKlant17
 S FP=2001 W @F,@F1
 S KC=$$SELECT^KLANT6()
 G Exit:'KC S KI1=^KK1(KC)
 S FP=2001 W @F,@F1
 L @Q1:2 E  X ^cTXT(0,"N",60) R K G SelecteerKlant
SelecteerKlant17 S LAC="" D ToonHoofding
SelecteerLeverAdres
 S K=$$SELECT^LEVADR(KC,"NR")
 I K="" G SelecteerKlant:'$G(Extern),Exit
 I K="N" F K=1:1 Quit:'$D(^KKL(KI1,"L"_$J(K,3)))
 D
 .N FG,F7,F8
 .D O^cA612(1,1,24,80,0,0,0,0)
 K KCL S SW7=0,KI2="L"_$J(K,3),FP=2001 W @F,@F1 S LAC=K
 D ToonTitel,ToonHoofding
 I '$D(@("^"_Q_"KL(KI1,KI2)")) D
 .S B(1)=SL
 .D WisScherm,^cFA13
 E  D
 .D WisScherm
 .D ^cFA14 S SW1=1
 S FP=2001 W @F,@F1
 D E^cA612
 G SelecteerLeverAdres
Exit
 Q

GeefOorsprong
 S FP=2203+F60 W @F,@F1,"LEVERINGSADRES :"
 w !?2,".[] = manueel ",!?2,"*[] = manueel via andere klant"
 S FP=2220+F60 W @F,@F0 R K S KCM=K I "*"'=K G GeefOorsprongZ:"-.,"[K&$L(K),GeefOorsprong
GeefOorsprongB D E^cA612 S K=$$SELECT^KLANT6(),FP=2101 W @F,@F1
 G GeefOorsprong:'K S K=^KK1(K)
 G GeefOorsprongB:K=KI1 S B(0)=^KKL(K,0)
 I KCM'="*" S KCL=K,K=$P(B(0),D,1)
 E  S $P(B(1),D,2,9)=$P(B(0),D,2,9),$P(B(1),D,13,14)=$P(B(0),D,13,14),$P(B(1),D,15)=$P(^KKL(K,1),D,24),K="."
GeefOorsprongZ
 Q
 
ToonTitel
 N K
 S K=$P($T(+1),U,2)_QN_" ",FP=203+$L(K) W @F61,@F11,@F1,@F,@F5 S FP=202 W @F,@F4,K,@F5
 Q
 
ToonHoofding N U2
 S FP=408 W @F,@F5 S FP=402 W @F,@F6,"KLANT",@F5," : "
 S U2=@("^"_Q_"KL(KI1,0)"),FP=412 W @F,@F2,$P(U2,D,1)," ",$P(U2,D,4)," ",$P(U2,D,2)
 S FP=512 W @F,@F2,$P(U2,D,5) S FP=612 W @F,@F2,$$LAND^vhRtn1($P(U2,D,8)) W:$L($P(U2,D,8)) "   " W $P(U2,D,6),"   ",$P(U2,D,7) D WisScherm
 Q
 
WisScherm N U1,U2
 S U1=100,SW1=0
 F  S U1=$N(A(U1)) Q:U1<0  D
 . S U2=A(U1)
 . S FP=$P(U2,U,2)*100+$P(U2,U,3) W:$P(U2,U,22) @F,$J(U1#100,2) I '$P(U2,U,23) S FP=FP+2 W @F,@F6,$P(U2,U,1),@F9
 . S FP=$P(U2,U,5)*100+$P(U2,U,6) I '$P(U2,U,23) S FP=FP-3 W @F,@F9,":"
 . S FP=$P(U2,U,5)*100+$P(U2,U,6) W @F,$J("",$P(U2,U,9)),$J("",$P(U2,U,13))
 Q
 
ToonScherm N U1,U2,U3,K,X
 S U1=""
 F  S U1=$O(A(U1)) Q:U1=""  D
 .S U2=A(U1),X=$P(U2,U,16) S:'$D(B(X\100)) B(X\100)="\\\\\\\\\\\\\\\\\\\\\\\\\" S (K,U3)=$P(B(X\100),D,X#100) I $L($P(U2,U,8)) X "S U3="_$P(U2,U,8)
 .S FP=$P(U2,U,5)*100+$P(U2,U,6)
 .W:SW1 @F,$J("",$P(U2,U,9)),$J("",$P(U2,U,13)) W @F,U3
 Q
 
Extern(KLNr)
 New KC,Extern
 Set (KC,Extern)=KLNr
 Goto VerwerkLeverAdres
 ;
 
 ; Ingave adrestype
AdresType
 New AdresType,zb,R,U2,X
 If $G(K)'="-" Do
 .D E^cA612
 .Set K=$P(B(1),D,12)
 .For  Set AdresType=$$PI^vhPOPUP("C;C","-1OA","","KLANT","ADRESTYPE",$S(K="":"L",1:K)),zb=$G(zb) Quit:zb="CANC"  Quit:$$CheckAdresTypes(AdresType)
 .Set K=$S(zb="CANC":"-",1:AdresType)
 .D
 ..N FG,F7,F8
 ..D O^cA612(1,1,24,80,0,0,0,0)
 .D ToonTitel,ToonHoofding,ToonScherm
 Quit
 
 ; Controle op ingave adrestype
CheckAdresTypes(AdresType)
 New AdresTypeOk,LevAdr,KlKey
 Set AdresTypeOk=1,LevAdr="L",KlKey=^KK1(KC)
 If AdresType="F"!(AdresType="B") Do  ; Verzendadres factuur of Bezoekadres (mag niet dubbel)
 . For  Set LevAdr=$O(^KKL(KlKey,LevAdr)) Quit:$E(LevAdr)'="L"  If $P(^KKL(KlKey,LevAdr),D)'=$P(B(1),D) Set AdresTypeOk=($P(^KKL(KlKey,LevAdr),D,12)'=AdresType) Quit:'AdresTypeOk
 . If 'AdresTypeOk Do WARN^vhTXTPOP("Er bestaat reeds een adres van~het type '"_$P(^RES("KLANT","PI","ADRESTYPE","D",AdresType),"`",2)_"'.","")
 Quit AdresTypeOk
 
 ; Mag een popupitem getoond worden?
CBADRESTYPE(Item)
 New Include
 If '$D(^KKL(KI1,KI2)) Do  ; Indien nieuw adres
 . New R,KI2
 . Do:$P(Item,"`")="B" ; Er mag slechts een bezoekadres ingegeven worden
 . . Set KI2="L"
 . . For  Set KI2=$O(^KKL(KI1,KI2)) Quit:$E(KI2)'="L"  Do  Quit:'Include
 . . . Set R=^KKL(KI1,KI2),Include=$P(R,"\",12)'="B"
 . Do:$P(Item,"`")="F" ; Er mag slechts een verzendadres factuur ingegeven worden
 . . Set KI2="L"
 . . For  Set KI2=$O(^KKL(KI1,KI2)) Quit:$E(KI2)'="L"  Do  Quit:'Include
 . . . Set R=^KKL(KI1,KI2),Include=$P(R,"\",12)'="F"
 Quit $G(Include,1)
 
AantalAdressen
 New R,KLNr,LevCount,BezCount
 Set KLNr=$P($G(B(1)),D,1),U3="neen"
 If $L(KLNr),$D(^KK1(KLNr)) Do
 . Set U3="L",(LevCount,BezCount)=0
 . For  Set U3=$O(^KKL(^KK1(KLNr),U3)) Quit:$E(U3)'="L"  Do
 . . Set R=^KKL(^KK1(KLNr),U3)
 . . If $P(R,D,12)="B" Set BezCount=BezCount+1
 . . Else  Set LevCount=LevCount+1
 . If 'LevCount,'BezCount Set U3="neen"
 . Else  Set U3="ja ("_LevCount_"/"_BezCount_")"
 Quit