KPVHPR ;VERGELIJKEN HUIDIGE PRIJZEN KLANTEN ;KPVHPR; [ 03/07/2002  1:45 PM ]
 ;
NOSA
 Set SchaduwIsActief=$G(^KLPUTZ("AS"))
 If 'SchaduwIsActief Set %SC=1,NoSa="N"
 Else  Do
 . Do DISPLAY^vhScherm("KPVHPR")
 . Set NoSa="N"
 . Do FIELD^vhScherm("KPVHPR","NOSA")
 Do:%SC
 . Do DISPLAY^vhScherm("KPVHPR")
 . If '$D(^KPHPR(NoSa,0)) Set R=$$^vhTXTPOP("KPVHPR","NOTOK","",NoSa,$S(NoSa="S":"schaduwprijzen",1:"huidige prijzen")) Quit
 . Do FIELD^vhScherm("KPVHPR","GO")
 . Quit:'%SC
 . Do COMPARE(NoSa,Go)
 Quit
 ;
INIT
 If $D(NoSa) Do
 . Set:NoSa'="S" NoSa="N"
 . Set Go=""
 . Set Aangemaakt=$G(^KPHPR(NoSa,0))
 . For Field="ALLCUST","VOLASSORT","HPRIJZEN","OPSLAG","AANGEMAAKT","AANMAAKTYD" Do REMATTR^vhScherm(Field,"H","H")
 Else  Do
 . Set NAangemaakt=$G(^KPHPR("N",0)),SAangemaakt=$G(^KPHPR("S",0))
 . For Field="NAANMAAK","SAANMAAK" Do REMATTR^vhScherm(Field,"H","H")
 Quit
 ;
COMPARE(NoSa,Go)
 Do PRIO^vhINITML("L")
 Set PrijsU=Go="U",(KlCount,Count)=0
 Kill ^HULP($J)
 Set FP=2201
 Write @F,@F1,!?2,"Klanten verwerkt :"
 Set KlKey=0
 For  Set KlKey=$O(^KKL(KlKey)) Quit:KlKey=""  Do
 . Set R=^KKL(KlKey,0),KLNr=$P(R,D),KlNaam=$P(R,D,2)
 . If PrijsU,'$D(^KLPUTZ("N",KLNr)) Quit
 . Set KlCount=KlCount+1
 . If '(KlCount#10) Set FP=2322 Write @F,@F1,KlCount,"   (",KLNr," ",KlNaam,")"
 . Kill ^HULP($J,"Sort")
 . Set PRNr=0
 . For  Set PRNr=$O(^KSTKL(KLNr,PRNr)) Quit:PRNr=""  Do
 ..  Quit:'$D(^KPHPR(NoSa,KLNr,PRNr))
 ..  Set KortTekst=$P($G(^KPR(PRNr,0)),D)
 ..  Quit:KortTekst=""
 ..  Set IdentNr=$P(^KPR(PRNr,2),D,25)
 ..  Set KPrijs=$$KLANTPR^KPRIJS(KLNr,PRNr)
 ..  Set Prijs=$P(KPrijs,D,1),Munt=$P(KPrijs,D,2),GrOrde=$P(KPrijs,D,3)
 ..  Set R=^KPHPR(NoSa,KLNr,PRNr)
 ..  Set PrijsVerschil=Prijs-$P(R,D,3)
 ..  Quit:'PrijsVerschil
 ..  Set SortKey=$$SORTKEY^PRODUKT(PRNr),KKey=$$KKEY^KLASS(PRNr)
 ..  Set HoofdGr=$$GETSORT^KLASS(KKey,1),Groep=$$GETSORT^KLASS(KKey,2),SubGroep=$$GETSORT^KLASS(KKey,3)
 ..  Set R=HoofdGr_D_Groep_D_SubGroep_D_IdentNr_D_KortTekst_D_Prijs_D_Munt_D_GrOrde_D_PRNr_D_R_KLNr_D_KlNaam
 ..  Set ^HULP($J,"Sort",SortKey)=R
 . Set SortKey=""
 . For  Set SortKey=$O(^HULP($J,"Sort",SortKey)) Quit:SortKey=""  Set R=^HULP($J,"Sort",SortKey),Count=Count+1,^HULP($J,Count)=R
 . Kill ^HULP($J,"Sort")
 If '$D(^HULP($J)) Do
 . New IK
 . Set FP=303
 . Write @F,@F1,!!!!!!!!!!!!!!!!!!!?3,"Geen verschillen gevonden",!!?3,"E = Einde"
 . For  Do IK^PROC Quit:R="E"
 Else  Do
 . Write !,"Verschillen aantal: ",Count, "  Druk op <enter>"
 . Read R
 . Set DL(1)="LD",LD(1)="^HULP("_$J,LD(2)=$P($T(T24),U,2,99),LD(3)=4,LD(5)=132,LD(8)=$P($T(T23),U,2,99)
 . Set LD(11)="Prijsverschillen"_D_$S(PrijsU:"(alleen klanten met prijsuitzonderingen)",1:"(alle klanten)")
 . Set Begin=$$EXTDATE^vhLib.DataTypes($$CALCDATE^vhLib.DataTypes($H,"M","-12"),"DM4")_" "
 . Set Einde=$$EXTDATE^vhLib.DataTypes($$CALCDATE^vhLib.DataTypes($H,"M","-1"),"DM4")_" "
 . For  Do  Quit:R="E"
 ..  Set FP=2303
 ..  Write @F,@F1,"Output : .",!?2,"S = scherm   P = printer   T = transfert   E = einde"
 ..  Do IK^PROC1
 ..  Quit:R="E"
 ..  Set LD(2)=$P($T(T24),U,2,99),LD(8)=$P($T(T23),U,2,99)
 ..  Set:R="T" LD(2)=LD(2)_$P($T(T26),U,2,99),LD(8)=LD(8)_$P($T(T25),U,2,99)
 ..  If R="S" Do ^OUTPUT("S","-") Quit
 ..  If R="P" Do ^OUTPUT("P","") Quit
 ..  If R="T" Do ^OUTPUT("T","") Quit
 . Kill ^HULP($J)
 Quit
 ;
T23 ;"Hfd";C;L;3;;|\" Grp ";C;L;5;;| \"SubGrp";C;C;6;; | \"Korttekst";C;L;25;; |\"Vroeger";C;R;10;; |\"Nu";C;R;10;; | \"KLNr";N;R;5;; \"Klantnaam";C;L;25;;
T24 ;1;C;L;2;; | ;;$E(X,3,4)\2;C;L;3;; | ;;$E(X,7,9)\3;C;L;6;; | ;;$E(X,12,17)\5;C;L;25;; |\12;N+;R;10;2; |\6;N+;R;10;2; | \16;C;R;5;; \17;C;L;25;;
 ;
T25 ;|\"Regio";C;L;5;;|\"Omzet";C;L;5;;
T26 ;|\16;C;L;5;; | ;;$S(X:$P(^KKL(^KK1(X),0),$C(92),20),1:"")\16;C;L;5;; | ;;$S(X:$TR($$KLANT^STAT(X,"",Begin,Einde,3),".",","),1:"")