#include vhLib.Macro
#include Prod.Product
#include BL.Derde.KlantSpecifiek
#include BL.Derde.LevSpecifiek

Export
	Set Device=$$OPEN^vhDEV(,"TAOR FakturatieAantallen.txt","W","T")
	Use Device
	Write "KLNr	Regio	FAKNr	Datum	PRNr	KortTekst	Telbaar	Aantal	Omzet	Kost	ZonderStock	OmzetZndrGlijder	KostZndrGlijder",!
	Do WriteFacturatie
	Do CLOSE^vhDEV(Device)
	Quit
WriteFacturatie
	Set KLNr=0
	Set BeginDatum=$$CALCDATE^vhLib.DataTypes($H,"BJ","FD",-1)
	Set EindDatum=$$CALCDATE^vhLib.DataTypes($H,"M","LD",-1)
	For  Set KLNr=$O(^KFA1("F",KLNr)) Quit:KLNr=""  Do
	. Set KlKey=^KK1(KLNr)
	. Set Regio=$P(^KKL(KlKey,0),"\",20)
	. Set Datum="" ; beginnen vanaf vandaag omdat orders van vorige maand ook in facturen van vandaag kunnen zitten
	. For  Set Datum=$O(^KFA1("F",KLNr,Datum)) Quit:Datum=""  Do
	. . Quit:-Datum>EindDatum
	. . Quit:-Datum<BeginDatum
	. . Set BKJaar=$$CALCDATE^vhLib.DataTypes(-Datum,"BJ","LD")
	. . Set FAKNr=""
 	. . For  Set FAKNr=$O(^KFA1("F",KLNr,Datum,FAKNr)) Quit:FAKNr=""  Do
	. . . Set BONNr="U"
	. . . For  Set BONNr=$O(^KFA("F",FAKNr,BONNr)) Quit:$E(BONNr)'="U"  Do
	. . . . Set BonRec=^KFA("F",FAKNr,BONNr,1)
	. . . . Set Vzw=$E($P(BonRec,"\",7),1,3)
	. . . . Set LNr=99
	. . . . For  Set LNr=$O(^KFA("F",FAKNr,BONNr,LNr)) Quit:LNr'?3.4N  Do
	. . . . . Set LRec=^KFA("F",FAKNr,BONNr,LNr)
	. . . . . Quit:$P(LRec,"\",17)="KF5"
	. . . . . SEt ZonderStock=($P(LRec,"\",14)["Z")||($P(LRec,"\",14)["S") ;zonder stockaanpassing
	. . . . . Set PRNr=$P(LRec,"\",2)
	. . . . . Quit:'PRNr
 	. . . . . Set GenTyp=$$GENTYP^HAD(PRNr,1)
 	. . . . . Quit:($P(GenTyp,"\")'="TAO")
	. . . . . Set Telbaar=$$$PRGet($$$Telbaar) ; nodig voor TA'OR Bulk in onderdelen
	. . . . . Set Qty=$P(LRec,"\",3)
	. . . . . Set Omzet=$P(LRec,"\",34)
	. . . . . Set Kost=$P(LRec,"\",33)
	. . . . . Set KostZndGlijder=Kost-(($$KostBS(PRNr,"PRGLIJD")+$S($E($$$PRGet($$$KortTekst),6)="Z":0,1:$$KostBS(PRNr,"PRKOP")))*Qty)
	. . . . . Set OmzetZndGlijder=Omzet * KostZndGlijder / Kost
	. . . . . ;Quit:Qty<1
 	. . . . . Write KLNr,*9,Regio,*9,FAKNr,*9,$$$ExcelDat(-Datum)
 	. . . . . Write *9,PRNr,*9,$$$PRGet($$$KortTekst),*9,Telbaar,*9,$$$ExcelNum(Qty),*9,$$$ExcelNum(Omzet),*9,$$$ExcelNum(Kost),*9,ZonderStock,*9,$$$ExcelNum(OmzetZndGlijder),*9,$$$ExcelNum(KostZndGlijder)
 	. . . . . Write !

	Quit
	
KostBS(PRNr,BSKeyBasis)
	New Kost,BSKey,HFPRNr
	Set Kost=0
	Set BSKey=BSKeyBasis
	For  Set BSKey=$O(^PRBS("BS",PRNr,BSKey)) Quit:BSKey'[BSKeyBasis  Do
	. Quit:$P(^PRBS("BS",PRNr,BSKey),"\",3)'="H"
	. Set HFPRNr=$P(^PRBS("BS",PRNr,BSKey),"\",1)
	. Quit:HFPRNr'?4.9N
	. Set Kost=Kost+$$CifPPL^KPRIJS(HFPRNr)*$P(^PRBS("BS",PRNr,BSKey),"\",2)
	Quit Kost