PVMatthias
#Include BL.Derde.LevSpecifiek
#include Prod.Product
#include vhLib.Macro

HistoriekBouwstenen
	Set Begin=$$CALCDATE^vhLib.DataTypes($H,"M",-12,"FD")
	Set Einde=$$CALCDATE^vhLib.DataTypes($H,"M",-1,"LD")
	Set Dev=$$OPEN^vhDEV(,"HistoriekBouwstenen.txt","W","T")
	Use Dev

	Do WriteHeader
	Set PRNr=""
	For  Set PRNr=$O(^PRHIST(PRNr)) Quit:'PRNr  Do
	. Quit:$E($$$PRGet($$$LinkType),1,2)'="HH" ;alleen Halux aankopen
	. Do HistoriekIndienHaluxMoeder(PRNr,Begin,Einde)

	Do CLOSE^vhDEV(Dev)
	Quit
	
HistoriekIndienHaluxMoeder(HFPRNr,Begin,Einde) 
 New Key,I,Rec,Actie,Magazijn,MPRNr
 Set Actie="H"
 Set Magazijn="W"
 Set Key=""
 Set Cumul="",Aantal=""
 For  Set Key=$O(^PRHIST(HFPRNr,Key)) Quit:Key=""  Do
 . Set Rec=^PRHIST(HFPRNr,Key)
 . Quit:+$P(Rec,"\")<Begin
 . Quit:+$P(Rec,"\")>Einde
 . Quit:$P(Rec,"\",5)'=Magazijn
 . Quit:$P(Rec,"\",4)'=Actie
 . Set MPRNr=$P(Rec,"\",15)
 . Quit:'MPRNr
 . Quit:$$GetOrOld^PRODUKT(MPRNr,$$$LeveranciersNr)'=$$$LevHalux
 . Do WriteRecord(MPRNr,HFPRNr,Rec)
 Quit
 
WriteRecord(MPRNr,HFPRNr,HistRec) 
 New KortTekstM,KortTekstHF,GenType,LevNrHF,LevNaamHF,AnalRekM,AnalOmsM,Aantal,Waarde
 Set KortTekstM=$$GetOrOld^PRODUKT(MPRNr,$$$KortTekst)
 Set KortTekstHF=$$GetOrOld^PRODUKT(HFPRNr,$$$KortTekst)
 Set GenType=$P($$GENTYP^HAD(MPRNr,1),"\",1,2) ; incl verwijderde
 Set LevNrHF=$$GetOrOld^PRODUKT(HFPRNr,$$$LeveranciersNr)
 Set AnalRekM=$$AnalytischeRekening(GenType)
 Set AnalOmsM=$$AnalytischeOmschrijving(AnalRekM)
 Set LevNaamHF=$P(^KLE(^KL1(LevNrHF),0),"\",2)
 Set Aantal=$P(HistRec,"\",2)
 Set Waarde=$P(HistRec,"\",12)
 Write MPRNr,*9,KortTekstM,*9,GenType,*9,AnalRekM,*9,AnalOmsM
 Write *9,HFPRNr,*9,KortTekstHF,*9,LevNrHF,*9,LevNaamHF
 Write *9,$$$ExcelDat(+$P(HistRec,"\")),*9,$$$ExcelDat($$CALCDATE^vhLib.DataTypes(+$P(HistRec,"\"),"M","FD")),*9,$$$ExcelNum(Aantal),*9,$$$ExcelNum(Waarde)
 Write !
 Quit
WriteHeader
	Write "MoederNr	MKortTekst	MGenType	MAnalRek	MAnalOms	HalfFabrNr	HFKortTekst	HFLevNr	HFLevNm	Datum	Maand	Aantal	Waarde",!
	Quit 
	
AnalytischeRekening(GenTyp)
	New AnalRek
	Set GenTyp=$P(GenTyp,"\",1,2)
	Set:GenTyp="" GenTyp="\"
	Set AnalRek=$P($G(^RES("HAD","PI","GENTYP","D",GenTyp)),"`",6)
	Set:AnalRek="" AnalRek="0199"
	Quit AnalRek

 
AnalytischeOmschrijving(AnalRek)	
	Quit $P($G(^RES("HAD","PI","ANALREK","D",AnalRek_" "),"`Not Found"),"`",2)