FLOWBON6 ;Selecteren van een leveringsbon en het afdrukken van de Orgaluxlabels [ 11/25/2003  3:03 PM ]
 ;#define LabelPrinterOrgalux "\\t6000\EasyCoder PC4"
 ; rechtstreeks gekoppeld aan de computer van Inpak
 ;#define LabelPrinterOrgalux "\\inpak_orgal_W2K\EasyCoder PC4" 
 ; via printserver
 #define LabelPrinterOrgalux "EasyCoder PC4"  
 Set K="AFDRUKKEN ORGALUXETIKETTEN "_QN_" ",FP=203+$L(K)
 Write @F61,@F11,@F1,@F,@F5
 Set FP=202
 Write @F,@F4,K,@F5
 ;Do INIT^vhPRINTER("","","UB")
 ;Set Dev=$G(Print("DEV"))
 Set Dev="TEST"
 Do:$L(Dev)
 .New C,KLNr,BONNr
 .For  Set BONNr=$$SELECT^FLOW("KUL","KU1",1) Quit:BONNr="-"  Do PRINT(BONNr)
 Quit
 
FETCHBON(C) 
 New R,KLNr,Adr,BONNr,FakSoort
 Set BONNr=C("BONNR"),KLNr=$P(^KU1(BONNr,"F"),D)
 Set FakSoort=$S($P(^KU1(BONNr,"F"),D,2):"G",1:"F") ; Reeds gefactureerd
 Set Adr=$G(^KUL(KLNr,FakSoort,BONNr,3))
 Set:$L($TR(Adr,"\",""))<5 Adr=^KKL(^KK1(KLNr),0)
 Set C("BONNR")=$$EXTNUM^vhLib.DataTypes(BONNr,0,".",0)
 Set C("KLNM")=$P(Adr,D,2)
 Set C("KLNR")=KLNr
 Set C("GEMEENTE")=$E($P(Adr,D,7),1,18)
 Set C("TAAL")=$P(^KKL(^KK1(KLNr),0),D,9)
 Set C("FETCHBON")=1,C("BONNR")=BONNr
 Quit
 
FETCHORD(C) 
 New R,KLNr,OrdRef,OrgalRef,BONNr,ORDNr,BLNr,FakSoort
 Set BONNr=C("BONNR"),BLNr=C("BLNR"),KLNr=$P(^KU1(BONNr,"F"),D)
 Set FakSoort=$S($P(^KU1(BONNr,"F"),D,2):"G",1:"F") ; Reeds gefactureerd
 Kill C("FETCHORD"),C("ORDNR")
 For  Set BLNr=$O(^KUL(KLNr,FakSoort,BONNr,BLNr),-1) Quit:BLNr<100  Do  Quit:$G(C("ORDNR"))
 .Set R=^KUL(KLNr,FakSoort,BONNr,BLNr)
 .Quit:$P(R,D,17)'="KF5"
 .Set ORDNr=$P($P(R,D,5)," - ",1),OrdRef=$P($P(R,D,5)," - ",3,99),OrgalRef=$P(R,D,20)
 .Set C("ORDREF")=OrdRef
 .Set C("ORGLREF")=OrgalRef
 .Set C("FETCHORD")=1,C("ORDNR")=ORDNr
 Quit
 
FETCHPR(C) 
 New I,R,PRNr,KortTxt,LangTxt1,LangTxt2,LangTxt3,OrgVerp
 Set PRNr=C("PRNR")
 Do ORGVERP(PRNr,.OrgVerp)
 Kill C("ORGVERP")
 Set OrgVerp=""
 For  Set OrgVerp=$O(OrgVerp(OrgVerp)) Quit:OrgVerp=""  Do
 .Set C("ORGVERP",OrgVerp)=OrgVerp(OrgVerp)
 .Merge:OrgVerp="I" C("ORGVERP",OrgVerp)=OrgVerp(OrgVerp)
 Do:$D(C("GROEP"))
 .If C("GROEP") Do
 ..Kill C("ORGVERP")
 ..Set C("ORGVERP","S")=1
 .Else  Do
 ..Kill C("ORGVERP","S"),C("ORGVERP","Z")
 ..If '$D(C("ORGVERP","I")),'$D(C("ORGVERP","O")) Set C("ORGVERP","Z")=""
 Do:PRNr
 .Set R=^KPR(PRNr,0),C("KORTTXT")=$E($P(R,D),4,11)
 .Set R=$$GETOMSCH^PRODUKT2(PRNr,$G(C("TAAL"),"N"))
 .For I=1:1 Quit:$P(R,D,I)=""  Set C("LANGTXT"_I)=$P(R,D,I)
 .For I=I:1 Quit:'$D(C("LANGTXT"_I))  Kill C("LANGTXT"_I)
 Quit
 
 ; Print
WLABEL(Dev,C) 
 Do PrintPPS  ;WriteLabelWithPicture
  Quit
 New I
 use Dev
 For I=1:1 Set Lijn=$T(@("L"_$G(C("TAAL"),"N")_$S($G(C("PRNR"))="V":"V",1:"")_I)) Quit:Lijn=""  Do
 . Write @$P(Lijn,";",2),!
 Quit
 
PrintPPS ;ViaPPSOLInpak
	Set %blPPSOLInpak=##class(BL.PPS.OL.Inpak).%New()
	Set BONNr=$G(C("BONNR"))
	If $G(C("PRNR")) Do ; Product
	. Set PRNr=C("PRNR")
	. Set Aantal=1 ;$G(C("COUNT"))
	. w PRNr," ",Aantal,! r k
	. Do %blPPSOLInpak.PrintProductBare(BONNr,PRNr,Aantal) 
	Else  Do ; Overdoos
	. Set Aantal=$G(C("AANTOVVP"))
	. Do %blPPSOLInpak.PrintOverdoosBare(BONNr,Aantal) 
	Q
 
 s PRNr=386983 w $$GetPicture^FLOWBON6(PRNr)
 w "\\CACHE01"_$TR(##class(cspBasis.ProductList).DataDefValueURL("N","OL",PRNr,"InfoSleutel","LI"),"/","\")
 
GetPicture(PRNr)
	Set URL=##class(Prod.Kenmerk.DataDefinitie).GetFullURL("OL",PRNr,"InfoSleutel","N","LI","BARTENDER")
	Quit:URL=""
	If URL[("ViaSleutel\") Do ; old
	. Set:$L(URL) $P(URL,"\",1,4)="\\notes01\e$\Data\OrgaLabelImages" ; Moet aangepast worden 
	Else  Do
	. Set TestURL=$$REPLACE^vhRtn1(URL,"ViaSleutelG","ViaSleutel")
	. Set TestURL=$P(TestURL,".")_"_G"_$P(TestURL,".",2)
	. Set $P(TestURL,"\",1,4)="\\notes01\e$\Data\OrgaLabelImages" ; Moet aangepast worden 
	. If ##class(%File).Exists(TestURL) Do
	. . Set URL=TestURL
	. Else  Do
	. . Set URL="\\CACHE01"_URL
	Quit URL
	 
 
WriteLabelWithPicture
	Set $ZTRAP="SoapError"
	Set pxData=##class(WS.Flow.Orgalux.pxOLPrintData).%New()
	Set pxData.Type=$S($G(C("PRNR"))="V":"V",1:"P")
 
	If pxData.Type="P" Do
	. Set pxData.PRNr=C("PRNR")
	. Set pxData.Image=$$GetPicture(pxData.PRNr)
	. Set pxData.ProductNaam=$G(C("KORTTXT"))
	. Set pxData.Omschrijving=$G(C("LANGTXT1"))_"~"_$G(C("LANGTXT2"))_"~"_$G(C("LANGTXT3"))_"~"
	. Set pxData.ExtraAantal=$G(C("COUNT"))
	Else  Do ; Type="V"
	. Set pxData.ExtraAantal=$G(C("AANTOVVP"))
 
	Set pxData.KlantNaam=$G(C("KLNM"))
	Set pxData.CommRef=$G(C("ORGLREF"))
	Set pxData.OrderRef=$G(C("ORDREF"))
	Set pxData.Gemeente=$G(C("GEMEENTE"))
	Set pxData.BonNr=$G(C("BONNR"))
	Set pxData.KLNr=$G(C("KLNR"))
	Set pxData.Aantal=1
	New ws,sc
	Set ws=##class(WS.Flow.Orgalux.wsPrintSoap).%New()
	Set sc=ws.OLPrintOne(pxData,$$$LabelPrinterOrgalux) ;"\\notes01\inpak_orgal_pcl")
	Quit
	
SoapError
	Set $ZTRAP=""
	Do SOAPErrorMail^cspBasis.SOAPlib("",,"FLOWBON6 : Afdruk Orgalux etiket failed "_$G(C("BONNR")),) ; use default message settings
	Set $ZE=""
	Quit
 
wlabel 
 New r
 For I=1:1 Set Lijn=$T(@("L"_$G(C("TAAL"),"N")_$S($G(C("PRNR"))="V":"V",1:"")_I)) Quit:Lijn=""  Do
 .Write @$P(Lijn,";",2),!
 Read r
 Quit
 
 ; Transfert
TLABEL(Transfert,C) 
 New I,R,Rec,TCount
 Set Rec=""
 For I=1:1 Set Lijn=$T(@("L"_$G(C("TAAL"),"N")_"T"_$S($G(C("PRNR"))="V":"V",1:"")_I)) Quit:Lijn=""  Do
 .Xecute "Set R="_$P(Lijn,";",2)
 .Set Rec=Rec_$C(9)_R
 Set $E(Rec)="",TCount=$O(^HULP(Transfert,"T",""),-1)+1,^HULP(Transfert,"T",TCount)=Rec
 Quit
 
tlabel 
 New r
 Set Rec=""
 For I=1:1 Set Lijn=$T(@("L"_$G(C("TAAL"),"N")_"T"_$S($G(C("PRNR"))="V":"V",1:"")_I)) Quit:Lijn=""  Do
 .Xecute "Set R="_$P(Lijn,";",2)
 .Set Rec=Rec_";"_R
 Set $E(Rec)=""
 Write Rec,!
 Read r
 Quit
 
 ; BONNr kan meerdere nrs bevatten "\" gescheiden.
 ; Elk BONNr kan als volgt zijn opgebouwd:
 ;   BONNr = de volledige bon
 ;   BONNr#ULNr = Bepaalde lijn van een bon
 ;   BONNr#ULNr#Aantal = Bepaald aantal (verschillend van het aantal in de lijn)
 ;   BONNr#?#Aantal#PRNr = Bepaald aantal van bepaald produkt (lijn onbekend)
PRINT(BONNr,BackGrnd,Transfert)
 New I,C,R
 Set BackGrnd=$G(BackGrnd)
 If 'BackGrnd Do
 .Do STORE^vhTERMINA()
 .Set FP=2001
 .Write @F,@F1,!?2,"Printing ..."
 If $L($G(Dev)) Do
 .;Open Dev
 .;Use Dev
 If $L($G(BONNr)) For I=1:1:$L(BONNr,D) Do
 .Set R=$P(BONNr,D,I)
 .If $P(R,"#") Do
 ..If $L($P(R,"#",2)) Set BONNr($P(R,"#"),$P(R,"#",2))=$P(R,"#",3,4)
 ..Else  Set BONNr($P(R,"#"))=""
 Set BONNr=""
 For  Set BONNr=$O(BONNr(BONNr)) Quit:BONNr=""  Do
 .Kill C
 .Merge C("BONNR")=BONNr
 .Do ONEBON(.C,1,$G(Transfert))
 ;Close:$L($G(Dev)) Dev
 Do:'BackGrnd REFRESH^vhTERMINA()
 Quit
 
ONEBON(C,BackGrnd,Transfert) 
 New D,R,Q,U,KLNr,BONNr,BLNr,PRNr,Aantal,FakSoort
 Set D="\",U=";",Q="K",BackGrnd=$G(BackGrnd)
 Merge BONNr=C("BONNR")
 Kill C("BONNR")
 Set R=$G(^KU1(BONNr,"F"))
 Set FakSoort=$S($P(R,D,2):"G",1:"F") ; Reeds gefactureerd
 If $L(R) Do
 .Set KLNr=$P(R,D),C("BONNR")=BONNr
 .Do:'$G(C("FETCHBON")) FETCHBON(.C)
 .If $O(BONNr(BONNr,""))="" Do  ; De volledige bon
 ..Set BLNr=10000
 ..For  Set BLNr=$O(^KUL(KLNr,FakSoort,BONNr,BLNr),-1) Quit:BLNr<100  Do
 ...Set R=^KUL(KLNr,FakSoort,BONNr,BLNr),PRNr=$P(R,D,2)
 ...If $P(R,D,17)="KF5" Set C("BLNR")=BLNr+1 Do FETCHORD(.C)
 ...Kill C("AANTAL"),C("PRNR"),C("ORGVERP")
 ...Set C("BLNR")=BLNr
 ...Do:PRNr ONELINE(.C,1,$G(Transfert))
 .Else  Do  ; Enkele lijnen van bon BONNr
 ..Set BLNr=""
 ..For  Set BLNr=$O(BONNr(BONNr,BLNr),-1) Quit:BLNr=""  Do
 ...Set R=BONNr(BONNr,BLNr),Aantal=$P(R,D),PRNr=$P(R,D,2)
 ...Kill C("FETCHORD"),C("ORDNR"),C("AANTAL"),C("PRNR"),C("ORGVERP")
 ...Set C("BLNR")=$P(BONNr(BONNr,BLNr),D,3)
 ...Set:PRNr C("PRNR")=PRNr Set:$L(Aantal) C("AANTAL")=Aantal,C("GROEP")=Aantal[";"
 ...Do ONELINE(.C,1,$G(Transfert))
 Do:'BackGrnd REFRESH^vhTERMINA()
 Quit
 
ONELINE(C,BackGrnd,Transfert) 
 New R,KLNr,BONNr,BLNr,PRNr,Aantal,FakSoort
 Set BackGrnd=$G(BackGrnd),BONNr=C("BONNR"),BLNr=C("BLNR")
 Set R=$G(^KU1(BONNr,"F"))
 Set FakSoort=$S($P(R,D,2):"G",1:"F") ; Reeds gefactureerd
 If $L(R) Do
 .Set KLNr=$P(R,D)
 .Set R=$G(^KUL(KLNr,FakSoort,BONNr,BLNr)),PRNr=$P(R,D,2),Aantal=$P(R,D,3)
 .Set:'$D(C("PRNR")) C("PRNR")=PRNr Set:'$D(C("AANTAL")) C("AANTAL")=Aantal
 .Do:'$G(C("FETCHBON")) FETCHBON(.C)
 .If '$G(C("FETCHORD")) Set C("BLNR")=$S(BLNr="?":999,1:BLNr+1) Do FETCHORD(.C)
 .Set C("BLNR")=BLNr,PRNr=C("PRNR")
 .If BLNr="?",PRNr="" Set (PRNr,C("PRNR"))="V"
 .If PRNr,$$ISORGAL^PRODUKT2(PRNr) Do ONETIKET(.C,1,$G(Transfert))
 .If PRNr="V" Do ONETIKET(.C,1,$G(Transfert))
 Do:'BackGrnd REFRESH^vhTERMINA()
 Quit
 
ONETIKET(C,BackGrnd,Transfert) 
 New R,OrgVerp,Aantal,ExtAant,PRNr
 Set BackGrnd=$G(BackGrnd),BONNr=C("BONNR"),BLNr=C("BLNR"),PRNr=C("PRNR")
 Do FETCHPR(.C)
 Set Aantal=C("AANTAL")
 For  Do  Quit:Aantal=""
 .Do:Aantal>0
 ..Kill OrgVerp
 ..Merge OrgVerp=C("ORGVERP")
 ..Set OrgVerp=""
 ..For  Set OrgVerp=$O(OrgVerp(OrgVerp)) Quit:OrgVerp=""  Do
 ...Quit:OrgVerp="E"
 ...Kill C("OVVP"),C("COUNT"),C("MAXCOUNT")
 ...Set C("AANTAL")=$P(Aantal,";")
 ...Set:OrgVerp="S" C("COUNT")=$J("x"_$P(Aantal,";"),5),C("AANTAL")=1 ; oud
 ...Set:OrgVerp="S" C("COUNT")=$P(Aantal,";"),C("AANTAL")=1 ; nieuw PV 04/08/2008
 ...Set:OrgVerp="O" C("OVVP")=OrgVerp
 ...Do:OrgVerp="I"
 ....Set C("MAXCOUNT")=OrgVerp("I")+$G(OrgVerp("Z"))
 ....Set C("COUNT")=C("MAXCOUNT")+1
 ....Kill OrgVerp("I"),OrgVerp("Z")
 ...For I=1:1:$S($G(C("MAXCOUNT")):C("MAXCOUNT"),1:C("AANTAL")) Do
 ....Set ExtAant=0
 ....If $G(C("MAXCOUNT")) Do
 .....Set:I=C("MAXCOUNT") ExtAant=$G(C("ORGVERP","E"))
 .....If $TR(C("COUNT")," ","")>C("MAXCOUNT") Set C("COUNT")=$J("1/"_C("MAXCOUNT"),5)
 .....Else  Set C("COUNT")=$J($TR(C("COUNT")," ","")+1_"/"_C("MAXCOUNT"),5)
 .....Set:'ExtAant ExtAant=$G(C("ORGVERP","I",+$TR(C("COUNT")," ","")))
 .....For J=1:1:C("AANTAL")+ExtAant Do
 ......Kill C("AANTOVVP")
 ......If $G(C("PRNR"))="V",$S($G(C("MAXCOUNT")):C("MAXCOUNT"),1:C("AANTAL"))+ExtAant>1 Set C("AANTOVVP")=I_"/"_($S($G(C("MAXCOUNT")):C("MAXCOUNT"),1:C("AANTAL"))+ExtAant)
 ......Do:'$G(Transfert) WLABEL($G(Dev),.C)
 ......Do:$G(Transfert) TLABEL(Transfert,.C)
 ....Else  Do
 .....Set ExtAant=$G(C("ORGVERP","E"))
 .....For J=1:1:1+ExtAant Do
 ......Kill C("AANTOVVP")
 ......If $G(C("PRNR"))="V",$S($G(C("MAXCOUNT")):C("MAXCOUNT"),1:C("AANTAL"))+ExtAant>1 Set C("AANTOVVP")=I_"/"_($S($G(C("MAXCOUNT")):C("MAXCOUNT"),1:C("AANTAL"))+ExtAant)
 ......Do:'$G(Transfert) WLABEL($G(Dev),.C)
 ......Do:$G(Transfert) TLABEL(Transfert,.C)
 .Set Aantal=$P(Aantal,";",2,99)
 Do:'BackGrnd REFRESH^vhTERMINA()
 Quit
 
 ; BONNr doorgegeven als .Local
 ; BONNr(BONNr1)=""
 ; BONNr(BONNr2,BLNr1)=""
 ; BONNr(BONNr2,BLNr2)=Aantal
 ; BONNr(BONNr2,"?")=Aantal_D_PRNr
EXTERN(BONNr,Dev,BackGrnd,Transfert) 
 New C
 Set Transfert=$G(Transfert)
 ;If '$L($G(Dev)),'Transfert Set Dev=$$DEV^vhPRINTER("lbl Inpak Orgalux") ; Device labelprinter : \\NOTES01\LABEL ORGALUX
 Set Dev="WebService"
 Do PRINT(.BONNr,$G(BackGrnd),$G(Transfert))
 Quit
 
 ; I = Individueel
 ; S = Single
 ; O = Verpakking
ORGVERP(MPRNr,OrgVerp) 
 New R,BSCode,KPRNr,ICount
 Set (OrgVerp,BSCode)="",ICount=0
 For  Set BSCode=$O(^PRBS("BS",MPRNr,BSCode)) Quit:BSCode=""  Do
 .Set R=^PRBS("BS",MPRNr,BSCode),KPRNr=$P(R,D)
 .Quit:'KPRNr
 .Set:$P(R,D,12)="" $P(R,D,12)="Z"
 .Set ICount=ICount+1
 .If $E($P(R,D,12))="I" Do
 ..Set OrgVerp("I")=$G(OrgVerp("I"),1)+$P(R,D,2)
 ..Set:$E($P(R,D,12),2,9)>1 OrgVerp("I",ICount)=$E($P(R,D,12),2,9)-1
 .Else  If $E($P(R,D,12))="E" Do
 ..If $E($P(R,D,12),2)="-"
 ..Else  Set OrgVerp("E")=$G(OrgVerp("E"))+($E($P(R,D,12),2)*$P(R,D,2))
 .Else  Set OrgVerp($P(R,D,12))=1
 Quit
 
 ; Label definitie NEDERLANDS (print)
LN1 ;""
LN2 ;"ZB"
LN3 ;"N"
LN4 ;"R100,60"
LN5 ;"A0,0,0,5,1,1,N,""",$G(C("KORTTXT")),""""
LN6 ;"A435,22,0,3,2,2,N,""",$G(C("COUNT")),""""
LN7 ;"A0,140,0,4,1,1,N,""",$G(C("LANGTXT1")),""""
LN8 ;"A0,185,0,4,1,1,N,""",$G(C("LANGTXT2")),""""
LN9 ;"A0,230,0,4,1,1,N,""",$G(C("LANGTXT3")),""""
LN10 ;"A0,300,0,4,1,1,N,""","Ref:",""""
LN11 ;"A95,300,0,4,1,1,N,""",$G(C("ORGLREF")),""""
LN12 ;"A95,360,0,4,1,1,N,""",$G(C("KLNM"))_$S($L($G(C("KLNM")))&$L($G(C("GEMEENTE"))):" - ",1:"")_$G(C("GEMEENTE")),""""
LN13 ;"A95,405,0,4,1,1,N,""",$G(C("BONNR"))_$S($L($G(C("BONNR")))&$L($G(C("ORDREF"))):" - ",1:"")_$G(C("ORDREF")),""""
LN14 ;"P1"
 ; Label definitie NEDERLANDS Verpakking (print)
LNV1 ;""
LNV2 ;"ZB"
LNV3 ;"N"
LNV4 ;"R100,60"
LNV5 ;"A0,0,0,4,2,2,N,""",$G(C("AANTOVVP")),""""
LNV6 ;"A0,150,0,4,2,2,N,""",$G(C("ORGLREF")),""""
LNV7 ;"A0,300,0,4,1,1,N,""",$G(C("KLNM"))_$S($L($G(C("KLNM")))&$L($G(C("GEMEENTE"))):" - ",1:"")_$G(C("GEMEENTE")),""""
LNV8 ;"A0,345,0,4,1,1,N,""",$G(C("ORDREF")),""""
LNV9 ;"A0,390,0,4,1,1,N,""",$G(C("BONNR")),""""
LNV10 ;"P1"
 ; Label definitie FRANS (print)
LF1 ;""
LF2 ;"ZB"
LF3 ;"N"
LF4 ;"R100,60"
LF5 ;"A0,0,0,5,1,1,N,""",$G(C("KORTTXT")),""""
LF6 ;"A435,22,0,3,2,2,N,""",$G(C("COUNT")),""""
LF7 ;"A0,140,0,4,1,1,N,""",$G(C("LANGTXT1")),""""
LF8 ;"A0,185,0,4,1,1,N,""",$G(C("LANGTXT2")),""""
LF9 ;"A0,230,0,4,1,1,N,""",$G(C("LANGTXT3")),""""
LF10 ;"A0,300,0,4,1,1,N,""","Ref:",""""
LF11 ;"A95,300,0,4,1,1,N,""",$G(C("ORGLREF")),""""
LF12 ;"A95,360,0,4,1,1,N,""",$G(C("KLNM"))_$S($L($G(C("KLNM")))&$L($G(C("GEMEENTE"))):" - ",1:"")_$G(C("GEMEENTE")),""""
LF13 ;"A95,405,0,4,1,1,N,""",$G(C("BONNR"))_$S($L($G(C("BONNR")))&$L($G(C("ORDREF"))):" - ",1:"")_$G(C("ORDREF")),""""
LF14 ;"P1"
 ; Label definitie FRANS Verpakking (print)
LFV1 ;""
LFV2 ;"ZB"
LFV3 ;"N"
LFV4 ;"R100,60"
LFV5 ;"A0,0,0,4,2,2,N,""",$G(C("AANTOVVP")),""""
LFV6 ;"A0,150,0,4,2,2,N,""",$G(C("ORGLREF")),""""
LFV7 ;"A0,300,0,4,1,1,N,""",$G(C("KLNM"))_$S($L($G(C("KLNM")))&$L($G(C("GEMEENTE"))):" - ",1:"")_$G(C("GEMEENTE")),""""
LFV8 ;"A0,345,0,4,1,1,N,""",$G(C("ORDREF")),""""
LFV9 ;"A0,390,0,4,1,1,N,""",$G(C("BONNR")),""""
LFV10 ;"P1"
 ; Label definitie DUITS (print)
LD1 ;""
LD2 ;"ZB"
LD3 ;"N"
LD4 ;"R20,60"
LD5 ;"A0,0,0,5,1,1,N,""",$G(C("KORTTXT")),""""
LD6 ;"A435,22,0,3,2,2,N,""",$G(C("COUNT")),""""
LD7 ;"A0,120,0,3,1,1,N,""",$G(C("LANGTXT1")),""""
LD8 ;"A0,165,0,3,1,1,N,""",$G(C("LANGTXT2")),""""
LD9 ;"A0,210,0,3,1,1,N,""",$G(C("LANGTXT3")),""""
LD10 ;"A0,305,0,3,1,1,N,""","Ref:",""""
LD11 ;"A85,300,0,4,1,1,N,""",$G(C("ORGLREF")),""""
LD12 ;"A85,360,0,3,1,1,N,""",$G(C("KLNM"))_$S($L($G(C("KLNM")))&$L($G(C("GEMEENTE"))):" - ",1:"")_$G(C("GEMEENTE")),""""
LD13 ;"A85,405,0,3,1,1,N,""",$G(C("BONNR"))_$S($L($G(C("BONNR")))&$L($G(C("ORDREF"))):" - ",1:"")_$G(C("ORDREF")),""""
LD14 ;"P1"
 ; Label definitie DUITS Verpakking (print)
LDV1 ;""
LDV2 ;"ZB"
LDV3 ;"N"
LDV4 ;"R20,60"
LDV5 ;"A0,0,0,4,2,2,N,""",$G(C("AANTOVVP")),""""
LDV6 ;"A0,150,0,4,2,2,N,""",$G(C("ORGLREF")),""""
LDV7 ;"A0,300,0,4,1,1,N,""",$G(C("KLNM"))_$S($L($G(C("KLNM")))&$L($G(C("GEMEENTE"))):" - ",1:"")_$G(C("GEMEENTE")),""""
LDV8 ;"A0,345,0,4,1,1,N,""",$G(C("ORDREF")),""""
LDV9 ;"A0,390,0,4,1,1,N,""",$G(C("BONNR")),""""
LDV10 ;"P1"
 ; Label definitie NEDERLANDS (transfert)
LNT1 ;$G(C("KORTTXT"))
LNT2 ;$G(C("COUNT"))
LNT3 ;$G(C("LANGTXT1"))
LNT4 ;$G(C("LANGTXT2"))
LNT5 ;$G(C("LANGTXT3"))
LNT6 ;"Ref:"
LNT7 ;$G(C("ORGLREF"))
LNT8 ;$G(C("KLNM"))_$S($L($G(C("KLNM")))&$L($G(C("GEMEENTE"))):" - ",1:"")_$G(C("GEMEENTE"))
LNT9 ;$G(C("BONNR"))
LNT10 ;$G(C("ORDREF"))
 ; Label definitie NEDERLANDS Verpakking (transfert)
LNTV1 ;""
LNTV2 ;""
LNTV3 ;""
LNTV4 ;""
LNTV5 ;""
LNTV6 ;""
LNTV7 ;$G(C("ORGLREF"))
LNTV8 ;$G(C("KLNM"))_$S($L($G(C("KLNM")))&$L($G(C("GEMEENTE"))):" - ",1:"")_$G(C("GEMEENTE"))
LNTV9 ;$G(C("BONNR"))
LNTV10 ;$G(C("ORDREF"))
 ; Label definitie FRANS (transfert)
LFT1 ;$G(C("KORTTXT"))
LFT2 ;$G(C("COUNT"))
LFT3 ;$G(C("LANGTXT1"))
LFT4 ;$G(C("LANGTXT2"))
LFT5 ;$G(C("LANGTXT3"))
LFT6 ;"Ref:"
LFT7 ;$G(C("ORGLREF"))
LFT8 ;$G(C("KLNM"))_$S($L($G(C("KLNM")))&$L($G(C("GEMEENTE"))):" - ",1:"")_$G(C("GEMEENTE"))
LFT9 ;$G(C("BONNR"))
LFT10 ;$G(C("ORDREF"))
 ; Label definitie FRANS Verpakking (transfert)
LFTV1 ;""
LFTV2 ;""
LFTV3 ;""
LFTV4 ;""
LFTV5 ;""
LFTV6 ;""
LFTV7 ;$G(C("ORGLREF"))
LFTV8 ;$G(C("KLNM"))_$S($L($G(C("KLNM")))&$L($G(C("GEMEENTE"))):" - ",1:"")_$G(C("GEMEENTE"))
LFTV9 ;$G(C("BONNR"))
LFTV10 ;$G(C("ORDREF"))
 ; Label definitie DUITS (transfert)
LDT1 ;$G(C("KORTTXT"))
LDT2 ;$G(C("COUNT"))
LDT3 ;$G(C("LANGTXT1"))
LDT4 ;$G(C("LANGTXT2"))
LDT5 ;$G(C("LANGTXT3"))
LDT6 ;"Ref:"
LDT7 ;$G(C("ORGLREF"))
LDT8 ;$G(C("KLNM"))_$S($L($G(C("KLNM")))&$L($G(C("GEMEENTE"))):" - ",1:"")_$G(C("GEMEENTE"))
LDT9 ;$G(C("BONNR"))
LDT10 ;$G(C("ORDREF"))
 ; Label definitie DUITS Verpakking (transfert)
LDTV1 ;""
LDTV2 ;""
LDTV3 ;""
LDTV4 ;""
LDTV5 ;""
LDTV6 ;""
LDTV7 ;$G(C("ORGLREF"))
LDTV8 ;$G(C("KLNM"))_$S($L($G(C("KLNM")))&$L($G(C("GEMEENTE"))):" - ",1:"")_$G(C("GEMEENTE"))
LDTV9 ;$G(C("BONNR"))
LDTV10 ;$G(C("ORDREF"))