LEVVW ;Levringsvoorwaarde ;[ 01/17/2002  2:07 PM ]
 ;
KLANT(KLNr,B) 
 New R,KlantId,KlLevVW,LevVw,Taal,Land,Munt,All
 If '$D(B),$G(KLNr) Do
 .Set KlantId=^KK1(KLNr)
 .For I=0:1:8 Set B(I+1)=$G(^KKL(KlantId,I))
 Set Land=$P($G(B(1)),D,8),Taal=$P($G(B(1)),D,9),Munt=$P($G(B(1)),D,11),All=0
 For  Do  Quit:$L(LevVw)
 .Kill LevVw
 .Set LevVw=$P($G(B(4)),D,3) Set:LevVw="" LevVw="00"
 .Do KLFETCH(.LevVw,Munt,Land,Taal,All)
 .Set LevVw=$$WILD^vhPOPUP("C;C","OK1-","Leveringsvoorwaarde",.LevVw,LevVw)
 .Set:LevVw="" All=1
 Quit LevVw
 ;
ORDER(ORDNr,B) 
 New R,KLNr,KlantId,KlLevVW,LevVw,Taal,Land,Munt,All,LvwTemp
 If $D(B(106)),$D(B(121)) Set R="",$P(R,D,6)=$G(B(106)),$P(R,D,21)=$G(B(121))
 Else  Set R=$G(B(1))
 If '$D(B),$G(ORDNr) Set KLNr=$P(^KO1(ORDNr,"F"),D),R=^KOD(KLNr,"F",ORDNr,1)
 Set KLNr=$P(R,D,6),LvwTemp=$P(R,D,21) Set:'KLNr KLNr=$G(KC)
 Set KlantId=^KK1(KLNr),R=^KKL(KlantId,0)
 Set Land=$P(R,D,8),Taal=$P(R,D,9),Munt=$P(R,D,11),All=0
 For  Do  Quit:$L(LevVw)
 .Kill LevVw
 .Set LevVw=LvwTemp
 .If LevVw="" Set LevVw=$$KLANT(KLNr) Quit
 .Do KLFETCH(.LevVw,Munt,Land,Taal,All)
 .Set LevVw=$$WILD^vhPOPUP("C;C","OK1-","Leveringsvoorwaarde",.LevVw,LevVw)
 .Set:LevVw="" All=1
 Quit LevVw
 ;
BON(BONNr) 
 New R,KLNr,KlantId,KlLevVW,LevVw,Taal,Land,Munt,All
 Set KLNr=$P(^KU1(BONNr,"F"),D),KlantId=^KK1(KLNr)
 Set R=^KKL(KlantId,0)
 Set Land=$P(R,D,8),Taal=$G(Taal,$P(R,D,9)),Munt=$P(R,D,11),All=0
 For  Do  Quit:$L(LevVw)
 .Kill LevVw
 .Set R=^KUL(KLNr,"F",BONNr,1),LevVw=$P(R,D,21)
 .Do KLFETCH(.LevVw,Munt,Land,Taal,All)
 .Set LevVw=$$WILD^vhPOPUP("C;C","OK1-","Leveringsvoorwaarde",.LevVw,LevVw)
 .Set:LevVw="" All=1
 Quit LevVw
 ;
KLFETCH(LevVw,Munt,Land,Taal,All) 
 New R,Count,Old,AddOld
 Set Old=$TR($G(LevVw)," ",""),Munt=$G(Munt),Land=$G(Land),Taal=$G(Taal),All=$G(All) Set:Taal="" Taal="N"
 Set LevVw="",Count=0,AddOld=$S(All:0,1:1)
 For  Set LevVw=$O(^KBA(153,LevVw)) Quit:LevVw=""  Do
 .If 'All,$L(Munt) Set R=$G(^KBA(153,LevVw,"M",0)) If $L(R),R'=Munt Quit
 .If 'All,$L(Land) Set R=$G(^KBA(153,LevVw,"L",0)) If $L(R),R'=Land Quit
 .Set R=$G(^KBA(153,LevVw,"N",1)) Set:R="" R=$G(^KBA(153,LevVw,Taal,1))
 .Set R=$P(R,": ",2),Count=Count+1,LevVw(Count)=$TR(LevVw," ","")_"`"_R
 .If 'All,$TR(LevVw," ","")=Old Set AddOld=0
 If 'All Set Count=Count+1,LevVw(Count)="&S",Count=Count+1,LevVw(Count)="`Volledig overzicht"
 Set LevVw=Old
 If AddOld Do
 .Set Old=$TR(Old," ","")_" "
 .For Count=Count:-1:1 Set LevVw(Count+1)=LevVw(Count)
 .Set R=$G(^KBA(153,Old,"N",1)) Set:R="" R=$G(^KBA(153,Old,Taal,1))
 .Set R=$P(R,": ",2),LevVw(Count)=$TR(Old," ","")_"`"_R
 Quit
 ;