ECNJOB ;e-Commerce [ 12/22/2003  11:40 AM ]
 ;
 Do CLEAR,MENU
 Quit
 ;
CLEAR 
 Kill ^EC("C")
 Quit
 ;
MENU 
 New D,R,UserNW,KLNr
 Kill ^EC("MUS"),^EC("MKL")
 Set D="\",UserNW=""
 If $G(^ATK(0,0,"A"))'="STOP" Do
 .For  Set UserNW=$O(^ATK("W",UserNW)) Quit:UserNW=""  Do ONEMENU(UserNW)
 .Set KLNr=0
 .For  Set KLNr=$O(^KK1(KLNr)) Quit:KLNr=""  Do:$$CHECKKL(KLNr) ONEMENU(,KLNr)
 Quit
 ;
ONEMENU(UserNW,KLNr) 
 New D,R,UserName,WachtW,Menu,UserId
 Set D="\"
 If $L($G(UserNW)) Do
 .Quit:'$D(^ATK("W",UserNW))
 .Set UserName=$P(UserNW,D),WachtW=$P(UserNW,D,2)
 .Set R=^ATK("W",UserNW),KLNr=$P(R,D),UserId=$P(R,D,5)
 .Quit:UserId=""  Quit:$G(^ATK(KLNr,0,"A"))=0  Quit:$G(^ATK(KLNr,UserName,"A"))=0
 .Kill ^EC("MUS",UserId)
 .Quit:'$D(^KK1(KLNr))
 .Set Menu=$G(^ATK(KLNr,UserName,"M"),$G(^ATK(KLNr,0,"M"),$G(^ATK(0,0,"M"))))
 .If $TR(Menu,"\K","")="" Do
 ..Set Menu=$G(^ATK(KLNr,0,"M"),$G(^ATK(0,0,"M"))) Set:$TR(Menu,"\K","")="" Menu=$G(^ATK(0,0,"M"))
 ..Set:$TR(Menu,"\K","")'="" Menu=Menu_"\C\T\R\E"
 .Set:'$D(^ATK(KLNr,UserName,"M")) Menu=$$MODMENU(KLNr,Menu)
 .Set:(KLNr'=1759)&&(KLNr'=6279) Menu=Menu_"\PI" ; niet voor Masson of Optima
 .Do SETMENU(UserId,,Menu),ONEMENU(,KLNr)
 If $L($G(KLNr)) Do
 .Kill ^EC("MKL",KLNr)
 .Quit:'$D(^KK1(KLNr))  Quit:$G(^ATK(KLNr,0,"A"))=0
 .Set Menu=$G(^ATK(KLNr,0,"M"),$G(^ATK(0,0,"M"))),Menu=$$MODMENU(KLNr,Menu)
 .Do SETMENU(,KLNr,Menu)
 Quit
 ;
MODMENU(KLNr,Menu) 
 New R,KlantId,Land,ORDNr
 Set KlantId=^KK1(KLNr),R=^KKL(KlantId,0),Land=$P(R,D,8)
 If (D_Menu_D)["\O\" Do
 .Set ORDNr=""
 .For  Set ORDNr=$O(^KOD(KLNr,"F",ORDNr)) Quit:ORDNr=""  Quit:$P(^KOD(KLNr,"F",ORDNr,1),D,25)="C"
 .Set:ORDNr Menu=Menu_"\C"
 .Set ORDNr=""
 .For  Set ORDNr=$O(^KOD(KLNr,"F",ORDNr)) Quit:ORDNr=""  Quit:$P(^KOD(KLNr,"F",ORDNr,1),D,25)="A"
 .Set:ORDNr Menu=Menu_"\A"
 .Set:$D(^BLBeri("IK",KLNr)) Menu=Menu_"\T"
 If $$LAND^vhRtn1(Land)'="BE",$D(^KFA1("F",KLNr)) Set Menu=Menu_"\E"
 If $E($O(^KKL(KlantId,"L")))="L" Set Menu=Menu_"\Y"
 If $D(^PAKKET("IK",KLNr))>0,Menu'="S" Set Menu=Menu_"\W\R"
 Set:(KLNr'=1759)&&(KLNr'=6279) Menu=Menu_"\PI" ; niet voor Masson of Optima
 Quit Menu
 ;
SETMENU(UserId,KLNr,Menu) 
 New I,R,MenuItem
 Set KLNr=$G(KLNr)
 Set Menu=$$CONVMENU(Menu)
 Set R="^EC("""_$S(KLNr:"MKL",1:"MUS")_""","_$S(KLNr:KLNr,1:"UserId")_",MenuItem)"
 For I=1:1:$L(Menu,D) Set MenuItem=$P(Menu,D,I) Set:$L(MenuItem)=2 @R=""
 Quit
 ;
CONVMENU(Menu) 
 New I
 Set:$E(Menu)'=D Menu=D_Menu Set:$E(Menu,$L(Menu))'=D Menu=Menu_D
 For I=1:1:$L(Menu,D) Do
 .Set:$P(Menu,D,I)="O" $P(Menu,D,I)="SO"
 .Set:$P(Menu,D,I)="C" $P(Menu,D,I)="CO"
 .Set:$P(Menu,D,I)="T" $P(Menu,D,I)="DO"
 .Set:$P(Menu,D,I)="B" $P(Menu,D,I)="UL"
 .Set:$P(Menu,D,I)="S" $P(Menu,D,I)="OF"
 .Set:$P(Menu,D,I)="V" $P(Menu,D,I)="VA"
 .Set:$P(Menu,D,I)="R" $P(Menu,D,I)="KR"
 .Set:$P(Menu,D,I)="E" $P(Menu,D,I)="IS"
 Quit Menu
 ;
CHECKKL(KLNr) 
 New D,R,ComNAkt
 Set D="\",R=^KKL(^KK1(KLNr),2),ComNAkt=$P(R,D,10)
 Quit 'ComNAkt
 ;