PVORGAL ; Orgalux controle op manuele prijsberekening [ 11/08/2003   8:27 PM ]
 Q
 
 
OLTXT
 
 Set NoSa="S"
 Set PRNr=0
 For  Set PRNr=$O(^KPR(PRNr)) Quit:PRNr=""  Do
 . Set KT=$P(^KPR(PRNr,0),D,1)
 . Quit:$P($$GENTYP^HAD(PRNr),"\",1,2)'="DIV\ASM"
 . 
 . Set Orgalux=0
 . Set MPRNr=""
 . For  Set MPRNr=$O(^PRBS("IP",PRNr,MPRNr)) Quit:MPRNr=""  Do
 . . Quit:'$$ISORGAL^ORGALUX(MPRNr)
 . . Set Orgalux=MPRNr
 . Quit:'Orgalux
 . Set MPRNr=Orgalux
 . Write PRNr,*9,KT," -> " ;,MPRNr,*9,$P(^KPR(MPRNr,0),D,1),!
 . ;Write $P(^KPR(PRNr,4),D,1),!
 . Set LT=$P(^KPR(PRNr,4),D,1)
 . Set LT=$$REPLACE^vhRtn1(LT,"mat","mat ORGALUX") 
 . write LT,!
 . Set $P(^KPR(PRNr,4),D,1)=LT
 Quit
 
 
 
OLCONTR Set Dev=0
 Set Dev=$$OPEN^vhDEV(,"Orgalux schaduwprijzen.TXT","W")
 Use Dev
 Write $TR("SortKey,PRNr,KortTekst,Klant,Groot,Spil,NL,BE",",",$C(9)),!
 Set KLNr=3711
 Set NoSa="S"
 Set PRNr=0
 For  Set PRNr=$O(^KPR(PRNr)) Quit:PRNr=""  Do
 . Set KT=$P(^KPR(PRNr,0),D,1)
 . Quit:$E(KT,1,2)'="OL"
 . Set SortKey=$$SORTKEY^PRODUKT(PRNr)
 . Quit:$E(SortKey,3,4)'="OL"
 . ;Set Groot=KlantPrijsViaKorting(3711,PRNr,"G",,,1,"S")
 . Set Klant=$P($$KLANTPR^KPRIJS(KLNr,PRNr,NoSa),D,1)
 . Set Groot=$P($$PROD^KPRIJS(PRNr,"G","","EUR","","",NoSa),D,1) 
 . Set Dealer=$P($$PROD^KPRIJS(PRNr,"S","","EUR","","",NoSa),D,1)
 . Set ConsNL=Dealer*2*(1+(19/100))
 . Set ConsBE=Dealer*2*(1+(21/100))
 . Write SortKey,$C(9),PRNr,$C(9),KT,$C(9),$TR(Klant,".",","),$C(9),$TR(Groot,".",","),$C(9),$TR(Dealer,".",","),$C(9),$TR(ConsNL,".",","),$C(9),$TR(ConsBE,".",","),!
 Close:Dev'=0 Dev
 Quit
 
PRLINK 
 Set Dev=$$OPEN^vhDEV(,"Moeder-Kind prijscontrole.TXT","W")
 Use Dev
 Write $TR("ProdGrp,MPRNr,Moeder,MCiffPPL,KPRNr,Kind,KCiffPPL,Faktor,CiffTot,StatAantal",",",$C(9)),!
 
 Set MPRNr=""
 For  Set MPRNr=$O(^PRLINK("D",MPRNr)) Quit:MPRNr=""  Do
 .Set MKT=$P($G(^KPR(MPRNr,0)),D,1)
 .Quit:MKT=""
 .Set ProdGrp=$$PRODGRP^PRODUKT(MPRNr)
 .Set Qty=$$PROD^STAT(MPRNr,0,"","",1)
 .Set Key=$O(^KPR(MPRNr,"J"))
 .Set MCiffPPL=$P(^KPR(MPRNr,Key),D,23)
 .Set KPRNr=""
 .For  Set KPRNr=$O(^PRLINK("D",MPRNr,KPRNr)) Quit:KPRNr=""  Do
 ..Set Faktor=$P(^PRLINK("D",MPRNr,KPRNr),D)
 ..Set KKT=$P($G(^KPR(KPRNr,0),"***onbekend***"),D,1)
 ..Set Key=$O(^KPR(KPRNr,"J"))
 ..Set KCiffPPL=$S($E(Key)="J":$P(^KPR(KPRNr,Key),D,23),1:0)
 ..Write ProdGrp,$C(9),MPRNr,$C(9),MKT,$C(9),$TR(MCiffPPL,".",","),$C(9),KPRNr,$C(9),KKT,$C(9),$TR(KCiffPPL,".",","),$C(9),Faktor,$C(9),$TR(KCiffPPL*Faktor,".",","),$C(9),Qty,!
 ..Set MCiffPPL=""
 ..Set Qty=""
 Close:Dev'=0 Dev
 Quit
 
FAKTALL Set %J=$$%J^vhRtn1()
 Kill HULP(%J)
 
 Set Dev=0
 Set Dev=$$OPEN^vhDEV(,"FAKTTELLING.TXT","W")
 Use Dev
 Write $TR("KLNr;Maand;FakCnt;BonCnt",";",$C(9)),!
 
 Set KLNr=""
 For  Set KLNr=$O(^KFA1("F",KLNr)) Quit:KLNr=""  Do
 . Kill HULP(%J)
 . Set EndDat=-($H-400)
 . Set MinDat=""
 . For  Set MinDat=$O(^KFA1("F",KLNr,MinDat)) Quit:MinDat=""!(MinDat>EndDat)  Do
 .. Set FAKNr=""
 .. For  Set FAKNr=$O(^KFA1("F",KLNr,MinDat,FAKNr)) Quit:FAKNr=""  Do
 ... Do FAKT(FAKNr)
 . ;
 . Set Maand=""
 . For  Set Maand=$O(HULP(%J,KLNr,Maand)) Quit:Maand=""  Do
 .. Set Rec=HULP(%J,KLNr,Maand)
 .. Write KLNr,$C(9),$$EXTDATE^vhLib.DataTypes(Maand,"DK"),$C(9),$P(Rec,D,1),$C(9),$P(Rec,D,2),!
 
 Close:Dev'=0 Dev
 Quit
 
FAKT(FAKNr) 
 Set KLNr=$P(^KFA("F",FAKNr,0,0),D,1)
 Set Datum=$P(^KFA("F",FAKNr,0,0),D,6)
 Set Datum=$$CALCDATE^vhLib.DataTypes($$INTDATE^vhLib.DataTypes(Datum),"M","FD")
 Set ULKey="U"
 Set ULCnt=0
 For  Set ULKey=$O(^KFA("F",FAKNr,ULKey)) Quit:ULKey=""  Do
 . Set ULCnt=ULCnt+1
 Set Rec=$G(HULP(%J,KLNr,Datum))
 Set $P(Rec,D)=$P(Rec,D)+1
 Set $P(Rec,D,2)=$P(Rec,D,2)+ULCnt
 Set HULP(%J,KLNr,Datum)=Rec
 Quit