KLANTT5 ;Klanten [ 03/07/2003  9:10 AM ]
 ;
EditKwalitatief
 New I,R,zb,Kwalitatief,Activiteit,Titel
 Set Kwalitatief=$P($G(B(4)),D,10),Activiteit=$P($G(B(2)),D,11) ;Set:Kwalitatief="" Kwalitatief="X"
 Set K="-"
 Do:$L(Activiteit)
 . Set R=$G(^RES("KLANT","PI","ACTIVITEIT","D",Activiteit))
 . If $TR($P(R,"`",3,6),"`","")="" Set K="" Quit
 . Set Titel=$P(R,"`",2)
 . For I=1:1:4 If $L($P(R,"`",I+2)) Set Kwalitatief(I)=I_"`"_$TR($P(R,"`",I+2),";",",")
 . Set K=$$WILD^vhPOPUP("C;C","-ZDOK1","Kwalitatief ("_Activiteit_")",.Kwalitatief,Kwalitatief)
 . Set:zb="CANC" K="-"
 Set Locals("K")=K
 Quit
 ;
EditKwantitatief
 New zb,Kwantitatief
 Set Kwantitatief=$P($G(B(4)),D,11) Set:Kwantitatief="" Kwantitatief="X"
 Set K=$$PI^vhPOPUP("C;C","-ZDOK1","Kwantitatief","KLANT","KWANTITATIEF",Kwantitatief)
 Set:zb="CANC" K="-"
 Set Locals("K")=K
 Quit
 ;
EditActiviteit
 New zb,Activiteit
 Set Activiteit=$P($G(B(2)),D,11)
 Set K=$$PI^vhPOPUP("C;C","-DOKZ1","Activiteit","KLANT","ACTIVITEIT",Activiteit)
 Set:zb="CANC" K="-"
 Set Locals("K")=K
 Quit
 ;
DisplayKwalitatief(KLNr)
 New R,Kwalitatief,Activiteit,KwalitatiefVertaald
 Set R=^KKL(^KK1(KLNr),1),Activiteit=$P(R,D,11)
 Set R=^KKL(^KK1(KLNr),3),Kwalitatief=$P(R,D,10)
 If Kwalitatief,$L(Activiteit) Set KwalitatiefVertaald=$P($G(^RES("KLANT","PI","ACTIVITEIT","D",Activiteit)),"`",Kwalitatief+2)
 Quit $LB(Kwalitatief,$G(KwalitatiefVertaald))
 ;
DisplayKwantitatief(KLNr)
 New R,Kwantitatief,KwantitatiefVertaald
 Set R=^KKL(^KK1(KLNr),3),Kwantitatief=$P(R,D,11)
 Set:$L(Kwantitatief) KwantitatiefVertaald=$P($G(^RES("KLANT","PI","KWANTITATIEF","D",Kwantitatief)),"`",2)
 Quit $LB(Kwantitatief,$G(KwantitatiefVertaald))
 ;
DisplayActiviteit(KLNr)
 Quit $LB($$GetActiviteit(KLNr))
 ;
GetKwalitatief(KLNr)
 Quit $P(^KKL(^KK1(KLNr),3),D,10)
 ;
GetKwantitatief(KLNr)
 Quit $P(^KKL(^KK1(KLNr),3),D,11)
 ;
GetActiviteit(KLNr)
 Quit $P(^KKL(^KK1(KLNr),1),D,11)
 ;
GetKlantType(KLNr)
 Quit $P(^KKL(^KK1(KLNr),1),"\",25)
 ;
IsHandelInclPassief(KLNr)
 Quit ($$UPCASE^vhRtn1($$GetActiviteit(KLNr))="HANDEL")
 
IsHandel(KLNr)
 ;Quit $$GetKlantType(KLNr)>0  ; De oude versie  ; Afgesloten op 17.01.10 (CW)
 Quit ($$UPCASE^vhRtn1($$GetActiviteit(KLNr))="HANDEL") && ($$GetKwalitatief(KLNr)?1(1"1",1"2"))
 ;
IsPreferenteHandel(KLNr)
 Quit ($$UPCASE^vhRtn1($$GetActiviteit(KLNr))="HANDEL") && ($$GetKwalitatief(KLNr)?1(1"1"))
 
IsMedewerker(KLNr)
 Quit ($$UPCASE^vhRtn1($$GetActiviteit(KLNr))="CONSUMENT") && ($$GetKwalitatief(KLNr)?1(1"3"))