PAKKETE ;Klant Product referenties EXPORT [ 11/29/2003   8:10 AM ]
 
TRANSFER(KLNr,NoSa) 
 Set:'$G(KLNr) KLNr=$$SELECT^KLANT6()
 Set Dev=0
 Set Dev=$$OPEN^vhDEV(,"PAKKET"_KLNr_".TXT","W")
 Use Dev
 Write $TR("PakRef;Oms;IDNr;ProduktNaam;Faktor;Prijs;GO;GVP;NVP;Stock;HerbestelImpuls;LevTrm;MinBH",";",$C(9)),!
 Set PakRef=""
 For  Set PakRef=$O(^PAKKET("IK",KLNr,PakRef)) Quit:PakRef=""  Do
 . Set PakId=^(PakRef)
 . Set Oms=$P(^PAKKET("D",PakId),D,4)
 . Set PRNr=""
 . For  Set PRNr=$O(^PAKKET("D",PakId,PRNr)) Quit:PRNr=""  Do
 .. Set Faktor=$P(^PAKKET("D",PakId,PRNr),D)
 .. ;Ophalen prod gegevens
 .. Set KortTxt=$P(^KPR(PRNr,0),D,1)
 .. Set IDNr=$P(^KPR(PRNr,2),D,25)
 .. Set Prijs=$$KLANTPR^KPRIJS(KLNr,PRNr,$G(NoSa))
 .. Set Key=$O(^KPR(PRNr,"J"))
 .. Set RecJ=^KPR(PRNr,Key)
 .. Set GVP=$P(RecJ,D,16)
 .. Set NVP=$P(RecJ,D,15)
 .. Set Stock=$P(^KPR(PRNr,1),D,20)
 .. If $D(^KPBI("D",KLNr,PRNr)) Do
 ... Set BIRec=^KPBI("D",KLNr,PRNr)
 ... Set Stock=$S($P(BIRec,D,3):"RC",1:"C")
 ... Set Limiet=$P(BIRec,D,1)
 ... Set MinBH=$P(RecJ,D,6)
 ... Set LevTrm=$P(RecJ,D,7)
 ... If $P(BIRec,D,2) Do  ; Verpakkingsfaktor ingevuld
 .... Set GVP=$P(BIRec,D,2)
 .... Set NVP=""
 .. Else  If Stock Do
 ... Set MinBH=""
 ... Set Stock="S"
 ... Set LevTrm=""
 ... Set Limiet=""
 .. Else  Do
 ... Set Stock="NS"
 ... Set MinBH=$P(RecJ,D,6)
 ... Set LevTrm=$P(RecJ,D,7)
 ... Set Limiet=""
 .. ;
 .. Write PakRef,$C(9),Oms,$C(9),IDNr,$C(9),KortTxt,$C(9),Faktor
 .. Write $C(9),$TR($P(Prijs,D),".",","),$C(9),$P(Prijs,D,3)
 .. Write $C(9),GVP,$C(9),NVP,$C(9),Stock,$C(9),Limiet,$C(9),LevTrm,$C(9),MinBH
 .. Write !
 Close:Dev'=0 Dev