#include vhLib.Macro
Contract ;CONTRACT-ORDERLIJNEN;
  
 ; Verzenden van een mail indien bepaalde contractlijnen volledig opgenomen zijn
SendMiniMail(KLNr,EmptyContract)
 New J,R,From,To,ccTo,Subject,Body,Opties,ORDNr,OLNr,ContrRef,PRNr,Korttekst,KlantRef,Prijs,HuidPrijs,KlNaam,KlAanspr,KlAdres,KlPostCode,KlWoonpl,IsStock,LevTem,MinBestH,Taal
 Try {
	 Set From=$$USERNAME^vhUSER(,"@") Set:From="" From="Info@VanHoecke.be"
	 Set Opties("CONNECT")="E", Opties("FILTER")=1,Opties("NOPOP")=1,Opties("PIECE")=6,Opties("VWBEPERK")="AK2" ; Aankoopverantwoordelijke
	 Set To=$$SELECT^PERSS("K",KLNr,.Opties)
	 Set:To="" Opties("VWBEPERK")="AB1",To=$$SELECT^PERSS("K",KLNr,.Opties) ; Algemeen beheerder indien geen AK2
	 Set:To="" To=$p(^KKL(^KK1(KLNr),2),D,19) ; Algemeen E-mail adres indien geen AK2 en geen AB1
	 Set ccTo="OV_ContractOrders@vanhoecke.be"
	 Set:To="" To=ccTo,ccTo=""  Set:From="" From="Info@VanHoecke.be"
 }
 Catch {
	 Set Exception = ##class(TECH.ExceptionHandler).Catch()
	 Do ##class(vhLib.Logger).LogEnMailExceptie(Exception," - mail ivm. contract (to="_$G(To)_", ccTo="_$G(ccTo)_")")
	 Set To=$$$SystemMail("Admin_Error")
	 Set ccTo=""
 }	 
 Set Taal=$P(^KKL(^KK1(KLNr),0),D,9) Set:Taal="" Taal="N"
 Set Subject=$$TXT("Afname"),(Body,ORDNr)=""
 For  Set ORDNr=$O(EmptyContract(ORDNr)) Quit:ORDNr=""  Do
 . Set ContrRef=EmptyContract(ORDNr),Body=Body_$C(13)_$$TXT("Contr")_": "_ORDNr_" - "_ContrRef,OLNr=""
 . For  Set OLNr=$O(EmptyContract(ORDNr,OLNr)) Quit:OLNr=""  Do
 . . Set R=EmptyContract(ORDNr,OLNr),PRNr=$P(R,D,2),KortTekst=$P(^KPR(PRNr,0),D),KlantRef=$$DISP^PAKKET(KLNr,PRNr,,,"CE")
 . . Set Prijs=$$EXTNUM^vhLib.DataTypes($P(R,D,6),0,".",2)_$S($E($P(R,D,21))="H":"%",1:"")_" "_$P(R,D,22)
 . . Set Body=Body_$C(13)_$C(13)_KortTekst
 . . Set:$L(KlantRef) Body=Body_$C(13)_$$TXT("UwRef")_": "_KlantRef
 . . Set Body=Body_$C(13)_$$TXT("Prijs")_": "_Prijs
 . . Set R=$$KLANTPR^KPRIJS(KLNr,PRNr),HuidPrijs=$$EXTNUM^vhLib.DataTypes($P(R,D),0,".",2)_$S($E($P(R,D,10))="H":"%",1:"")_" "_$P(R,D,2)
 . . Set:Prijs'=HuidPrijs Body=Body_" - "_$$TXT("NPrijs")_": "_HuidPrijs
 . . Set AndereContr=$$AndereContr(KLNr,PRNr)
 . . If 'AndereContr Do
 . . . Set R=^KPR(PRNr,1),IsStock=$P(R,D,20)
 . . . Set J=$O(^KPR(PRNr,"J"))
 . . . If $E(J)="J" Set R=^KPR(PRNr,J),MinBestH=$P(R,D,6),LevTerm=$P(R,D,7)+1
 . . . Set Body=Body_$C(13)_$$TXT("GeenContr")
 . . . Set Body=Body_$C(13)_$$TXT("LevTerm")_": "_$S(IsStock:$$TXT("Stock"),1:LevTerm_$$TXT("Week",LevTerm'=1+2))
 . . . Set:MinBestH Body=Body_$C(13)_$$TXT("MinBestH")_": "_$$EXTNUM^vhLib.DataTypes(MinBestH,0,".",0)_$$TXT("Stuk",MinBestH'=1+2)
 . . Else  Set Body=Body_$C(13)_$$TXT("AndereContr")_": "_$$EXTNUM^vhLib.DataTypes(AndereContr,0,".",0)_$$TXT("Stuk",AndereContr'=1+2)
 Set $E(Body)=""
 Set Body=$$TXT($S($L(Body,$C(13)_$C(13))>2:"LijnenOp",1:"LijnOp"))_":"_$C(13)_$C(13)_Body
 Set R=^KKL(^KK1(KLNr),0),KlNaam=$P(R,D,2),KlAanspr=$P(R,D,4),KlAdres=$P(R,D,5),KlPostCode=$P(R,D,6),KlWoonpl=$P(R,D,7)
 Set Body=$S($L(KlAanspr):KlAanspr_" ",1:"")_KlNaam_$C(13)_KlAdres_$C(13)_KlPostCode_"   "_KlWoonpl_$C(13)_$C(13)_Body
 Set Body=Body_$C(13)_$C(13)_$$TXT("MVrGr")_$S(From["Info":"",1:$C(13)_$C(13)_$$USERNAME^vhUSER(,1))
 Set Body=Body_$C(13)_$C(13)_"VAN HOECKE nv - "_$$TXT("Expert")_$C(13)_"Europark Noord, 9"_$C(13)_"B-9100 Sint-Niklaas"
 Set Body=Body_$C(13)_"Tel.: 0032-(0)3/760 19 00"_$C(13)_"Fax.: 0032-(0)3/760 19 19"
 Set Body=Body_$C(13)_"http://www.vanhoecke.be"_$C(13)_"http://www.orgalux.be"
 Set:$L(ccTo) To=ccTo,ccTo="" ; Mail enkel naar CDV verzenden (aangepast op 30 mei 2007 CW)
 Do SendMiniMail^vhLib(From,$$PiecesToList^vhLib(To,";"),Subject,Body,,,,,,,$LB(ccTo))
 Quit
 
 ; Zijn er nog restanten in andere contracten?
AndereContr(KLNr,PRNr)
 New AndereContr,WIndex,ORDNr,OLNr
 Set AndereContr="",WIndex="W"
 For  Set WIndex=$O(^KPR(PRNr,WIndex)) Quit:$E(WIndex)'="W"  Do:$E(WIndex,9)="R"
 . Set ORDNr=$E(WIndex,18,23),OLNr=100+$TR($E(WIndex,24,26)," ","")
 . Quit:$P($G(^KO1(ORDNr,"F")),D)'=KLNr
 . Set R=$G(^KOD(KLNr,"F",ORDNr,1))
 . Quit:$P(R,D,25)'="C"
 . Set R=$G(^KOD(KLNr,"F",ORDNr,OLNr)),AndereContr=AndereContr+$P(R,D,3)
 Quit AndereContr
 
 ; Ophalen taalafhankelijke tekst
TXT(Ref,Piece) 
 If '$D(Piece) Set Piece=2
 Quit $P($P($T(@("T"_Ref)),U,Piece),D,$F("NFDE",Taal)-1)
 
TAfname ;Afname contractorders\Diminution du contrat\Afname contractorders\Afname contractorders
TContr ;Contract\Contrat\Contract\Contract
TUwRef ;Uw ref\Votre réf\Uw ref\Uw ref
TPrijs ;Prijs\Prix\Prijs\Prijs
TNPrijs ;Nieuwe prijs\Nouveaux prix\Nieuwe prijs\Nieuwe prijs
TGeenContr ;Geen stuks meer voorradig\Rien en stock\Geen stuks meer voorradig\Geen stuks meer voorradig
TLevTerm ;Levertermijn\Délai de livraison\Levertermijn\Levertermijn
TMinBestH ;Min. bestelhoeveelheid\Quantité de commande minimale\Min. bestelhoeveelheid\Min. bestelhoeveelheid
TAndereContr ;Aantal in andere contracten\Quantité dans autres contrats\Aantal in andere contracten\Aantal in andere contracten
TWeek ; week\ semaine\ week\ week; weken\ semaines\ weken\ weken
TStock ;Stock\Stock\Stock\Stock
TStuk ; stuk\ pièce\ stuk\ stuk; stuks\ pièces\ stuks\ stuks
TLijnOp ;Volgende contractlijn is volledig afgenomen\La position suivante du contrat a été prise dans sa totalité\Volgende contractlijn is volledig afgenomen\Volgende contractlijn is volledig afgenomen
TLijnenOp ;Volgende contractlijnen zijn volledig afgenomen\Les positions suivantes du contrat ont été prise dans leurs totalité\Volgende contractlijnen zijn volledig afgenomen\Volgende contractlijnen zijn volledig afgenomen
TMVrGr ;Met vriendelijke groeten,\Meilleurs salutations,\Met vriendelijke groeten,\Met vriendelijke groeten,
TExpert ;expert in functioneel meubelbeslag\expert en quincaillerie fonctionnelle pour meubles\expert in functioneel meubelbeslag\expert in functioneel meubelbeslag