KKOVEXP ; Export hoofgroep van potentieel analyse
#include vhLib.Macro
#define VerdelerVH 8005

Export
	Set Dev=$$OPEN^vhDEV(,"ExportPotentieel.txt","W","T")
	Use Dev
	Write "GeneratieID	KlantId	Codex	ProdGrp	Aantal	Omzet",!
	Set GenerationID=$zdt($H,-2)
	Set KLNr=0
	For  Set KLNr=$O(^KKOV(KLNr)) Quit:KLNr=""  Do
	. Do ExportKlant(KLNr)
	Do CLOSE^vhDEV(Dev)
	Quit
	
ExportKlant(KLNr)
	Set HG=99
	For  Set HG=$O(^KKOV(KLNr,HG)) Quit:HG=""  Do
	. Set GrpProd=$$TranslateHG(HG)
	. Quit:GrpProd=""
	. Set GrpRec=$$Groepeer(KLNr,HG)
	. Quit:$P(GrpRec,"\",3)<1 ; geen potentieel bij VH
	. Set Codex=$P(^KKL(^KK1(KLNr),2),"\",3)
	. Write GenerationID,*9,KLNr, *9, $$VertaalCodex(Codex),*9, GrpProd
	. Write *9, $$$ExcelNum($P(GrpRec,"\",3)), *9, $$$ExcelNum($P(GrpRec,"\",16))
	. Write !
	Quit
	
Groepeer(KLNr,HG)
	Set (Verd,Fabr,Kov)="",GR=0
	Set GrpRec=""
	For  Set GR=$O(^KKOV(KLNr,HG,GR)) Quit:GR=""  Do
	. For  Set Verd=$O(^KKOV(KLNr,HG,GR,Verd)) Quit:Verd=""  Do
	. . Quit:Verd'=$$$VerdelerVH ; alleen die via VH worden verkocht
	. . For  Set Fabr=$O(^KKOV(KLNr,HG,GR,Verd,Fabr)) Quit:Fabr=""  Do
	. . . Set Rec=^KKOV(KLNr,HG,GR,Verd,Fabr)
	. . . For I=3,12,16 Set $P(GrpRec,"\",I)=$P(GrpRec,"\",I)+$P(Rec,"\",I)
 	Quit GrpRec
 	
VertaalCodex(Codex)
	;Quit:Codex="C" "Cons"
	;Quit:Codex="P" "Prijslijst"
	;Quit:Codex="L" "Lijst"
	;Quit:Codex="R" "Rabat"
	;Quit:Codex="S" "Spil"
	;Quit:Codex="B" "Basis"
	;Quit:Codex="G" "Groot"
	Quit Codex
	
TranslateHG(HG)
	Quit:$E(HG,3,4)="CH" "Scharnier"
	Quit:$E(HG,3,4)="KB" "Klep"
	Quit:$E(HG,3,4)="GL" "Glijder"
	Quit:$E(HG,3,4)="BX" "Lade los"
	Quit:$E(HG,3,4)="LA" "Lade mont"
	Quit ""