ENQUETE ;Opvraging Enquete [ 03/16/95  10:56 AM ]
 D:'$D(Q) ^cA604
 Write @F11,@F1
 X FLO
 Read "KlantNr (Klnr met een '+' is wijzigen) : ",KLNr
 Set Wijz=""
 If KLNr["+" Set Wijz=1,KLNr=$TR(KLNr,"+","")
 Quit:KLNr="-"!(KLNr=".")
 Goto ENQUETE:KLNr'?4.5N
 If '$D(^KK1(KLNr)) W !,*7,"Foutieve klant" h 3 Goto ENQUETE
 Write " ",$P(^KKL(^KK1(KLNr),0),D,2),!
 If 'Wijz,$D(^Enquete(KLNr)) Write *7,"Klant is reeds ingevuld herdoen J[] ?",*7 R K G:"J"'=$$UPCASE^vhRtn1(K) ENQUETE W !
 Kill:'Wijz ^Enquete(KLNr)
 Set Enq(1)=$G(^Enquete(KLNr,1))
 Set Enq(2)=$G(^Enquete(KLNr,2))
 Set Enq(3)=$G(^Enquete(KLNr,3))
 Set String=""
 For I=1:1 Do  Quit:K="."!(I<-1)
 .If Wijz Read !,"Rubriek : ",I Set:I="-"!(I=".") K="." Q:'(I>0&(I<50))  If I Write " waarde : ",$P(Enq($S(I<38:1,I<46:2,1:3)),D,$S(I<38:I,I<46:I-37,1:I-45))
 .Write:I=15&'Wijz !
 .If I<38 Set K=$$READ(I,Wijz,0,"012345")
 .If I=38 Set K=$$READ(I,1,0,"01234689")
 .If I=39 Set K=$$READ(I,1,0,";1;2;3;4;6;12;52;0;")
 .If I=40 Set K=$$READ(I,1,0,"01")
 .If I=42 Set K=$$READ(I,1,0,";0;24;2;5;14;")
 .If I=41!(I>42) Set K=$$READ(I,1,"","")
 .If K="." Set I=99 Q
 .If K="-" Set I=I-2 Q
 .Do STORE(I,K)
 .Set:I=49 Wijz=1
 Set ^Enquete(KLNr,1)=$G(Enq(1))
 Set ^Enquete(KLNr,2)=$G(Enq(2))
 Set ^Enquete(KLNr,3)=$G(Enq(3))
 Goto ENQUETE
 Quit
 
READ(Cnt,Line,Default,Value) 
READ2 If Line Write:Line !,Cnt,": "  Read K
 If 'Line Write " ",Cnt,":" Read *K Set K=$C(K)
 Quit:K="-"!(K=".") K
 ;If " "[K!(K=$C(13)) Set K=Default
 If Value="" Quit K
 If Value'[";",$L(K),Value[K Quit K
 If Value[";",$L(K),Value[(";"_K_";") Quit K
 Quit:Value="" ""
 Write !,*7,"Foutieve ingave ",Value," Rubriek "
 Goto READ2
 
STORE(I,Val) 
 If I<38 Set $P(Enq(1),D,I)=Val Quit
 If I<46 Set $P(Enq(2),D,I-37)=Val Quit
 Set $P(Enq(3),D,I-45)=Val
 Quit