KORTING ;Klant korting
 
	; Normale lijnkorting
KORTPC(KLNr,PRNr,NoSa,RefDat,Aantal,LevTerm)
	New Rec
	Set Rec=$$GetKorting(KLNr,PRNr,.NoSa,.RefDat,.Aantal,.LevTerm)
	Quit $LG(Rec,2)_D_$LG(Rec,3)_D_$LG(Rec,6)_D_D_D_$S($LG(Rec,6)="O":"O",1:"")	
 
	// Bepalen van de korting 
GetKorting(KLNr,PRNr,NoSa,RefDat,Aantal,LevTerm,Optie)
	; Optie : T = Geen TANDEMBOX korting berekening
	; Optie : D = Display van optionele kortingen 
	New I,R,Korting,Korting1,Korting2,DTyp,HoofdGroep,Groep,SubGroep,Niveau,PrijsGegRec
	New GrootVp,OptMin,OptPlus,OptKort,IsKatPr,PrijsKl,KlantInd,KYW,GenPRNr
	New KatPrijs,Result,OptKortList,HeeftUitz,DispOption,KortRec
	
	Do InitKORTPC ; ophalen van HoofdGroep, groep, subgroep, PrijsGegRec en defaulten option variabelen
	Set PrijsKl=$$PRIJSKL^KLANT(KLNr,PRNr,NoSa) ;Prijsklasse Beslag of Orgalux
	Set KatPrijs=$$KATPrijs(KLNr,PRNr,NoSa,PrijsGegRec) ; Katprijs zonder uitzonderingen
	If $L(PrijsKl),"CP"[PrijsKl Set KatPrijs="" ; Geen katprijs indien "C" of "P" klant
 
	Set Result=""
	Set OptKortList=0
	; De verschillende kortingnivo's aflopen totdat een korting gevonden wordt, volgorde is ZEER belangrijk
	Set:(HeeftUitz) Result=$$GetUitz(KLNr,NoSa,"P",HoofdGroep,Groep,SubGroep,PRNr,RefDat,Aantal,LevTerm,.OptKortList) ; Product
	Set:('$LL(Result))&&(HeeftUitz) Result=$$GetUitz(KLNr,NoSa,"W",HoofdGroep,Groep,SubGroep,PRNr,RefDat,Aantal,LevTerm,.OptKortList) ; Product via WILDCARDING
	Set:('$LL(Result))&&(KatPrijs?1A) Result=$LB("K",KatPrijs,"",,,"K") ; KATPrijs
	Set:('$LL(Result))&&(HeeftUitz) Result=$$GetUitz(KLNr,NoSa,"S",HoofdGroep,Groep,SubGroep,0,RefDat,Aantal,LevTerm,.OptKortList) ; Subgroep 
	Set:('$LL(Result))&&(HeeftUitz) Result=$$GetUitz(KLNr,NoSa,"G",HoofdGroep,Groep,0,0,RefDat,Aantal,LevTerm,.OptKortList) ; Groep 
	Set:('$LL(Result))&&(HeeftUitz) Result=$$GetUitz(KLNr,NoSa,"H",HoofdGroep,0,0,0,RefDat,Aantal,LevTerm,.OptKortList) ; HoofdGroep 
	Set:('$LL(Result)) Result=$LB("K",PrijsKl,"",,,"C") ; Prijsklasse klant
	If $G(OptKortList),$G(Optie)["D" Do  ; Er zijn optionele uitzonderingen
	. Do FilterOptioneleUitz(Result,.OptKortList) ; alle kleinere uitzonderingen wegfilteren
	. Quit:'$G(OptKortList) ; ze zijn allemaal weggefilterd
	. Set ResultOpt=$$DisplayOptioneleUitz(KLNr,PRNr,.OptKortList)
	. Set:$LL(ResultOpt) Result=ResultOpt,$LI(Result,6)="O" ;geforceerde optionele uitzondering
 
	If $LI(Result,2)?1A Do
	. Set $LI(Result,2)=$$TranslateCodex^KPRIJS(PRNr,$LI(Result,2),NoSa,$P(PrijsGegRec,D,14))
	. Set $LI(Result,3)=""
 
	;Result : 
	; 1 TypeKorting (K=Korting,E=Extra korting,P=Vaste prijs)
	; 2 Korting1 (percentage*100)
	; 3 Korting2 (percentage*100)
	; 4 Extra korting (percentage * 100)
	; 5 Vaste prijs
	; 6 Kortingsnivo (K=KATprijs,P=Product,W=Product wildcarding,H=Hoofdgroep,G=Groep,S=SubGroep,C=Codexklant,O=geforceerde optionele uitzondering
	; 7 KlantGrootteOrde
	Quit Result
 
	// Ophalen van de geldige uitzonderingen en die maximale korting behouden, 
	// de niet geledige uitzonderingen worden in de OptKortList gestoken voor later verwerking
GetUitz(KLNr,NoSa,Nivo2,HoofdGroep,Groep,SubGroep,PRNr,RefDat,Aantal,LevTerm,OptKortList)
	New Korting,Geldig,MaxKorting,MaxRec,UitzRec,Product,VolgNr,Ongeldig
	Set MaxKorting=-999
	Set (MaxRec,VolgNr)=""
	Set Product=$S(Nivo2="W":0,1:PRNr) ; Wildcarding is ingesteld op subgroep nivo
	For  Set VolgNr=$O(^KLPUTZ(NoSa,KLNr,HoofdGroep,Groep,SubGroep,Product,VolgNr)) Quit:VolgNr=""  Do
	. Set UitzRec=^KLPUTZ(NoSa,KLNr,HoofdGroep,Groep,SubGroep,Product,VolgNr)
	. If Nivo2="W",'$L($P(UitzRec,D,15)),'$L($P(UitzRec,D,16)) Quit ; wildcarding of callback maar deze zijn niet ingevuld
	. Set Korting=$$OneKorting^KPRIJS($P(UitzRec,D,1),$P(UitzRec,D,2))
	. Set Ongeldig=$$OngeldigUitz(KLNr,PRNr,UitzRec,RefDat,Aantal,LevTerm)
	. If Ongeldig="",MaxKorting<Korting Set MaxKorting=Korting,MaxRec=UitzRec ; Geldige uitz met grootste korting bepalen
	. Else  Set:$L(Ongeldig)&&(Ongeldig'="X") OptKortList($I(OptKortList))=$LB(Nivo2,HoofdGroep,Groep,Subgroep,Product,UitzRec,Ongeldig)
 
	Quit:MaxRec="" ""
	Quit $LB("K",$P(MaxRec,D,1),$P(MaxRec,D,2),,,Nivo2)_$S($L($P(MaxRec,D,13)):$LB($P(MaxRec,D,13)),1:"")
	
	
KATPrijs(KLNr,PRNr,NoSa,PrijsGegRec) ; Katprijs zonder rekening te houden met uitzonderingen op product nivo
	New IsKsCust,KlTyp,Rec
	Quit:$$IsMedewerker^KLANT5(KLNr) "" ; geen katprijs voor medewerkers
	Set:$G(PrijsGegRec)="" PrijsGegRec=$$PRIJSGEGZONDERAX^KPRIJS(PRNr,.NoSa)
	Set KlTyp=$$IsHandel^KLANT5(KLNr)
	Set IsKsCust=0 ;$$ISKLANT^KS(KLNr,,.NoSa)
	Quit $S(IsKsCust:$P(PrijsGegRec,D,18),KlTyp:$P(PrijsGegRec,D,17),1:$P(PrijsGegRec,D,16))
 
InitKORTPC ; Initialisatie voor KORTPC routine
	; Klassificatie
	Set:$G(NoSa)="" NoSa="N"
	Set (HoofdGroep,Groep,SubGroep)=" ",I=$O(^KPR(PRNr,"I"))
	If $E(I)="I" Set R=^KPR(PRNr,I),HoofdGroep=$P(R,D),Groep=$P(R,D,2),SubGroep=$P(R,D,3)
	Set GenPRNr=$P(^KPR(PRNr,0),D,3)
	; Heeft uitzonderingen
	Set HeeftUitz=$D(^KLPUTZ(NoSa,KLNr))
	;Defaulting option parameters
	Set Aantal=$G(Aantal)
	Set RefDat=$G(RefDat,$H)
	Set:RefDat'?.N RefDat=$$INTDATE^vhLib.DataTypes(RefDat)
	; Omzetten van leverweek naar levertermijn
	Set LevTerm=$G(LevTerm),DTyp="" If LevTerm'?.N Set DTyp="DW"
	If $L(DTyp) Set LevTerm=$$CALCDATE^vhLib.DataTypes($$INTDATE^vhLib.DataTypes(LevTerm,DTyp),"W","FD"),LevTerm=$J((LevTerm-$H)/7,0)
	Set DispOption=$G(DispOption)
	Set PrijsGegRec=$$PRIJSGEGZONDERAX^KPRIJS(PRNr,NoSa)
	Quit
 
	// --- Optionele kortingen ---
OngeldigUitz(KLNr,PRNr,UitzRec,RefDat,Aantal,LevTerm,OokZonderRefParamIngevuld) ; Indien leeg teruggegeven dan GELDIG anders wordt het probleem aangeduid
	; Parmeter OokZonderRefParamIngevuld : Indien de RefParam niet is ingevuld dan moet er toch getest worden !
	New Ongeldig,%Val
	Set Ongeldig=""
	;w "Ongeldig ",KLNr," ",PRNr," ",UitzRec,! r k
	If $L($P(UitzRec,D,15)) Do  Quit:Ongeldig="X" Ongeldig ; Patternmatch op korttekst
	. If PRNr'?4.7N Set Ongeldig="X"  Quit ; alleen als het product is ingevuld
	. New KortT
	. Set KortT=$P(^KPR(PRNr,0),D)
	. Set:KortT'?@$P(UitzRec,D,15) Ongeldig="X" 
	If $L($P(UitzRec,D,16)) Do  Quit:Ongeldig="X" Ongeldig ; Callback
	. If PRNr'?4.7N Set Ongeldig="X"  Quit ; alleen als het product is ingevuld
	. Do EXECS^vhRES($P(UitzRec,D,16),"Allow","(KLNr,PRNr)")
	. Set:'Allow Ongeldig="X" 
	If $P(UitzRec,D,5),($P(UitzRec,D,5)>Aantal)||(Aantal="") Set Ongeldig=Ongeldig_$S(Aantal="":"a",1:"A") ; Probleem met aantal
	If $P(UitzRec,D,6),($P(UitzRec,D,6)>LevTerm)||(LevTerm="") Set Ongeldig=Ongeldig_$S(LevTerm="":"t",1:"T") ; Probleem met leveringstermijn
	If $P(UitzRec,D,7),($P(UitzRec,D,7)>RefDat)||(RefDat="") Set Ongeldig=Ongeldig_$S(RefDat="":"s",1:"S") ; Probleem met startdatum
	If $P(UitzRec,D,8),($P(UitzRec,D,8)<RefDat)||(RefDat="") Set Ongeldig=Ongeldig_$S(RefDat="":"e",1:"E") ; Probleem met einddatum
	; De lowercase betekend dat het gaat over een opt. uitzondering waar voor geen parameter werd doorgegeven
	Set:'$G(OokZonderRefParamIngevuld)&&($ZCONVERT(Ongeldig,"U")'=Ongeldig) Ongeldig="X"
	Quit Ongeldig
 
FilterOptioneleUitz(UitzRec,OptKortList) ; Alle kleinere uitzonderingen worden weggefilterd
    New tempList,VolgNr,Rec
    Set Volgnr="",tempList=0
    Set Korting=$$OneKorting^KPRIJS($P(UitzRec,D,1),$P(UitzRec,D,1)) ; reeds weerhouden korting
	For VolgNr=1:1:$G(OptKortList) Do
	. Set Rec=$LI(OptKortList(VolgNr),6)
    . Set:Korting<$$OneKorting^KPRIJS($P(Rec,D,1),$P(Rec,D,1)) tempList($I(tempList))=OptKortList(VolgNr)
    Kill OptKortList
    Merge:tempList OptKortList=tempList
    Quit
	
DisplayOptioneleUitz(KLNr,PRNr,OptKortList)
    ;Set OptKortList=3
    New Result,Input,List,Input,UitzRec,Nivo
    Quit:'$G(OptKortList) ""
    Set Result=""
    Set List=0
    For VolgNr=1:1:$G(OptKortList) Do
	. Set UitzRec=$LI(OptKortList(VolgNr),6)
	. Set $P(UitzRec,D,20)=$LI(OptKortList(VolgNr),1) ; Nivo
	. Set $P(UitzRec,D,21)=$LI(OptKortList(VolgNr),7) ; OngeldigUitz codes
    . Set List($I(List))=UitzRec
    Do INIT^vhLIST("KORTING","SELECTOPT",.LD)
    Do WRITE^vhLIST(.LD)
    Set Input=$$SCROLL^vhLIST(.LD)
	If Input="S" Do  ; Optionele uitzondering geselecteerd
	. Set VolgNr=LD("SELECT")
	. Set Nivo=$LI(OptKortList(VolgNr),1)
	. Set UitzRec=$LI(OptKortList(VolgNr),6)
	. Set Result=$LB("K",$P(UitzRec,D,1),$P(UitzRec,D,2),,,Nivo)_$S($L($P(UitzRec,D,13)):$LB($P(UitzRec,D,13)),1:"")
	Quit Result
 
HeeftUitz(KLNr,PRNr,NoSa) 
	New I,R,Result,HoofdGroep,Groep,SubGroep,HeeftUitz,Aantal,RefDat,LevTerm,DTyp,DispOption,PrijsGegRec
	Do InitKORTPC
	Set Result=""
	Set:HeeftUitz Result=$$GetUitz(KLNr,NoSa,"P",HoofdGroep,Groep,SubGroep,PRNr,.NoSa,.RefDat,.Aantal,.LevTerm)
	Set:('$LL(Result))&&(HeeftUitz) Result=$$GetUitz(KLNr,NoSa,"W",HoofdGroep,Groep,SubGroep,PRNr,RefDat,Aantal,LevTerm,.OptKortList) ; Product via WILDCARDING
	Set:('$LL(Result))&&(HeeftUitz) Result=$$GetUitz(KLNr,NoSa,"S",HoofdGroep,Groep,SubGroep,0,.NoSa,.RefDat,.Aantal,.LevTerm)
	Set:('$LL(Result))&&(HeeftUitz) Result=$$GetUitz(KLNr,NoSa,"G",HoofdGroep,Groep,0,0,.NoSa,.RefDat,.Aantal,.LevTerm)
	Set:('$LL(Result))&&(HeeftUitz) Result=$$GetUitz(KLNr,NoSa,"H",HoofdGroep,0,0,0,.NoSa,.RefDat,.Aantal,.LevTerm)
	Set Result=''$L(Result)
	Quit Result
 
	; Formateer korting
FMTKORT(Korting1,Korting2,Length) 
	New Korting
	Set Korting1=$G(Korting1),Korting2=$G(Korting2),Length=$G(Length),Korting=""
	If Korting1["#" Set Korting2=$P(Korting1,"#",2),Korting1=$P(Korting1,"#")
	If Korting1 Set Korting=$$EXTNUM^vhLib.DataTypes(Korting1,Length,"",1)
	If Korting2 Set Korting=Korting_" + "_$$EXTNUM^vhLib.DataTypes(Korting2,Length,"",1)
	Quit Korting
 
 
	// Neemt de uitzondering van het generisch product op productnivo
GetGenerischeUitz(KLNr,NoSa,GenPRNr,RefDat,Aantal,LevTerm,OptKortList)
	New HoofdGroep,Groep,SubGroep,Result
	Set (HoofdGroep,Groep,SubGroep)=" ",I=$O(^KPR(GenPRNr,"I"))
	If $E(I)="I" Set R=^KPR(GenPRNr,I),HoofdGroep=$P(R,D),Groep=$P(R,D,2),SubGroep=$P(R,D,3)
	Set Result=$$GetUitz(KLNr,NoSa,"P",HoofdGroep,Groep,SubGroep,GenPRNr,RefDat,Aantal,LevTerm,.OptKortList) ; GenerischProduct
	Quit Result
	
	// Bepalen van de uitzondering voor de gemonteerde tandembox
GetTBXUitz(KLNr,PRNr,NoSa,PrijsGegRec) 
	; optioneel PrijsGegRec
	New Result,LijstPrijs,Korting
	Set NoSa=$G(NoSa,"N")
	Quit:$P($$GENTYP^HAD(PRNr),D)'="TBX" ""
	Set:$G(PrijsGegRec)="" PrijsGegRec=$$PRIJSGEG^KPRIJS(PRNr,.NoSa)
	Quit:'$D(^PRBS("BS",PRNr)) "" ; geen halffabrikaten
	Quit:'$$CHECK^KLHFUTZ(KLNr,"BX",NoSa) "" ; geen uitzondering op boxen
	Do CALC^PRBS(PRNr,.Prijs,,,KLNr,NoSa)
	If Prijs=-1 Do  Quit $LB("K",0,"",,,"P") ; Fout bij prijsberekening (bv. halffabrikaat verwijderd), geen korting
	. Do:$G(Optie)["D" WARN^vhTXTPOP("Fout bij de herrekening van de korting, mogelijk is er een halffabrikaat verwijderd")
	Set LijstPrijs=$P(PrijsGegRec,D,15)
	Set Korting=$J(1-(Prijs/LijstPrijs)*100-.04999,0,1)
	Set Result=$LB("K",Korting,"",,,"P")
	Quit Result