KLLABEL ;Afdruk adresetiket voor Klant en leverancier;[ 09/01/2003  2:18 PM ]
 Do INIT^vhTERMINA
 ;Do KLANT($$SELECT^KLANT6())
 Do KLANT(11708,2)
 Quit
 
KLANT(KLNr,LevAdrNr)  ; Adres of leveringsadres van klant
 New KLId,Adres,C
 Quit:KLNr=""
 Set KLId=^KK1(KLNr)
 Quit:KLId=""
 Set:$G(LevAdrNr)?1.2N Adres=$G(^KKL(KLId,"L "_$J(LevAdrNr,2)))
 Set:'$L($G(Adres)) Adres=^KKL(KLId,0)
 Do SPLIT(.C,Adres)
 Do CONVADR(.C)
 Do PRINT(.C)
 Quit
 
LEV(LEVNr) ; Adres van leverancier
 New LEVId,Adres,C
 Quit:LEVNr=""
 Set LEVId=^KL1(LEVNr)
 Set Adres=^KLE(LEVId,0)
 Do SPLIT(.C,Adres)
 Do CONVADR(.C)
 Do PRINT(.C)
 Quit
 
EWMS(CONSNr)  ; Leveringsadres van consolidatie 
 New KLNr,Adres,C
 Set KLNr=$P($G(^ORDW("D",CONSNr)),D)
 Quit:KLNr=""
 Set Adres=$G(^ORDW("D",CONSNr,"A"))
 If $L($TR(Adres,D,""))<5 Do KLANT(KLNr) Quit
 Do SPLIT(.C,Adres)
 Do CONVADR(.C)
 Do PRINT(.C)
 Quit
 
BON(BONNr)  ; Leveringsadres van levering
 New KLNr,Adres,C
 Set KLNr=$P($G(^KU1(BONNr,"F")),D)
 Quit:KLNr=""
 Set Adres=$G(^KUL(KLNr,"F",BONNr,3))
 If $L($TR(Adres,D,""))<5 Do KLANT(KLNr) Quit
 Do SPLIT(.C,Adres)
 Do CONVADR(.C)
 Do PRINT(.C)
 Quit
 
CONVADR(C)  ; C via .Local doorgeven
 Set C=1,C(C)=C("NAAM")_$S($L($G(C("AANSPREKING"))):" "_C("AANSPREKING"),1:"")
 Set:$L($G(C("TOENAAM"))) C=C+1,C(C)=C("TOENAAM")
 Set:$L($G(C("TAV"))) C=C+1,C(C)=C("TAV")
 Set C=C+1,C(C)=C("STRAAT")
 Set C=C+1,C(C)=C("POSTNR")_" "_C("WOONPLAATS")
 Set:C("LAND")'="BELGIE"&$L($G(C("LAND"))) C=C+1,C(C)=C("LAND")
 Quit
 
SPLIT(C,Adres) ; C via .Local doorgeven
 Set C("NAAM")=$P(Adres,D,2)
 Set C("TOENAAM")=$P(Adres,D,3)
 Set C("AANSPREKING")=$P(Adres,D,4)
 Set C("STRAAT")=$P(Adres,D,5)
 Set C("POSTNR")=$P(Adres,D,6)
 Set C("WOONPLAATS")=$P(Adres,D,7)
 Set C("LAND")=$$LAND^vhRtn1($P(Adres,D,8),2)
 Quit
 
PRINT(C) ; C via .Local doorgeven
 Do STORE^vhTERMINA()
 Set FP=1201 Write @F,@F1
 Set FP=1301 Write @F,"    Lijn 1 : ",C(1)
 Set FP=1401 Write @F,"         2 : ",$G(C(2))
 Set FP=1501 Write @F,"         3 : ",$G(C(3))
 Set FP=1601 Write @F,"         4 : ",$G(C(4))
 Set FP=1701 Write @F,"         5 : ",$G(C(5))
 Set FP=1801 Write @F,"         6 : ",$G(C(6))
 Set FP=2204 Write @F,"  Type :"
 Set FP=2215 Write @F,"KLANT"
 Set FP=2007 Write @F,"PRINT\LABEL\ADRES"
 ; Start Applicatie
 Set FP=2001 Write @F,"VBA:\\"
 ; Terugkeer van VBA
 Read ENTER
 Do REFRESH^vhTERMINA()
 Quit