IUPD ;Update naar Vx.xx ;IUPD [ 12/06/2000  10:09 AM ]
 ; enkel maar vanaf 7.11 en hoger
 ;
 ; niet te kopieren
TNC1 ;BA;DAMBA;DATA;DIN;DLOG;DPAR;DMA("NS";DMC("NS";DMM("NS";DMH("NS";
TNC2 ;EABA;EABEST1;EACNTRL;EAFORM1;EAELA*;EAINTR("%F",1;EAINTR(1-99999999;EAINTR("%P";EAKH;EAKORT;EAKOT;EAL1;EAPEL;EAPS;EAPW*;EAR1;EAUI*;EAWE;
TNC3 ;EAMEMO;EAPR(0,19;ERROR;
TNC4 ;HULP*;I*;MAIL;MUNT;UTILI*;a-zz;
 ;
 ;enkel nul-nodes : (1-"z" wordt toegevoegd via prog
TNUL1 ;EAAFS;EAAK;EAAR;EAARA;EABEST;EAFORM;EAKL;EALE;EANP;EAOD;EAPR;EAPV;EARF;EASTKL;EASTLE;EATB;EATO;EATOL;EAUL;EAUT;EAVT;
 ;
 ;
YZ Q
 ;
COPY ; kopiëren ^x
 w !,"kopiëren ^x ..."
 s ge="x" i $zv'["MSM" s ge="^x"
 f  s ge=$$NEXT(ge) q:ge=""  d
 . s oge=ge i $zv'["MSM" s oge=$p(ge,"^",2,99)
 . s nge="^"_$e(oge,2,99)
 . ; indien Q_BA
COPYA . i $l(oge)>3,$e(oge,$l(oge)-1,$l(oge))="BA" d  q
 .. W !,nge
 .. i $e(oge)'="^" s k="^"_oge
 .. f  s k=$zo(@k) q:k=""  d
 ... s a=@k,b=k,$p(b,"(")=nge
 ... w "."
 ... ; menu
 ... i $qs(k,1)="MENU" d  q
 .... i $D(@b) s $p(@b,D,1,6)=$p(a,D,1,6),$P(@b,D,11)=$p(a,D,11) q
 .... s @b=a
 ... s @b=a
COPYB . i $l(oge)>3,"\UL\OD\TO\TB\PV\"[(D_$e(oge,$l(oge)-1,$l(oge))_D)!("\TOL\"[(D_$e(oge,$l(oge)-2,$l(oge))_D)) d  q
 .. W !,nge
 .. i $e(oge)'="^" s k="^"_oge
 .. f  s k=$zo(@k) q:k=""  d
 ... s a=@k,b=k,$p(b,"(")=nge,l=$qs(k,3)
 ... w "."
 ... i '$d(@b) s @b=a q
 ... I $qs(k,0)["PV",l="UDFA" s $p(@b,D)=$p(a,D)
 ... i "\LNT\ULNT\UDUO\UVD\UTO\"[(D_l_D) q
 ... i l="UDET" s $p(@b,D,2)=$p(a,D,2),$p(@b,D,4)=$p(a,D,4) q
 ... i l="UR" S $p(@b,D,2)=$p(a,D,2) q
 ... s @b=a
COPYC . i $l(oge)>3,$E(oge,2,4)="DMS" d  q
 .. W !,nge
 .. i $e(oge)'="^" s k="^"_oge
 .. f  s k=$zo(@k) q:k=""  d
 ... s a=@k,b=k,$p(b,"(")=nge
 ... w "."
 ... i $L($qs(k,3)),$e($qs(k,3),1,2)="DM" q  ; geen nodes "DMA", "DMM", ...
 ... I '$d(@b) s @b=a q
 ... I $qs(k,3)=0 s $p(a,D,40)=D,@b=$p(a,D,1,28)_D_$p(@b,D,29,31) q
 ... m @b=a
 . m @nge=@("^"_oge) W !,nge
COPYZ Q
 ;
DEL ; verwijderen ^x
 w !!,"Verwijderen ^x..."
 s ge="x" i $zv'["MSM" s ge="^x"
 f  s ge=$$NEXT(ge) q:'$l(ge)  d
 . s oge=ge i $zv'["MSM" s oge=$p(ge,"^",2,99)
 . K @("^"_oge) w "."
DELZ Q
 ;
IS(OVV,VV) ;      OVV = oude versie (V7.xx), VV = nieuwe versie (Vx.xx)
 ;      zie ook ^cLOG(,"VERS","%A" van bij klant
 ;      versie mag niet lager zijn dan 7.10
 i $g(VV)'?1"V"1.N.1".".3N w !!,"Geen geldige versie : ",VV G ISZ
 i $g(OVV)'?1"V"1.N.1".".3N w !!,"Geen geldige versie : ",OVV G ISZ
 i $$VERS(VV)<7000 w !!,"Versie mag niet lager zijn dan V7.00" G SAVEZ
 i $ZV["MSM" I $ZU(5)["MGR" d ^cQSW   ; terug naar TST
 w !,$ZU(5)
 d
 . N VV,OVV
 . d ^cA604,^cA105,^cA106 s QU="DAM"
ISA s vv=$p($g(^cLOG(0,"VERS","%A"),$g(^cLOG("VERS","%A"),"?")),D)
 w !!,"Van : ",vv
 w !,"Naar: ",VV,!
 i vv'=OVV w !,"De vorige versie klopt niet!",! g ISZ
 w !!,"Start <N>" r k s k=$tr(k,"JjYy1","11110") i k'=1 g ISZ
 ;
ISB S $P(^cLOG(0,"VERS","%A"),D,2)=VV
 d DEL   ; verwijderen ^x
 s (hvv,nvv)=$$VERS(OVV),evv=$$VERS(VV)
 s qq=^cLOG(boot,"Q",$ZU(5))
 f  s nvv=$o(^upd(nvv)) q:nvv>evv!'$l(nvv)  d
 . w !!,nvv
 . w !,"Inlezen files ..."
 . s upd="^upd" I $D(^upds(nvv)) s upd="^upds"
 . k updb m updb=@upd@(nvv)
 . s vnr=""
 . f  s vnr=$o(updb("TST",vnr)) q:vnr=""  d   ; inlezen files TST
 .. s a=updb("TST",vnr)
 .. w !!,"Kies nu het bestand: ",@F92,$p(a,D),@F93,!
 .. d @("^"_$p(a,D,2))
 . I $ZV["MSM" d ^cQSW  ; over naar MGR
 . s vnr=""
 . f  s vnr=$o(updb("MGR",vnr)) q:vnr=""  d   ; inlezen files MGR
 .. s a=updb("MGR",vnr)
 .. w !!,"Kies nu het bestand: ",@F92,$p(a,D),@F93,!
 .. d @("^"_$p(a,D,2))
 . I $ZV["MSM" d ^cQSW  ; terug naar TST
 . w !!,"Voor ..."
 . i $l($g(updb(0))) x updb(0)   ; Xecute voor
 . ; copieren ^x naar ^Q...
 . d COPY
 . w !!,"Na ..."
 . f i=1:1:$l(qq,D) s q=$p(qq,D,i) i $l(q) 
 .. n Q s Q=q
 .. d S1^cAN002("DAM","DMS")   ; indexen ^DMS
 . i $l($g(updb(1))) x updb(1)   ; Xecute achteraf
 . d DEL  ; verwijderen ^x
 S $P(^cLOG(0,"VERS","%A"),D)=VV
ISZ Q
 ;
NEXT(ge) ; ophalen volgend bestand
 I $ZV'["MSM" s ge=$o(^$GLOBAL(ge)) i $e(ge,2)'="x" s ge=""
 I $ZV["MSM" s ge=$o(@("^"_ge)) i $e(ge)'="x" s ge=""
 Q ge
 ;
 ;
 ;  opzetten van ^x...
SAVE(VV)       ; versie vanaf waar moet upgedate worden, moet doorgegeven worden
 ;           zie ^cLOG(,"VERS","%A" van bij klant
 ;      versie mag niet lager zijn dan 7.00
 D
 . N VV
 . D ^cA604,^cA105,^cA106 s QU="DAM"
 i $g(VV)'?1"V"1.2N1"."1.3N w !!,"Geen geldige versie : ",VV G SAVEZ
 i $$VERS(VV)<7000 w !!,"Versie mag niet lager zijn dan V7.00" G SAVEZ
 w !!,"Van  : ",VV
 w !,"Naar : ",$p(^cLOG(0,"VERS","%A"),D),!
 w !!,"Start <N>" r k s k=$tr(k,"JjYy1","11110") i k'=1 g SAVEZ
 ;
SAVEA ; Opbouw hulp met niet te kopiëren onderdelen
 K ^HULP(boot,$J)
 ; niet te kopieren
 f i=1:1 S a=$p($T(@("TNC"_i)),U,2,999) q:'$l(a)  d TNC^IUPD01(a)
 ; enkel nulnodes
 f i=1:1 S a=$p($T(@("TNUL"_i)),U,2,999) q:'$l(a)  d
 . F j=1:1:$l(a,U) S k=$p(a,U,j) i $l(k) s k=k_"(1-""z""",$p(a,U,j)=k
 . d TNC^IUPD01(a)
 ;
SAVEB d DEL
 ;
SAVEC W !!,"Kopiëren bestanden"
 s ge=""
 f  s ge=$o(@("^"_ge)) q:$e(ge)="x"  d
 . i $d(^HULP(boot,$J,ge)) k ^HULP(boot,$J,ge) W !,ge," -> niet" q
 . s nge="x"_ge
 . w !,nge m @("^"_nge)=@("^"_ge)
 ;
SAVED W !!,"Opkuis globals"
 s ge="",vge=""
 f  s ge=$o(^HULP(boot,$J,ge)) q:ge=""  d
 . i vge'=$qs(ge,0) s vge=$qs(ge,0) w !,vge
 . s nge="^x"_ge k @nge w "."
 K ^HULP(boot,$j)
 ;
SAVEE W !!,"set van nodes vanaf versie ..."
 s vv=$$VERS(VV)
 f  s vv=$o(^upd(vv)) q:vv=""  d
 . W !!,vv
 . s vnr=""
 . f  s vnr=$o(^upd(vv,"U",vnr)) q:vnr=""  d
 .. s ge=^(vnr)
 .. s nge="^x"_ge I $e(ge)="%" s nge="^mgr"_$e(ge,2,$l(ge))
 .. I $d(@("^"_ge)) m @nge=@("^"_ge) w !,ge
 ;
SAVEF W !!,"Nu kan je eventueel nog specifieke aanpassingen doen",!,"en een global-save doen van ^x*",!!
 ;
SAVEZ Q
 ;
VERS(R) Q $E($TR(R,"V.")*100,1,4)
 ;
ZZ ; 30.06.00 - 15 u 23 * V7.4