KLPOT ; Potentieel 
 Quit
 ;
 
 ; Geeft de fabrikant met het grootste aantal voor een bepaalde hoofdgroep
PotLev(KLNr,HoofdGr)
 New D,R,PotLev,Groep,Verdeler,Fabrikant,FabrikantNr,Lev,Aantal
 Set D="\",Groep="",HoofdGr=$$HoofdGr(HoofdGr)
 If $D(^KKOV(KLNr,HoofdGr,0,0,0)),$P(^KKOV(KLNr,HoofdGr,0,0,0),D,8)="*" Set Groep=0
 For  Set Groep=$O(^KKOV(KLNr,HoofdGr,Groep)) Quit:Groep=""  Do
 . Set Verdeler=""
 . For  Set Verdeler=$O(^KKOV(KLNr,HoofdGr,Groep,Verdeler)) Quit:Verdeler=""  Do
 . . Set Fabrikant=""
 . . For  Set Fabrikant=$O(^KKOV(KLNr,HoofdGr,Groep,Verdeler,Fabrikant)) Quit:Fabrikant=""  Do
 . . . Set R=^KKOV(KLNr,HoofdGr,Groep,Verdeler,Fabrikant),Aantal=$P(R,D,3),FabrikantNr=$P(R,D,14)
 . . . Set:'FabrikantNr FabrikantNr=999999
 . . . Set FabrikantNr(FabrikantNr)=$G(FabrikantNr(FabrikantNr))+Aantal
 Set (FabrikantNr,PotLev,Aantal)=""
 For  Set FabrikantNr=$O(FabrikantNr(FabrikantNr)) Quit:FabrikantNr=""  Set:FabrikantNr(FabrikantNr)>Aantal Aantal=FabrikantNr(FabrikantNr),PotLev=FabrikantNr
 Set PotLev=$S(PotLev="":"",PotLev=999999:"",$D(^KFAB1(PotLev)):$P(^KFAB(^KFAB1(PotLev),0),D,10),1:"Onbekend")
 Quit PotLev
 
 ; Geeft het totale aantal van een bepaalde hoofdgroep
PotAantal(KLNr,HoofdGr)
 New D,R,PotAantal,Groep,Verdeler,Fabrikant
 Set D="\",Groep="",PotAantal=0,HoofdGr=$$HoofdGr(HoofdGr)
 If $D(^KKOV(KLNr,HoofdGr,0,0,0)),$P(^KKOV(KLNr,HoofdGr,0,0,0),D,8)="*" Set Groep=0
 For  Set Groep=$O(^KKOV(KLNr,HoofdGr,Groep)) Quit:Groep=""  Do
 . Set Verdeler=""
 . For  Set Verdeler=$O(^KKOV(KLNr,HoofdGr,Groep,Verdeler)) Quit:Verdeler=""  Do
 . . Set Fabrikant=""
 . . For  Set Fabrikant=$O(^KKOV(KLNr,HoofdGr,Groep,Verdeler,Fabrikant)) Quit:Fabrikant=""  Do
 . . . Set R=^KKOV(KLNr,HoofdGr,Groep,Verdeler,Fabrikant),PotAantal=PotAantal+$P(R,D,3)
 Quit PotAantal
 
 ; Bepalen van de hoofdgroepindex
HoofdGr(HoofdGr)
 New HGIndex
 Set HGIndex=""
 For  Set HGIndex=$O(^KPHG(HGIndex)) Quit:HGIndex=""  Quit:HGIndex[HoofdGr
 Quit HGIndex